start tok64 d64-yafEl6
0 IFPEEK(49152)=120THENSYS49152:GOTO70
1 PRINT"{clear}{ct n}{white}Fixar svenska tecken.
2 READy:IFy=>0THENPOKE49152+a,y:s=s-y*(a<178):a=a+1:GOTO2
3 IFs-23434THENPRINT"fel i data!":STOP
4 SYS49152
5 DATA120,169,51,133,1,160,0,185
6 DATA0,208,153,0,240,200,208,247
7 DATA238,9,192,238,12,192,208,239
8 DATA169,208,141,9,192,169,240,141
9 DATA12,192,169,55,133,1,32,45
10 DATA192,88,76,68,229,173,2,221
11 DATA9,3,141,2,221,173,0,221
12 DATA41,252,141,0,221,169,200,141
13 DATA136,2,169,45,141,24,208,169
14 DATA8,133,44,32,139,192,169,89
15 DATA141,24,3,169,192,141,25,3
16 DATA96,72,138,72,152,72,169,127
17 DATA141,13,221,32,188,246,32,225
18 DATA255,32,163,253,32,24,229,160
19 DATA3,185,48,253,153,20,3,136
20 DATA16,247,160,25,185,54,253,153
21 DATA26,3,136,16,247,32,45,192
22 DATA108,2,160,160,23,185,178,192
23 DATA153,216,240,153,216,250,73,255
24 DATA153,216,244,153,216,254,136,16
25 DATA236,160,23,185,202,192,153,216
26 DATA248,73,255,153,216,252,136,16
27 DATA242,96
28 DATA102,24,60,102,126,102,102,0
29 DATA102,60,102,102,102,102,60,0
30 DATA60,102,60,102,126,102,102,0
31 DATA102,0,60,6,62,102,62,0
32 DATA102,0,60,102,102,102,60,0
33 DATA60,102,60,6,62,102,62,0,-1
45 REM{ct n}" *******************************
46 REM" *{space*29}*
47 REM" * Glosor 64. Tillverkat av:{space*3}*
48 REM" * Peter Karlsson -89{space*10}*
49 REM" *{space*29}*
50 REM" * (c) 1989,1990,1992{space*10}*
51 REM" * Peter Karlsson{space*14}*
52 REM" *{space*29}*
53 REM" * Detta [r version 1.1{space*8}*
54 REM" *{space*29}*
55 REM" * Peter Karlsson{space*14}*
56 REM" * V[rnsta Ullers[ter{space*10}*
57 REM" * S710 40{space*2}FR{cm -}VI{space*14}*
58 REM" * Sverige{space*21}*
59 REM" *{space*29}*
60 REM" *******************************
70 REM*** initering ***
80 DIMs$(1000),t$(1000),s(1000):c=0:t$="":GOSUB900:POKE650,128
90 REM s$()=svenska, t$()=glosor,c=antal, t$=spr]k, s()=pekare
200 REM*** meny ***
210 PRINT"{gray}{clear}{ct h}{ct n}HUVUDMENY: {yellow}GLOSOR V1.1":POKE53280,0:POKE53281,0
220 PRINT"{down}{white}L{gray}adda in nya data fr]n {yellow}disk{gray}"
230 IFcTHENPRINT"{down}{white}S{gray}para dina data p] {yellow}disk{gray}"
240 IFcTHENPRINT"{down}{white}T{gray}esta dig p] alla"c"glosor."
250 IFcTHENPRINT"{down}t{white}E{gray}sta dig p] slumpvis utvalda glosor."
260 IFcTHENPRINT"{down}{white}R{gray}ensa {yellow}ALLA{gray} data."
270 PRINT"{down}{white}{sh +}{gray}ndra spr]k.";:IFt$=""THENPRINT"<- Inget inmatat.";
280 PRINT:IFt$<>""THENPRINT"{down}s{white}K{gray}riv in data."
290 IFcTHENPRINT"{down}[{white}N{gray}dra glosa
390 PRINT"{home}{down*19}{reverse on}-F{cm -}R DIG MED INTERNATIONELLT TANGENTBORD";
391 PRINT"Pundtecken ger {pound}, hakparantes v[ ger [, ";
392 PRINT"{reverse on}h{pound} ger ]. shift&- ger {sh -}. shift&+ ger {sh +}{space*2}";
393 PRINT"commodore&- ger {cm -}. I huvudmenyn (denna) ";
394 PRINT"kan du [ven anv[nda a&o f{pound}r ],[&{pound}.{space*6}{home}"
400 GETa$:IFa$=""THEN400
410 IFa$="l"THENGOSUB1000:GOTO200
420 IFa$="s"ANDc>0THENGOSUB2000:GOTO200
430 IFa$="t"ANDc>0THENGOSUB3000:GOTO200
440 IFa$="e"ANDc>0THENGOSUB4000:GOTO200
450 IFa$="r"ANDc>0THENGOSUB5000:GOTO200
460 IFa$="["ORa$="a"THENGOSUB6000:GOTO200
470 IFa$="k"ANDt$<>""THENGOSUB7000:GOTO200
480 IFa$="n"ANDc>0THENGOSUB8000:GOTO200
500 GOTO400
900 RESTORE
910 READs$:IFs$<>"komma"THEN910
920 FORi=828TO864:READa:POKEi,a:NEXT:SYS828:RETURN
930 DATAkomma,169,,133,95,133,90,133,88,169,160,133,96,169,192,133,91,133,89,32
940 DATA191,163,169,128,141,104,172,141,108,172,141,112,172,169,54,133,1,96
1000 REM *** ladda ***
1010 INPUT"{clear}{yellow}LADDA{home}{down}Filnamn{gray}";f$
1100 OPEN2,8,2,"0:"+f$+",s,r"
1110 INPUT#2,t$,c
1120 FORj=1TOc
1130 :INPUT#2,s$(j),t$(j)
1140 :PRINT"{home}{gray}{right*5}:"j"{left} AV"c"{left}."
1150 NEXT
1160 CLOSE2
1200 PRINT"{clear}L{sh +}SNING{sh space}KLAR. TRYCK {white}SPACE{gray} F{cm -}R FORTS."
1210 GETa$:IFa$=" "THENRETURN
1220 GOTO1210
2000 REM *** spara ***
2010 INPUT"{clear}{yellow}SPARA{home}{down}Filnamn{gray}";f$
2100 k$=CHR$(13):OPEN2,8,2,"0:"+f$+",s,w"
2110 PRINT#2,t$k$c
2120 FORj=1TOc
2130 :PRINT#2,s$(j)k$t$(j)
2140 :PRINT"{home}{gray}{right*5}:"j"{left} AV"c"{left}."
2150 NEXT:CLOSE2
2200 PRINT"{home}SKRIVNING KLAR. TRYCK {white}SPACE{gray} F{cm -}R FORTS."
2210 GOTO1210
3000 REM *** stort glostest ***
3010 r1=0:r2=0:f=0:PRINT"{clear}TESTA ALLA GLOSOR."
3020 PRINT"Testa {white}F{gray}r]n eller {white}T{gray}ill "t$"?"
3030 GETa$:IFa$<>"f"ANDa$<>"t"THEN3030
3040 x=0:IFa$="t"THENx=1
3050 s$="svenska":IFxTHENs$=t$
3100 FORi=1TOc
3110 :PRINT"{down*3}{gray}GLOSA"i"{left}:"
3120 :a1$=t$(i):a2$=s$(i)
3130 :IFxTHENa1$=a2$:a2$=t$(i)
3140 :PRINT"{down}Vad heter {yellow}"a1$"{gray} p] "s$"?"
3150 :INPUTi$
3160 :IFi$=a2$THENr1=r1+1:GOTO3210
3170 :PRINT"FEL{!*5} Ordet b{pound}rjar p] "LEFT$(a2$,1)"!"
3180 :INPUT"F{pound}rs{pound}k igen";i$
3190 :IFi$=a2$THENr2=r2+1:GOTO3210
3200 :PRINT"FEL IGEN{!*4} Svaret var "a2$"!":f=f+1:GOTO3300
3210 :z=RND(.):IFz<.2THENPRINT"HURRA{!*3} R{sh +}TT!":GOTO3300
3220 :IFz<.4THENPRINT"EN STOR APPL{sh -}D{!*3}":GOTO3300
3230 :IFz<.6THENPRINT"HEUREKA":GOTO3300
3240 :IFz<.8THENPRINT"BRA{!*8}":GOTO3300
3250 :PRINT"BRAVO BRAVO BRAVO{!*4}"
3300 NEXT
3400 PRINT"{clear}H{sh +}R KOMMER RESULTATEN:"
3410 p1=(r1/c)*100:p2=(r2/c)*100:p=p1+p2
3420 PRINT"{down}R[tt:"r1+r2"av"c"("p"{left}% )"
3430 PRINT"{down}R[tt f{pound}rsta f{pound}rs{pound}ket:"p1"%
3440 PRINT"R[tt andra{space*2}f{pound}rs{pound}ket:"p2"%
3500 b$="B{O*3}TT{E*3}N"
3510 IFp>10THENb$="L{sh +}R DIG STAVA!"
3520 IFp>30THENb$="SYND!!"
3530 IFp>40THENb$="N{sh +}RA HALVA!"
3540 IFp>49.9THENb$="I ALLA FALL H{sh +}LFTEN{!*3}"
3550 IFp>60THENb$="B{sh +}TTRE {sh -}' B{sh +}TTRE DA' F{cm -}R DA'{.*3}"
3560 IFp>70THENb$="BRAVO"
3570 IFp>80THENb$="DUKTIGT"
3580 IFp>90THENb$="FENOMENALT ASS{sh -}{.*3}"
3590 IFp>99.9THENb$="Y{E*3}AAHH{!*3} DU {sh +}R JU KLART B{sh +}ST{!*8}"
3600 PRINTb$
3700 PRINT"Tryck {white}SPACE{gray} f{pound}r meny."
3710 GETa$:IFa$=" "THENRETURN
3720 GOTO3710
4000 REM *** litet glostest ***
4010 r1=0:r2=0:f=0:PRINT"{clear}TESTA N{sh -}GRA GLOSOR."
4020 PRINT"Testa {white}F{gray}r]n eller {white}T{gray}ill "t$"?"
4030 GETa$:IFa$<>"f"ANDa$<>"t"THEN4030
4040 x=0:IFa$="t"THENx=1
4050 s$="svenska":IFxTHENs$=t$
4060 INPUT"Hur m]nga glosor";q:IFq<1ORq>cTHEN4060
4100 FORi=1TOc:s(i)=0:NEXT
4200 FORi=1TOq
4210 :z=INT(RND(.)*c+1)
4220 :IFs(z)THEN4210
4230 :s(z)=-1
4240 :PRINT"GLOSA NR"z"{left}."
4250 :a1$=t$(z):a2$=s$(z)
4260 :IFxTHENa1$=a2$:a2$=t$(z)
4270 :PRINT"{down}Vad heter "a1$" p] "s$"?"
4280 :INPUTi$
4290 :IFi$=a2$THENr1=r1+1:GOTO4340
4300 :PRINT"FEL{!*5} Ordet b{pound}rjar p] "LEFT$(a2$,1)"!"
4310 :INPUT"F{pound}rs{pound}k igen";i$
4320 :IFi$=a2$THENr2=r2+1:GOTO4340
4330 :PRINT"KLANTHUVE'{!*4} Svaret var "a2$"!":f=f+1:GOTO4390
4340 :z=RND(.):IFz<.2THENPRINT"HURRA{!*3} R{sh +}TT!":GOTO4390
4350 :IFz<.4THENPRINT"EN STOR APPL{sh -}D{!*3}":GOTO4390
4360 :IFz<.6THENPRINT"HEUREKA":GOTO4390
4370 :IFz<.8THENPRINT"BRA{!*8}":GOTO4390
4380 :PRINT"BRAVO BRAVO BRAVO{!*4}"
4390 NEXT
4400 PRINT"{clear}H{sh +}R KOMMER RESULTATEN:"
4410 p1=(r1/q)*100:p2=(r2/q)*100:p=p1+p2
4420 PRINT"{down}R[tt:"r1+r2"av"q"("p"{left}% )"
4430 GOTO 3430
5000 REM *** rensa ***
5010 PRINT"{clear}RENSA"
5020 INPUT"VILL DU INTE SPARA F{cm -}RST";a$
5030 a$=LEFT$(a$,1):IFa$<>"n"THENGOSUB2000
5040 INPUT"{sh +}R DU S{sh +}KER P{sh -} ATT DU VILL RENSA";a$
5050 a$=LEFT$(a$,1):IFa$<>"j"THENRETURN
5060 INPUT"RIKTIGT S{sh +}KER";a$
5070 a$=LEFT$(a$,1):IFa$<>"j"THENRETURN
5080 PRINT"OK{!*3}":RUN70
6000 REM *** spr]k ***
6010 PRINT"{clear}{sh +}NDRA SPR{sh -}K":IFc=0THEN6060
6020 INPUT"OBS! DETTA RENSAR ALLA DATA. {sh +}R DU S{sh +}KERP{sh -} ATT DU VILL";a$
6030 a$=LEFT$(a$,1):IFa$<>"j"THENRETURN
6040 INPUT"VILL DU SPARA F{cm -}RST";a$
6050 a$=LEFT$(a$,1):IFa$<>"n"THENGOSUB2000
6060 PRINT"OK!":CLR:DIMs$(1000),t$(1000),s(1000)
6070 INPUT"Spr]k";t$
6080 PRINT"Tryck {white}SPACE{gray} f{pound}r att forts[tta"
6090 GETa$:IFa$=" "THENGOTO210
6100 GOTO6090
7000 REM *** input ***
7010 PRINT"{clear}INPUT"
7020 PRINT"{down}Mata in: (svenska=end avslutar)"
7030 c=c+1:IFc>1000THENPRINT"OUT OF MEMORY":GOTO7100
7040 PRINT"{down}svenska"TAB(15);:INPUTs$(c):IFs$(c)="end"THEN7100
7050 PRINTt$TAB(15);:INPUTt$(c):PRINT"St[mmer det?
7060 GETa$:IFa$="j"THEN7030
7070 IFa$="n"THENc=c-1:GOTO7030
7080 GOTO7060
7100 c=c-1:PRINT"{down*2}Du har nu"c"glosor i minnet"
7110 PRINT"{down}Tryck {white}SPACE{gray} f{pound}r att forts[tta"
7120 GETa$:IFa$=" "THENRETURN
7130 GOTO7120
8000 REM *** [ndra ***
8010 PRINT"{clear}{sh +}NDRA GLOSOR
8020 PRINT"Glosan p] svenska:":INPUTa$
8030 FORi=1TOc:IFs$(i)<>a$THENNEXT:RETURN
8040 PRINT"{gray}Nuvarande svar:{yellow}":PRINTt$(i)
8050 PRINT"{gray}{sh +}ndra till (RETURN ger samma):"
8060 INPUTt$(i):RETURN
63000 "{.*10}GLOSOR..1.1{.*11}
63002 ". Programuppbyggnad:{space*11}.
63003 ".{space*4}0-{space*2}39 Svenska tecken{space*5}.
63004 ".{space*3}45-{space*2}60 REM info{space*11}.
63005 ".{space*3}70-{space*2}99 Initiering{space*9}.
63006 ".{space*2}200- 399 Huvudmeny{space*10}.
63007 ".{space*2}400- 599 Behandlar val{space*6}.
63008 ".{space*2}900- {9*3} Subr:input m. komma.
63009 ". 1{0*3}-1{9*3} Subrutin:ladda data.
63010 ". 2{0*3}-2{9*3} Subrutin:spara data.
63011 ". 3{0*3}-3{9*3} Subr:stort glostest.
63012 ". 4{0*3}-4{9*3} Subr:litet glostest.
63013 ". 5{0*3}-5{9*3} Subrutin:rensa data.
63014 ". 6{0*3}-6{9*3} Subrut: [ndra spr]k.
63015 ". 7{0*3}-7{9*3} Subrut:input glosor.
63016 ". 8{0*3}-8{9*3} Subrut:[ndra glosor.
63018 "{.*32}
63019  
63020 "Softwolves Software 1994
63021 "Distribueras genom:
63022 "{space*4}SYS{sh space}PD/C64, C128
63023 "c/o Peter Karlsson
63024 "{space*4}V[rnsta, Ullers[ter
63025 "{space*4}710 40{space*2}FR{cm -}VI
stop tok64
(bastext 1.0)