start tok64 d64-6LYY2i
0 REM"{cm n}M{space*5}{cm n}M{space*3}{cm n}M{space*12}v1.3
1 REM"{cm n*2}{space*5}{cm n*2}{space*3}{cm n*2}{space*9}1993-06-11
2 REM"{cm n}Nouble{cm n}Nisk{cm n}Nirectory
3 REM
4 REM (c)1991,1993 mr.p for softwolves
5 REM                       software
6 REM for sys pd/c64,c128
7 REM
8 REM -------------------------------            this program is free ware
9 REM    and may be copied freely.            -------------------------------
10 DIMa$(150,1),bl(150,1)
20 POKE53280,.:POKE53281,.
30 PRINT"{yellow}{reverse on}{clear} double disk directory v1.3 {white} freeware {yellow}{space*2}"
40 PRINT"{yellow}(c)1991,93 mr.p. and softwolves software
50 PRINT"{green}for sys pd/c64,c128
60 PRINT"{down}{156}do you want to use {white}s{156}creen or {white}p{156}rinter?{down}
70 POKE198,.:WAIT198,1:GETa$:IFa$="s"THENdv=3:sk=9:pw=40:GOTO150
80 IFa$<>"p"THEN70
90 PRINT"{light gray}note: to use the tfc3 parallel port
91 PRINT"{space*6}emulator, enter 0 as 2ndry addy.{down}
100 INPUT"{156}printer device#{space*5}? 4{left*3}";dv:IFdv<4ORdv>7THEN100
110 INPUT"2ndry addr (0=none) ? 0{left*3}";sk:IFsk<0ORsk>255THEN120
120 INPUT"paper width(40-255) ? 80{left*4}";pw:IFpw<40ORpw>255THEN120
130 PRINT"{down}is this correct{space*5}?":POKE198,.:WAIT198,1:GETa$:IFa$="n"THEN100
140 PRINT
150 INPUT"view del(eted) files? y{left*3}";dl$:IFdl$<>"y"ANDdl$<>"n"THEN150
152 INPUT"dual disk drive{space*5}? n{left*3}";dd$:IFdd$<>"y"ANDdd$<>"n"THEN150
155 INPUT"two disk drives{space*5}? n{left*3}";td$:IFtd$<>"y"ANDtd$<>"n"THEN150
160 INPUT"disk device#{space*8}? 8{left*3}";dd:IFdd<8ORdd>15THEN160
161 IFtd$="n"THEN170
165 INPUT"2nd disk device#{space*4}? 9{left*3}";td:IFtd<8ORtd>15THEN165
170 PRINT"{yellow}{reverse on}{clear} double disk directory v1.3 {white} freeware {yellow}{space*2}"
172 PRINT"{cyan} please insert ";
175 IFdd$="y"ORtd$="y"THENPRINT"disks
180 IFdd$="n"ANDtd$="n"THENPRINT"first disk
190 POKE198,.:WAIT198,1
200 CLOSE8:OPEN8,dd,0,"$0
210 dr=.:PRINT"{156}{down}{right}reading first disk":GOSUB1000:d1=de
220 CLOSE8:IFtd$="y"THENOPEN8,td,0,"$0":GOTO260
230 IFdd$="n"THENPRINT"{down}{cyan} please insert second disk":POKE198,.:WAIT198,1
240 IFdd$="y"THENOPEN8,dd,0,"$1
250 IFdd$="n"THENOPEN8,dd,0,"$0
260 dr=1:PRINT"{156}{down}{right}reading second disk":GOSUB1000
270 CLOSE8
280 d2=de:IFd1>deTHENde=d1
285 PRINT"{yellow}{reverse on}{clear} double disk directory v1.3 {white} freeware {yellow}{space*2}"
287 IFdv>3THENPRINT"{cyan} printing {.*3}
290 CLOSE4:IFsk=0THENOPEN4,dv:GOTO295
292 OPEN4,dv,sk
295 CMD4," double disk directory (c)1991,93 mr.p."
297 s$="{space*40}"
298 s$=s$+s$+s$
300 IFpw<80THEN320
310 s1$="disk: "+a$(.,.):s2$="disk: "+a$(.,1):GOSUB1500:GOTO330
320 s1$=LEFT$(a$(.,.),19):s2$=LEFT$(a$(.,1),19):GOSUB1500
330 FORi=1TOde
340 IFi>d1THENs1$="":GOTO400
350 IFpw=>80THEN370
360 s1$=a$(i,.):GOTO400
370 s1$=LEFT$(a$(i,.),17)+STR$(bl(i,.))
380 b$=RIGHT$(a$(i,.),1):GOSUB2000:s1$=s1$+"("+b$+")"
400 IFi>d2THENs2$="":GOTO475
410 IFpw=>80THEN430
420 s2$=a$(i,1):GOTO475
430 s2$=LEFT$(a$(i,1),17)+STR$(bl(i,1))
440 b$=RIGHT$(a$(i,1),1):GOSUB2000:s2$=s2$+"("+b$+")"
475 GOSUB1500
500 IFdv>3THEN550
510 rw=rw+1:IFrw<17THEN550
520 PRINT"{white}any key":POKE198,.:WAIT198,1:POKE198,.:rw=.
530 PRINT"{yellow}{reverse on}{clear} double disk directory v1.3 {white} freeware {yellow}{space*2}"
550 NEXT
600 s1$=STR$(bl(d1+1,.))+" blocks free":s2$=STR$(bl(d2+1,1))+" blocks free"
610 GOSUB1500
620 PRINT#4:CLOSE4
630 END
1000 GET#8,a$,a$,a$,a$
1010 GET#8,a$:IFa$<>CHR$(34)THEN1010
1020 FORi=1TO16:GET#8,a$:a$(0,dr)=a$(0,dr)+a$:NEXT
1030 GET#8,a$,a$,b$,c$,d$,e$,f$,a$
1040 a$(0,dr)=a$(0,dr)+","+b$+c$+d$+e$+f$:PRINT"{down}{right}{yellow}title: "a$(0,dr)"{down*2}
1090 de=1
1100 GET#8,a$,a$,l$,h$:bl(de,dr)=ASC(l$+CHR$(.))+256*ASC(h$+CHR$(.))
1110 GET#8,a$:IFa$="b"THENde=de-1:RETURN
1115 PRINT"{up}{right}{gray}files:"de
1120 IFa$<>CHR$(34)THEN1110
1130 GET#8,a$:IFa$<>CHR$(34)THENa$(de,dr)=a$(de,dr)+a$:GOTO1130
1140 GET#8,a$:IFa$=" "THEN1140
1150 a$(de,dr)=LEFT$(a$(de,dr)+"{space*16}",16)+" "+a$
1155 IFdl$="n"ANDa$="d"THENa$(de,dr)="":de=de-1
1160 GET#8,a$:IFa$THEN1160
1170 de=de+1:GOTO1100
1500 PRINTLEFT$(s1$+s$,pw/2)LEFT$(s2$,pw/2):RETURN
2000 IFb$="p"THENb$="program":RETURN
2010 IFb$="s"THENb$="sequential":RETURN
2020 IFb$="r"THENb$="relative":RETURN
2030 IFb$="d"THENb$="deleted":RETURN
2040 IFb$="u"THENb$="user":RETURN
2050 IFb$="*"THENb$="not closed":RETURN
2060 b$="error":RETURN
3000 REM v1.1 : 1991-07-22
3010 REM v1.2 : 1993-06-10
3020 REM v1.3 : 1993-06-11
stop tok64
(bastext 1.0)