start tok64 d64-gH1ets
0 REM sys pd 1992
10 REM *********************
20 REM *                   *
30 REM * {pound}nskerutinen nr 1 *
40 REM *                   *
50 REM * test drive        *
60 REM *                   *
70 REM * av kim johansson  *
80 REM * modifierat av     *
90 REM * peter karlsson    *
100 REM ************************
110 REM * obs!!!               *
120 REM * programmet fungerar  *
130 REM * p] c-64 och c-128    *
140 REM ************************
145 POKE53280,15:POKE53281,15
150 x=128:IFPEEK(40960)THENx=64
160 PRINT"{white}{clear} test drive 64/128. k{pound}rs nu p] en c"MID$(STR$(x),2)".
165 PRINT"{white}{cm y*40}{down}":FORdv=8TO11
170 OPEN15,dv,15
180 IFx=64THENPOKE780,dv:SYS65457:POKE780,15:SYS65427
190 IFx=128THENSYS65457,dv:SYS65427,15
195 PRINT"{down}{black}enhet{white} #"MID$(STR$(dv),2)TAB(10)"{dark gray}[r ";
200 IFst<.THENPRINT"ej ansluten !":SYS65454:GOTO280
210 SYS65454
220 ad=58822:GOSUB390
230 PRINT"en";
240 IFa=52THENPRINT1541:GOTO280
250 IFa=55THENPRINT1571;:GOSUB310:GOTO280
260 IFa=255THENPRINT1581:GOTO280
270 PRINT"piratdrive (1541)?
280 CLOSE15
290 PRINT"{black}{cm y*39}":NEXTdv
300 END
310 REM 1571 test
320 ad=681:GOSUB390
330 IFa=222THENPRINT"i 1571 mode":GOTO380
340 IFa=136THENPRINT"i 1541 mode ";
350 ad=6159:GOSUB390
360 IFNOTaAND4THENPRINT"sida 1
370 IFaAND4THENPRINT"sida 2
380 RETURN
385 REM disk peek
390 ah=INT(ad/256):al=ad-ah*256
400 PRINT#15,"m-r"CHR$(al)CHR$(ah)CHR$(1)
410 GET#15,a$
420 a=ASC(a$+CHR$(0))
430 RETURN
stop tok64
(bastext 1.0)