start tok64 d64-0gTyax
10 REM"{141}{up}{cm a}{sh asterisk*37}{cm s}
11 REM"{141}{up}{sh -}{space*5}{cm @*27}{space*5}{sh -}
12 REM"{141}{up}{sh -}{space*5}{reverse on}mini sequential file reader{reverse off}{space*5}{sh -}
13 REM"{141}{up}{sh -}{space*37}{sh -}
14 REM"{141}{up}{sh -} (c) 1991 softwolves software/sys pd {sh -}
15 REM"{141}{up}{sh -} and mr.p.{space*27}{sh -}
16 REM"{141}{up}{cm q}{sh asterisk*37}{cm w}
17 REM"{141}{up}{sh -} ok to copy, translate and modify{space*4}{sh -}
18 REM"{141}{up}{sh -} but do not sell or erase my name{!*3} {sh -}
19 REM"{141}{up}{cm z}{sh asterisk*37}{cm x}
20 REM"{delete*7}save"mini seq reader",8
21 REM"{delete*7}{141*3}run
30 POKE53280,14:POKE53281,14
40 PRINT"{ct h}{142}{clear}{down}{right*5}{white}{reverse on} {sh asterisk}{cm k}{sh -}{reverse off}{cm k}{reverse on} {sh asterisk}
50 PRINT"{right*5}{reverse on}{cm y} {right} {right}{cm y} {right}{reverse off}public domain presents:
60 FORi=.TO1000:NEXT
70 PRINT,"{white}{down*2}in cooperation with:
80 FORi=.TO2000:NEXT
90 PRINT,"{down*2}{reverse on}softwolves{space*2}software
100 FORi=.TO1000:NEXT
110 PRINT,"{down*2}copyright (c) in 1991
120 FORi=.TO3000:NEXT
130 PRINT"{ct h}{142}{clear}{down}{cm a}{cm r}{cm s}{cm r}{cm a}{sh asterisk}{cm s}{cm r} {cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s} {cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}I{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}
131 PRINT"{sh -*5} {sh -*2} {sh -}{space*2}{sh -}{space*2}{sh -} {sh -} {sh -} {sh -*2}{space*2}{sh -} {sh -*2} {sh -*2}{space*2}{sh -} {sh -}ver";
132 PRINT"{sh -*5} {sh -*2} {cm z}{sh asterisk}{cm s}{cm q}{sh asterisk}{cm w}{sh -} {sh -} {cm q}{cm r}{cm x}{cm q}{sh asterisk}{cm w}{cm q}{sh asterisk}{cm w}{sh -} {sh -}{cm q}{sh asterisk}{cm w}{cm q}{cm r}{cm x}1.0";
133 PRINT"{sh -} {sh -*3} {sh -*2}{space*3}{sh -*2}{space*2}{sh -}M{sh -} {sh -}{cm z}{cm s}{sh -}{space*2}{sh -} {sh -*2} {sh -*2}{space*2}{sh -}{cm z}{cm s}
134 PRINT"{cm x} {cm z}{cm e}{cm x} {cm z}{cm e} {cm z}{sh asterisk}{cm x}{cm z}{sh asterisk}{cm x}{cm z}{sh asterisk}M {cm e} {cm e}{cm z}{sh asterisk}{cm x}{cm e} {cm e}{cm z}{sh asterisk}K{cm z}{sh asterisk}{cm x}{cm e} {cm e}
140 PRINT"{blue}{sh asterisk*40}
150 PRINT"{white}which seq-file do you want to read?
160 POKE198,.:a$="":INPUT"$=dir @=dos {arrow left}=quit? ${left*3}";a$
161 IFa$="{arrow left}"THENPRINT"{clear}{light blue}";:POKE53281,6:END
165 IFa$="@"THENGOSUB2000:GOTO140
170 IFa$="$"THENGOSUB1000:GOTO140
180 OPEN15,8,15
185 PRINT"{clear}{ct n}";
190 OPEN8,8,8,"0:"+a$+",s,r"
200 GOSUB990:PRINT:PRINT"{reverse on}SHIFT{reverse off} pauses and {reverse on}Q{reverse off} quits
210 GET#8,b$:IFstTHEN280
220 PRINTb$;:IFPEEK(653)AND3=.THENGOSUB990:GOTO210
230 IFPEEK(653)AND1=1THEN230
240 IFPEEK(197)=62THEN260
250 GOTO210
260 PRINT:PRINT"{reverse on}Reading aborted by user.":CLOSE8:CLOSE15
270 PRINT:PRINT"Press {reverse on}CONTROL{reverse off} to restart":WAIT653,4:RUN130
280 PRINT:PRINT"{reverse on}End of file":CLOSE8:CLOSE15:GOTO270
290 PRINT"{reverse on}Reading aborted due to disk error:
300 PRINT"{reverse on}"CHR$(ASC(em$)+32)MID$(em$,2)".":CLOSE8:CLOSE15:GOTO270
990 INPUT#15,en,em$,et,es:IFen<20THENRETURN
991 GOTO290
1000 PRINT"{down}pause directory with {reverse on}shift{reverse off}.
1005 a$="$0:*=s":IFz=1THENa$="$":z=.
1010 OPEN1,8,0,a$:POKE781,1:SYS65478:GETa$,a$:e$=CHR$(.)
1020 GETa$,a$,h$,l$:IFstTHENSYS65484:CLOSE1:RETURN
1030 IFPEEK(653)AND1=1THEN1030
1040 PRINTASC(h$+e$)+256*ASC(l$+e$);
1050 GETa$,b$:IFa$THENPRINTa$b$;:GOTO1050
1060 PRINTa$:GOTO1020
2000 PRINT"{down}enter dos command: $ for dir.
2010 PRINT"return to quit.
2020 a$="":POKE631,34:POKE198,1:INPUTa$
2030 IFa$="$"THENz=1:GOSUB1000:GOTO2020
2040 IFa$=""THENRETURN
2050 IFLEFT$(a$,1)="n"THEN2110
2060 IFLEFT$(a$,1)="v"THEN2120
2070 IFLEFT$(a$,1)="s"THEN2130
2080 PRINT"sending:":PRINTa$:OPEN15,8,15,a$
2090 INPUT#15,en,em$,et$,es$:PRINTCHR$(34)em$CHR$(34)"{space*2}"et$" "es$
2100 CLOSE15:GOTO2020
2110 g$="format":GOTO2140
2120 g$="validate":GOTO2140
2130 g$="scratch
2140 PRINT"warning: by using the "g$" command
2150 PRINT"{space*9}you can lose important data.
2160 PRINT"{space*9}to continue: press {reverse on} y {reverse off}.
2170 GETa$:IFa$=""THEN2170
2180 IFa$<>"y"THEN2020
2190 PRINT"{space*9}press {reverse on} ^ {reverse off} to "g$".
2200 GETa$:IFa$=""THEN2200
2210 IFa$<>"^"THEN2020
2220 GOTO2080
stop tok64
(bastext 1.0)