start tok64 d64-w6HQFE
0 PRINT"{clear}LIV2{.*18}CREATIVE COMPUTING{down*3}":POKE53272,27
7 DIMn(6,6),k(18),a(16),x(2),y(2)
8 DATA3,102,103,120,130,121,112,11,12
9 DATA21,30,1020,1030,1011,1021,1003,1002,1012
10 FORm=1TO18:READk(m):NEXT
13 DATA-1,0,1,0,0,-1,0,1,-1,-1,1,-1,-1,1,1,1
14 FORo1=1TO16:READa(o1):NEXT
20 GOTO500
50 FORj=1TO5:FORk=1TO5:IFn(j,k)>99THENGOSUB200
60 NEXTk,j
90 k=0:m2=0:m3=0
99 FORj=0TO6:PRINT
100 FORk=0TO6:IFj<>0ANDj<>6THEN105
102 IFk=6THENPRINT0;:GOTO125
103 PRINTk;:GOTO120
105 IFk<>0ANDk<>6THEN110
106 IFj=6THENPRINT0:GOTO126
107 PRINTj;:GOTO120
110 GOSUB300
120 NEXTk
125 NEXTj
126 RETURN
130 NEXTj
200 b=1:IFn(j,k)>999THENb=10
220 FORo1=1TO15STEP2
230 n(j+a(o1),k+a(o1+1))=n(j+a(o1),k+a(o1+1))+b
231 NEXTo1:RETURN
300 IFn(j,k)<3THEN399
305 FORo1=1TO18:IFn(j,k)=k(o1)THEN350
315 NEXTo1:GOTO399
350 IFo1>9THEN360
351 n(j,k)=100:m2=m2+1:PRINT" * ";
355 RETURN
360 n(j,k)=1000:m3=m3+1:PRINT" # ";
365 RETURN
399 n(j,k)=0:PRINT"{space*3}";:RETURN
500 PRINTTAB(10)"U.B. Livsspel
505 m2=0:m3=0
510 FORj=1TO5:FORk=1TO5:n(j,k)=0:NEXT:NEXT
519 FORb=1TO2:p1=3:IFb=2THENp1=30
520 PRINT"Spelare"b"- 3 levande pj[ser.
525 x$="*":IFb=2THENx$="#"
526 PRINT"Dina pj[ser markeras med '"x$"'."
530 PRINT"Siffrorna [r 'g{pound}mda' s] de kan inte{space*5}l[sas n[r de skrivs in.
535 FORk=1TO3:GOSUB700:n(x(b),y(b))=p1:NEXTk
542 NEXT
559 GOSUB90
560 PRINT:GOSUB50
570 IFm2=0THENIFm3=0THEN574
571 IFm3=0THENb=1:GOTO575
572 IFm2=0THENb=2:GOTO575
573 GOTO580
574 PRINT:PRINT"Oavgjort.":END
575 PRINT:PRINT"Spelare"b"har vunnit.":END
580 FORb=1TO2:PRINT:PRINT"Spelare"b;:GOSUB700
581 IFb=99THEN560
582 NEXTb
586 n(x(1),y(1))=100:n(x(2),y(2))=1000
596 GOTO560
700 PRINT"X,Y:
701 INPUT"{reverse on}Koord.:{space*2}{left*2}";y(b),x(b):q=FRE(.)
705 IFx(b)=<5ANDx(b)>0THEN708
706 GOTO750
708 IFy(b)=<5ANDy(b)>0THEN715
710 GOTO750
715 IFn(x(b),y(b))<>0THEN750
720 IFb=1THENRETURN
725 IFx(1)=x(2)ANDy(1)=y(2)THEN740
730 RETURN
740 PRINT"Samma koord. Ange 0 (noll)
741 n(x(b)+1,y(b)+1)=0:b=99:RETURN
750 PRINT"Ogiltiga koord. skriv om!":GOTO700
stop tok64
(bastext 1.0)