start tok64 d64-RcODhR
0 REM ********************************
1 REM* hastkapplopning -  ett spel av *
2 REM* 0041 mr.p. for club64 1990 (c) *
3 REM* greetings to all club64-fans!! *
4 REM ********************************
5 kr=1000
10 PRINT"hastlopning
20 PRINT"{down*2}nr namn",,,"odds
30 PRINT"{cm y*2} {cm y*4}",,,"{cm y*4}
40 REM ** las hastar **
50 ha=ha+1:IFha>1THEN100
60 DIMn$(50),n1$(9),od(9),kr(9)
70 s=.
80 s=s+1:READn$(s)
90 IFn$(s)<>"slut"THEN80
95 hn=s-1
100 REM ** valj hastar **
110 od(.)=999:FORi=1TO9
120 z=1+INT(RND(.)*hn):n1$(i)=n$(z)
130 IFi=1THEN170
140 FORj=1TOi-1
150 IFn1$(i)=n1$(j)THEN120
160 NEXT
170 od(i)=INT((1+RND(.)*5)*100+.5)/100:PRINTi;n1$(i)TAB(29)od(i)
175 IFod(i)<od(x)THENy=x:x=i:GOTO180
176 IFod(i)<od(y)THENy=i
180 NEXTi
190 REM ** satsning **
200 PRINT"du har"kr"kr.":FORi=1TO9:kr(i)=.:NEXT
210 PRINT"du kan satsa pa max 4 hastar , <return> avslutar
215 PRINT"* tipset: "n1$(x)" och":PRINT"* "n1$(y)
220 INPUT"hast 1: nr,kr";s,kr(s):IFs=.ORkr(s)<.THEN220
225 FORi=2TO4
230 PRINT"hast"i"{left}: ";:INPUT"nr,kr";s,kr(s):IFs=.THENa=i-1:GOTO300
235 IFkr(s)<.THEN230
240 NEXT
250 a=4
300 REM ** loppet **
310 PRINT"{clear}du har satsat pa:
320 FORi=1TO9:IFkr(i)>.THENPRINT"nummer"i;n1$(i)":"TAB(25)kr(i)"{left}kr
330 l(i)=.:NEXT
340 PRINT"{home}{down*6}0"TAB(9)"100"TAB(19)"200"TAB(29)"300"TAB(37)"400{sh -}";
350 PRINTTAB(49)"{sh -}"TAB(59)"{sh -}"TAB(69)"{sh -}"TAB(79)"{sh -}";
360 a$="{sh asterisk*8}{sh +}{sh asterisk}"
370 PRINT"{cm q}"a$a$a$"{sh asterisk*8}{cm w}{sh -}{space*8}{sh -}{space*9}{sh -}{space*9}{sh -}{space*9}{sh -}
380 FORi=1TO9
390 PRINT"{home}{down*9}"LEFT$("{down*10}",i);
395 s$=MID$("{sh -*2}start{sh -*2}",i,1):f$=MID$("{sh -}{white}f{red}i{cyan}n{156}i{green}s{brown}h{yellow}{sh -}{gray}{sh -}{light gray}",i*2-1,2)
400 PRINTs$"{space*8}{sh -}{space*9}{sh -}{space*9}{sh -}{space*9}"f$"{reverse on}{up}"SPC(l(i))CHR$(48+i)"{light blue}
410 IFINT(l(i))=39THEN500
415 s=5-od(i)+RND(.)*5:s=s+s*(s<1ORs>5)-1*(s<1)-5*(s>5)
420 q=RND(.)*s:IFq>5THEN420
430 l(i)=l(i)+q:IFl(i)>=39THENl(i)=39
440 NEXT
450 GOTO380
500 REM ** segrare **
510 PRINT"{home}{down*19}i loppet vann hast nr"i
520 PRINT"("n1$(i)") odds="od(i)
530 IFkr(i)=.THEN600
540 PRINT"pa hast nr"i"hade du satsat
550 PRINTkr(i)"{left}kr.":v=INT(kr(i)*od(i))
560 PRINT"du vinner"v"{left}kr.
570 kr=kr+v
580 GOTO700
600 PRINT"pa hast nr"i"hade du inte satsat
610 PRINT"ett dugg{!*3}
700 FORq=1TO9:IFi<>qTHENkr=kr-kr(q)
710 NEXT
720 PRINT"vill du satsa igen?"
730 GETa$:IFa$="j"THEN10
740 IFa$="n"THEN800
750 GOTO730
800 REM ** slut **
810 PRINT"{clear}hej da
820 PRINT"du fick"kr"{left}kr
830 PRINT"det var ";:IFkr<1000THENPRINT"tur";
840 IFkr=>1000THENPRINT"synd";
850 PRINT" att det inte var verkligt!":END
900 REM ** hastar **
910 DATAcommodore club
920 DATAatari tilt
930 DATAserieexpressen
940 DATAmagic flute
950 DATAblack magic
960 DATAbig bang
970 DATArobin hood
980 DATAthe brother
990 DATAmacho king
1000 DATAjoy stick
1010 DATAsinclair star
1020 DATAluxor lucy
1030 DATAoric oracle
1040 DATAtexas time
1050 DATAgreat grape ape
1060 DATAhackers harm
1070 DATAcrackers cream
1080 DATAdebugger
1090 DATAbranch burner
1100 DATAjumpin' jake
1110 DATAcare of case
1120 DATAauto fire
1130 DATAfrankensteins monster
1140 DATApop corn
2000 DATAslut
stop tok64
(bastext 1.0)