start tok64 d64-Y6CvC3
2 PRINT"{clear}":POKE53280,5:POKE53281,0
3 PRINT"{white}{down*2}{right*2}greetings to:"
4 PRINT"{cyan}{down}{right*2}qhawk, sysop fm, thomast2, bonnie,"
5 PRINT"{right*2}djsenterp, dicka2, kel, exploited3,"
6 PRINT"{right*2}cnet rep, qguide sas, iant, the rad"
7 PRINT"{right*2}heavy metal bands, and all the other"
8 PRINT"{right*2}cool qlinkers i forgot to mention.":PRINT"{white}{down}{right*2}{reverse on}hit any key"
9 POKE53280,5:POKE53280,6:POKE53280,4:GETa$:IFa$=""THEN9
10 POKE53280,0:POKE53281,0:DIMi$(13,13)
15 FORi=54272TO54296:POKEi,0:NEXT
20 PRINT"{clear}{blue}{reverse on}O{cm y*38}P";
30 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
40 PRINT"{reverse on}{cm h}{reverse off}{space*3}{white}m a x i m u m{space*2}o v e r d r i v e{space*3}{reverse on}{blue}{cm n}";
50 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
60 PRINT"{reverse on}L{cm p*38}{sh @}";
70 PRINT"{reverse on}O{cm y*38}P";
80 FORi=1TO11:PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";:NEXT
90 PRINT"{reverse on}L{cm p*38}{sh @}";
92 PRINT"{reverse on}O{cm y*38}P";
94 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
95 PRINT"{reverse on}{cm h}{reverse off}{space*2}{white}by digidan{space*14}{reverse on}select a-r{reverse off}{space*2}{reverse on}{blue}{cm n}";
96 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
98 PRINT"{reverse on}L{cm p*38}{sh @}";
100 PRINT"{up*3}{white}{right*3}{reverse off}"
110 PRINT"{home}{down*6}{right}{reverse on}{light blue}{cm a}{sh asterisk}{cm s}"
120 PRINT"{up}{right}{reverse on}{sh -}a{sh -}":PRINT"{right}{reverse on}{sh -}b{sh -}":PRINT"{up}{right}{reverse on}{sh -}c{sh -}":PRINT"{right}{reverse on}{sh -}d{sh -}":PRINT"{up}{right}{reverse on}{sh -}e{sh -}"
130 PRINT"{right}{reverse on}{sh -}f{sh -}";:PRINT"{down}{left*3}{reverse on}{sh -}g{sh -}":PRINT"{right}{reverse on}{sh -}h{sh -}":PRINT"{up}{right}{reverse on}{sh -}i{sh -}":PRINT"{right}{reverse on}{cm z}{sh asterisk}{cm x}"
140 PRINT"{up*11}{right*5}{cyan}insulting":PRINT"{right*5}destruction"
150 PRINT"{up}{right*5}unresponsive":PRINT"{right*5}wake up":PRINT"{up}{right*5}128 look-alike"
160 PRINT"{right*5}intruder alert":PRINT"{up}{right*5}flattering"
170 PRINT"{right*5}twilight zone":PRINT"{up}{right*5}byte thief"
180 PRINT"{up*10}"TAB(21)"{reverse on}{light blue}{cm a}{sh asterisk}{cm s}"
190 PRINTTAB(21)"{reverse on}{up}{sh -}j{sh -}":PRINTTAB(21)"{reverse on}{sh -}k{sh -}":PRINTTAB(21)"{up}{reverse on}{sh -}l{sh -}"
200 PRINTTAB(21)"{reverse on}{sh -}m{sh -}":PRINTTAB(21)"{reverse on}{up}{sh -}n{sh -}":PRINTTAB(21)"{reverse on}{sh -}o{sh -}"
210 PRINTTAB(21)"{reverse on}{up}{sh -}p{sh -}":PRINTTAB(21)"{reverse on}{sh -}q{sh -}":PRINTTAB(21)"{up}{reverse on}{sh -}r{sh -}"
220 PRINTTAB(21)"{reverse on}{cm z}{sh asterisk}{cm x}"
230 PRINTTAB(25)"{up*11}{cyan}malfunction"
240 PRINTTAB(25)"messenger":PRINTTAB(25)"{up}self control"
250 PRINTTAB(25)"norad":PRINTTAB(25)"{up}frustrating":PRINTTAB(25)"screen quake"
260 PRINTTAB(25)"{up}{yellow}disable stop"
270 PRINTTAB(25)"instructions"
280 PRINTTAB(25)"{up}quit":c=1
290 GETa$:GOSUB7000:IFa$=""THEN290
300 IFa$="q"THEN500
302 IFa$="r"THENPOKE53280,14:POKE53281,6:PRINT"{clear}{light blue}";:END
304 IFa$="a"THEN900
305 IFa$="b"THEN1600
306 IFa$="c"THEN1950
307 IFa$="d"THEN2150
308 IFa$="e"THEN2400
309 IFa$="f"THEN2540
310 IFa$="g"THEN2750
311 IFa$="h"THEN3000
312 IFa$="i"THEN3250
313 IFa$="j"THEN4000
314 IFa$="k"THEN4350
315 IFa$="l"THEN4500
316 IFa$="m"THEN4800
317 IFa$="n"THEN5200
318 IFa$="o"THEN5400
319 IFa$="p"THEN6000
499 GOTO290
500 PRINT"{clear}{green}{reverse on}O{cm y*38}P";
510 FORi=1TO16:PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
520 NEXT:PRINT"{reverse on}L{cm p*38}{sh @}";
530 PRINT"{reverse on}O{cm y*38}P";
535 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
540 PRINT"{reverse on}{cm h}{reverse off} {white} instructions{space*11}{reverse on}hit any key{reverse off}{space*2}{green}{reverse on}{cm n}";
545 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
550 PRINT"{reverse on}L{cm p*38}{sh @}";
560 PRINT"{reverse off}{home}{down*2}{right*2}{light blue}this program is designed for having"
570 PRINT"{up}{right*2}some totally rad fun.{space*2}there are 15"
580 PRINT"{right*2}different faking modes.{space*2}each of"
590 PRINT"{up}{right*2}these begin by simulating the basic"
600 PRINT"{right*2}environment.{space*2}after that, something"
610 PRINT"{up}{right*2}strange will happen.. depending on"
620 PRINT"{right*2}which mode you selected."
630 PRINT"{right*2}it is suggested that you select a"
640 PRINT"{up}{right*2}faking mode, leave the computer on,"
650 PRINT"{right*2}and wait until someone tries to use"
660 PRINT"{up}{right*2}it.{space*2}that's where the fun part"
670 PRINT"{right*2}comes in.{space*2}for the first time you"
680 PRINT"{up}{right*2}can watch your friend jump 40 feet."
685 GOTO720
690 GETa$:IFa$=""THEN690
700 PRINT"{home}{down}":FORi=1TO7:PRINT"{right*2}{space*36}":NEXT
705 PRINT"{up*16}"
706 FORi=1TO7:PRINT"{down}{right*2}{space*36}{up}":NEXT
710 RETURN
720 GOSUB690
730 PRINT"{home}{down*2}{right*2}after you select a faking mode,"
740 PRINT"{up}{right*2}it will describe what it does and"
750 PRINT"{right*2}allow you to either use it or"
760 PRINT"{up}{right*2}return to the main menu."
770 PRINT"{down}{right*2}this program was written by dan"
780 PRINT"{right*2}komaromi of {yellow}digital wizard co.{light blue}"
790 PRINT"{up}{right*2}special thanks to 'qhawk' of the"
800 PRINT"{right*2}clark county commodore computer"
810 PRINT"{up}{right*2}club for having the best user group"
820 PRINT"{right*2}in the world.. and to 'sysop fm'"
830 PRINT"{up}{right*2}from quantum link for doing such"
840 PRINT"{right*2}a totally radical job with the"
850 PRINT"{up}{right*2}software libraries."
851 GOSUB690:PRINT"{home}{down*2}{right*2}if you like this program, or have"
852 PRINT"{up}{right*2}any comments or suggestions, please"
853 PRINT"{right*2}send a postcard to:"
854 PRINT"{right*2}dan komaromi":PRINT"{up}{right*2}251 altura dr.":PRINT"{right*2}fullerton, ca"
855 PRINT"{up}{right*2}92635"
856 PRINT"{down}{right*2}remember that this program is in"
857 PRINT"{right*2}the public domain.{space*2}i encourage"
858 PRINT"{up}{right*2}you to spread this around to all"
859 PRINT"{right*2}of your friends free of chagre."
860 PRINT"{up}{right*2}later, dude!"
861 GETa$:IFa$=""THEN861
870 RUN10
900 GOTO937
902 PRINT"{clear}{light green}{reverse on}O{cm y*38}P";
904 FORi=1TO16:PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";:NEXT
906 PRINT"{reverse on}L{cm p*38}{sh @}";
908 PRINT"{reverse on}O{cm y*38}P";
910 FORi=1TO3:PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";:NEXT
920 PRINT"{reverse on}L{cm p*38}{sh @}";
930 PRINT"{up*3}{right*3}{reverse off}{white}{reverse on}u=use{reverse off}{space*23}{reverse on}m=menu"
932 RETURN
937 GOSUB902:PRINTTAB(11)"{up*2}{reverse on}c=change insults"
940 PRINT"{home}{down*2}{right*2}{light blue}this will cause your computer to"
950 PRINT"{up}{right*2}insult the user whenever a command"
960 PRINT"{right*2}is typed."
962 PRINT"{right*2}{white}effective commands:{cyan} load, save,"
964 PRINT"{up}{right*2}print, poke, peek, list, run, new,"
966 PRINT"{right*2}restore, and clr."
980 PRINT"{yellow}{right*2}press 'c' to modify the insults,"
990 PRINT"{up}{right*2}or 'u' to use the built-in ones."
992 PRINT"{down}{white}{right*2}type {pink}finish{white} to end."
1000 GETa$:IFa$=""THEN1000
1010 IFa$="m"THENRUN10
1020 IFa$="c"THEN1050
1030 IFa$="u"THENskp=5:GOTO1120
1040 GOTO1000
1050 PRINT"{clear}":PRINT"{156}{reverse on}O{cm y*38}P";
1060 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
1070 PRINT"{reverse on}{cm h}{reverse off}{white}{space*11}change insults{space*13}{reverse on}{156}{cm n}";
1080 PRINT"{reverse on}{cm h}"SPC(38)"{cm n}";
1090 PRINT"{reverse on}L{cm p*38}{sh @}";
1100 PRINT"{right*2}{down*2}{white}{reverse off}[f1] {light gray}forward{space*2}{white}[f2] {light gray}reverse"
1110 PRINT"{right*2}{down}{white}[f5] {light gray}change{space*3}{white}[f7] {light gray}done"
1120 FORi=1TO13:READa$:READb$:i$(i,0)=a$:i$(i,1)=b$:NEXT:tn=1:IFskp=5THEN1380
1130 DATA "load","load it yourself!"
1140 DATA "save","why don't you do it instead?"
1150 DATA "print","isn't paper good enough for you?"
1160 DATA "list","the list is in your pocket you fool"
1170 DATA "run","you run, weakling!"
1180 DATA "poke","go poke someone your own size"
1190 DATA "peek","got a staring problem?"
1200 DATA "new","think you can erase me, huh?"
1210 DATA "clr","can't you spell out the whole thing?"
1220 DATA "restore","it's your brain that needs restoring"
1230 DATA "no","yes!!"
1240 DATA "yes","no!!"
1250 DATA "fu","didn't you have enough last night?"
1260 PRINT"{home}{down*14}{right*2}{yellow}#"tn"{left} "
1270 PRINT"{right*2}{down}{light gray}"i$(tn,0);:FORi=1TO38-LEN(i$(tn,0)):PRINT" ";:NEXT
1280 PRINT"{right*2}{green}{E*37}"
1290 PRINT"{right*2}{down*2}{light gray}"i$(tn,1);:FORi=1TO38-LEN(i$(tn,1)):PRINT" ";:NEXT
1300 PRINT"{right*2}{green}{E*37}"
1310 GETx$:IFx$="{f1}"THENtn=tn+1:POKE54296,15:POKE54296,0:IFtn>10THENtn=10
1320 IFx$="{f3}"THENtn=tn-1:POKE54296,15:POKE54296,0:IFtn<1THENtn=1
1330 IFx$="{f5}"THEN1360
1340 IFx$="{f7}"THEN1380
1350 GOTO1260
1360 POKE19,54:PRINT"{home}{white}{down*20}{right*2}";:FORi=1TO80:PRINT" ";:NEXT
1370 PRINT"{home}{down*20}{right*2}";:INPUTn$:i$(tn,1)=n$:GOTO1260
1380 GOTO1399
1381 POKE53280,14:POKE53281,6:PRINT"{clear}{light blue}{down}{right*4}**** commodore 64 basic v2 ****"
1390 PRINT"{down} 64k ram system{space*2}38911 basic bytes free{down}":skp=0:RETURN
1399 GOSUB1381
1400 PRINT"ready."
1410 POKE19,54:INPUTa$:IFa$=""THENPRINT
1420 IFLEFT$(a$,4)="load"THENPRINT:PRINT:PRINTi$(1,1):GOTO1400
1430 IFLEFT$(a$,4)="save"THENPRINT:PRINT:PRINTi$(2,1):GOTO1400
1440 IFLEFT$(a$,5)="print"THENPRINT:PRINT:PRINTi$(3,1):GOTO1400
1450 IFLEFT$(a$,4)="list"THENPRINT:PRINT:PRINTi$(4,1):GOTO1400
1460 IFLEFT$(a$,3)="run"THENPRINT:PRINT:PRINTi$(5,1):GOTO1400
1470 IFLEFT$(a$,4)="poke"THENPRINT:PRINT:PRINTi$(6,1):GOTO1400
1480 IFLEFT$(a$,4)="peek"THENPRINT:PRINT:PRINTi$(7,1):GOTO1400
1490 IFLEFT$(a$,3)="new"THENPRINT:PRINT:PRINTi$(8,1):GOTO1400
1500 IFLEFT$(a$,3)="clr"THENPRINT:PRINT:PRINTi$(9,1):GOTO1400
1510 IFLEFT$(a$,7)="restore"THENPRINT:PRINT:PRINTi$(10,1):GOTO1400
1520 IFLEFT$(a$,2)="no"THENPRINT:PRINT:PRINTi$(11,1):GOTO1400
1530 IFLEFT$(a$,3)="yes"THENPRINT:PRINT:PRINTi$(12,1):GOTO1400
1540 IFLEFT$(a$,2)="fu"THENPRINT:PRINT:PRINTi$(13,1):GOTO1400
1550 IFVAL(LEFT$(a$,2))>0THENPRINT:GOTO1410
1555 IFa$="finish"THENPRINT:PRINT:PRINT"{clear*2}":POKE19,0:RUN10
1560 IFa$<>""THENPRINT:PRINT:PRINT"?syntax{space*2}error":GOTO1400
1580 GOTO1410
1600 GOSUB902
1610 PRINT"{home}{down*2}{right*2}{pink}self destruction{.*3}"
1620 PRINT"{right*2}{white}have you ever seen a computer"
1630 PRINT"{right*2}{up}demolish itself?{space*2}well, you're"
1640 PRINT"{right*2}unsuspecting friend will."
1660 PRINT"{right*2}{yellow}this will make it seem like your"
1670 PRINT"{right*2}{up}commodore is suicidal."
1675 PRINT"{right*2}{down}{156}turn up yer volume!"
1680 GETa$:IFa$=""THEN1680
1690 IFa$="m"THENRUN10
1695 IFa$="u"THEN1700
1697 GOTO1680
1700 GOSUB1381
1710 PRINT"ready."
1720 POKE19,54:INPUTa$
1730 PRINT:PRINT"{down*2}?super syntax error"
1740 FORd=1TO200:POKE54296,15:POKE54296,0:NEXT
1750 PRINT"{clear}":POKE53280,0:POKE53281,0
1760 PRINT"{right*4}{down*5}{white}self destruction{space*2}00 % complete"
1770 FORi=1TO99:PRINT"{home}{down*6}{right*21}{light blue}"i
1780 PRINT"{home}"TAB(16)"{down*10}{yellow}{reverse on}danger{reverse off}";
1785 PRINT"{home}"TAB(16)"{down*10}{red}{reverse on}danger{reverse off}";
1790 FORd=1TO5:POKE54296,15:POKE54296,0:NEXT:NEXT
1800 PRINT"{clear}"
1801 FORr=54272TO54296:POKEr,0:NEXT
1802 POKE54296,15:POKE54277,0
1803 POKE54278,240:POKE54275,8
1804 POKE54276,65:POKE54272,237
1805 POKE54273,50
1810 POKE53296,15:FORi=1TO250
1820 POKE53280,11:POKE53280,12
1830 POKE53280,6:POKE53280,4
1840 POKE53280,14:POKE53280,0
1850 POKE53280,6:POKE53280,0
1860 NEXT:POKE53296,0
1870 POKE53281,1:POKE53280,1:FORd=1TO100:NEXT
1880 POKE53281,15:POKE53280,15:FORd=1TO100:NEXT:GOSUB1930
1890 POKE53281,12:POKE53280,12:FORd=1TO100:NEXT:GOSUB1930
1900 POKE53281,11:POKE53280,11:FORd=1TO100:NEXT:GOSUB1930
1910 POKE53281,0:POKE53280,0:FORd=1TO100:NEXT:GOSUB1930
1920 PRINT"{clear}{black}":POKE54296,0:END
1930 POKE54273,PEEK(54272)/2:FORd=1TO10:NEXT:RETURN
1950 GOSUB902
1960 PRINT"{home}{down*2}{right*2}{white}this is guaranteed to fool even"
1970 PRINT"{up}{right*2}the most intelligent of all nerds."
1980 PRINT"{down}{yellow}{right*2}they will think they're commodore"
1990 PRINT"{right*2}is broken.{space*2}have plenty of tissue"
2000 PRINT"{up}{right*2}paper ready."
2010 PRINT"{down}{156}{right*2}this just makes your computer"
2020 PRINT"{right*2}ignore everything you type.{space*2}it"
2030 PRINT"{up}{right*2}is simple but effective."
2040 GETa$:IFa$=""THEN2040
2050 IFa$="m"THENRUN10
2060 IFa$="u"THEN2080
2070 GOTO2040
2080 GOSUB1381:PRINT"ready."
2100 POKE19,54:INPUTa$
2110 PRINT:GOTO2100
2150 GOSUB902
2160 PRINT"{home}{down*2}{right*2}{white}for the first time, your c64"
2170 PRINT"{up}{right*2}(or c128) is getting sleepy. see"
2180 PRINT"{right*2}what happens when the unsuspecting"
2190 PRINT"{up}{right*2}user tries to wake it up."
2200 PRINT"{down}{right*2}{light green}{z*17}"
2210 GETa$:IFa$=""THEN2210
2220 IFa$="m"THENRUN10
2230 IFa$="u"THEN2250
2240 GOTO2210
2250 GOSUB1381
2260 PRINT"ready."
2270 POKE19,54:INPUTa$
2280 PRINT:PRINT"{down}don't wake me up.{space*2}i'm sleeping."
2290 PRINT"ready."
2300 POKE19,54:INPUTa$
2310 PRINT:PRINT"{down}i said to leave me alone!"
2320 PRINT"ready."
2330 POKE19,54:INPUTa$
2340 PRINT:PRINT"{down}goodnight, i'm turning the lights off!"
2350 FORd=1TO3000:NEXT
2360 POKE53280,15:POKE53281,15
2370 FORd=1TO100:NEXT:POKE53280,12:POKE53281,12:FORd=1TO100:NEXT
2380 POKE53280,11:POKE53281,11:FORd=1TO100:NEXT:POKE53280,0:POKE53281,0
2390 PRINT"{black}{clear}":END
2400 GOSUB902
2410 PRINT"{home}{down*2}{right*2}{pink}this will make your c64 screen"
2420 PRINT"{up}{right*2}look exactly like a c128 screen,"
2430 PRINT"{right*2}but actually be in c64 mode."
2432 PRINT"{right*2}{156}after the 'startup' message is"
2433 PRINT"{up}{right*2}displayed, this program will end"
2434 PRINT"{right*2}so be careful what kind of disk"
2435 PRINT"{up}{right*2}commands you use."
2440 GETa$:IFa$=""THEN2440
2450 IFa$="m"THENRUN10
2460 IFa$="u"THEN2480
2470 GOTO2440
2480 PRINT"{clear}":POKE53280,13:POKE53281,11
2490 PRINT"{light green} commodore basic v7.0 122365 bytes free"
2500 PRINT"{space*3}(c)1985 commodore electronics, ltd."
2510 PRINT"{space*8}(c)1977 microsoft corp."
2520 PRINT"{space*10}all rights reserved"
2530 END
2540 GOSUB902
2550 PRINT"{home}{down*2}{right*2}{white}with 'intruder alert', you can"
2560 PRINT"{up}{right*2}make sure everyone keeps far"
2570 PRINT"{right*2}away from your computer."
2580 PRINT"{yellow}{right*2}you can make up some wild story"
2590 PRINT"{up}{right*2}explaining your new security"
2600 PRINT"{right*2}system."
2602 PRINT"{right*2}{cyan}turn the volume way up!"
2610 GETa$:IFa$=""THEN2610
2620 IFa$="m"THENRUN10
2630 IFa$="u"THEN2650
2640 GOTO2610
2650 GOSUB1381
2660 PRINT"ready."
2670 POKE19,54:INPUTa$:FORi=54272TO54296:POKEi,0:NEXT:POKE54272,12
2671 PRINT"{clear}{white}{down*11}"TAB(12)"intruder alert!!"
2672 POKE54296,15:POKE54277,0:POKE54278,240:POKE54275,8:POKE54276,65
2674 POKE54273,1
2680 POKE53280,0:POKE53281,0
2690 FORi=1TO100:POKE54273,i:NEXT
2700 POKE53280,2:POKE53281,2
2710 FORi=100TO1STEP-1:POKE54273,i:NEXT
2720 GOTO2680
2750 GOSUB902
2760 PRINT"{home}{down*2}{right*2}{cyan}there is nothing worse than a"
2770 PRINT"{up}{right*2}computer trying to flirt with you."
2780 PRINT"{down}{right*2}{pink}try this one on your friends and"
2790 PRINT"{right*2}they will be in for a big surprise!"
2800 GETa$:IFa$=""THEN2800
2810 IFa$="m"THENRUN10
2820 IFa$="u"THEN2840
2830 GOTO2800
2840 GOSUB1381
2850 PRINT"ready."
2860 POKE19,54:INPUTa$
2870 PRINT:PRINT"{down}my, what beutiful fingers you have!":PRINT"ready."
2880 POKE19,54:INPUTa$
2890 PRINT:PRINT"{down}i love the way you stroke my keys!":PRINT"ready."
2900 POKE19,54:INPUTa$
2910 PRINT:PRINT"{down}touch me like that again please":PRINT"ready."
2920 POKE19,54:INPUTa$
2930 PRINT:PRINT"{down}yes, i love you too":PRINT"ready."
2940 POKE19,54:INPUTa$
2950 PRINT:PRINT"{down}bye dear, talk to you later, eh?"
2960 POKE19,0:END
3000 GOSUB902
3010 PRINT"{home}{down*2}{right*2}{156}you are about to enter a"
3020 PRINT"{up}{right*2}different dimension - not only"
3030 PRINT"{right*2}of sight and sound but of mischief."
3040 PRINT"{right*2}{yellow}doo de do da{.*3}"
3050 GETa$:IFa$=""THEN3050
3060 IFa$="m"THENRUN10
3070 IFa$="u"THEN3090
3080 GOTO3050
3090 GOSUB1381
3100 PRINT"ready."
3102 FORr=54272TO54296:POKEr,0:NEXT
3103 POKE54296,15:POKE54277,0:POKE54278,240:POKE54275,8:POKE54276,65
3104 POKE54272,12
3110 POKE19,54:INPUTa$
3120 FORi=1TO25:PRINT:NEXT
3130 PRINT"{clear}":POKE53280,0:POKE53281,0
3140 a$="you have just entered the twilight zone!"
3150 PRINT"{down*10}"
3160 FORi=1TOLEN(a$):PRINTMID$(a$,i,1);:FORd=1TO100:NEXT:POKE54273,255
3170 POKE54273,200:NEXT
3180 FORi=255TO0STEP-1:POKE54273,i:NEXT
3200 POKE54273,50:FORi=1TO50:POKE53280,0:POKE53280,5:NEXT
3210 POKE54273,60:FORi=1TO50:POKE53280,0:POKE53280,6:NEXT
3220 POKE54273,70:FORi=1TO50:POKE53280,0:POKE53280,2:NEXT:POKE53280,0
3230 FORxx=54272TO54295:POKExx,0:NEXT:POKE54296,15:POKE54277,8:POKE54278,255
3231 POKE54276,23:yy=4:FORzz=1TO3:POKE54287,yy:FORxx=1TO150:POKE54273,xx
3232 POKE53280,6:POKE53280,5:yy=yy+.01:NEXT:NEXT:POKE54278,15
3233 GOTO3230
3250 GOSUB902
3260 PRINT"{home}{down*2}{right*2}{light blue}are you getting sick of always"
3270 PRINT"{up}{right*2}seeing 38911 bytes free?"
3280 PRINT"{down}{right*2}{yellow}this will get rid of 'em."
3290 GETa$:IFa$=""THEN3290
3300 IFa$="m"THENRUN10
3310 IFa$="u"THEN3330
3320 GOTO3290
3330 GOSUB1381:PRINT"ready."
3340 POKE19,54:INPUTa$
3345 PRINT:PRINT"{down*3}ouch!!{space*2}don't hit my keyboard so hard!!"
3350 PRINT:PRINT"{down*3}i'm going to punish you by taking"
3360 PRINT"away your available ram memory."
3370 FORi=38911TO0STEP-1
3380 PRINT"{home}{down*3}{right*16}"i
3390 NEXT
4000 GOSUB902
4010 PRINT"{home}{down*2}{right*2}{white}scare 'em into thinking they"
4020 PRINT"{up}{right*2}destroyed your computer."
4030 PRINT"{cyan}{down}{right*2}prepare to recieve kindness and/or"
4040 PRINT"{right*2}loans from your victims."
4050 GETa$:IFa$=""THEN4050
4060 IFa$="m"THENRUN10
4070 IFa$="u"THEN4090
4080 GOTO4050
4090 GOSUB1381
4100 PRINT"ready."
4110 POKE19,54:INPUTa$
4120 POKE53280,0:POKE53281,0
4130 PRINT"{clear}{pink}{down*10}{right*10}computer malfunction"
4140 FORr=54272TO54296:POKEr,0:NEXT
4150 POKE54296,15:POKE54277,0:POKE54278,240:POKE54275,8:POKE54276,65
4160 POKE54272,12
4170 POKE54273,10
4180 FORi=1TO50
4190 PRINTSPC(i);"{left} {yellow}{sh asterisk}";:POKE54273,15:POKE54273,25
4200 NEXT:POKE54273,20:POKE53280,1
4300 FORd=1TO100:NEXT:PRINT"{pink}{right*5}computer malfunction":POKE53280,0:GOTO4180
4350 GOSUB902
4360 PRINT"{home}{right*2}{down*2}{light blue}with this, you can enter your"
4370 PRINT"{up}{right*2}own personal message to be seen"
4380 PRINT"{right*2}after the user hits return."
4390 PRINT"{right*2}{yellow}it will allow up to 10 lines."
4400 GETa$:IFa$=""THEN4400
4410 IFa$="m"THENRUN10
4420 IFa$="u"THEN4431
4430 GOTO4400
4431 PRINT"{clear}{cyan}you have up to 10 lines of text for"
4432 PRINT"your message.{space*2}hit return to skip"
4433 PRINT"remaining lines.{space*2}start entering:{down*3}{green}"
4434 POKE19,54:FORi=0TO10:INPUTm$(i):PRINT:NEXT
4435 PRINT"{down*2}{reverse on}{light blue}hit any key to start"
4436 GETa$:IFa$=""THEN4436
4440 GOSUB1381
4450 PRINT"ready."
4460 POKE19,54:INPUTa$
4470 PRINT:PRINT:FORi=0TO10:PRINTm$(i):NEXT
4474 POKE19,0
4475 END
4500 GOSUB902
4510 PRINT"{home}{down*2}{right*2}{156}this will freak 'em out by"
4520 PRINT"{up}{right*2}allowing your commodore control"
4530 PRINT"{right*2}itself."
4540 PRINT"{right*2}{yellow}it will seem like it's writing"
4550 PRINT"{up}{right*2}and executing a small program."
4560 GETa$:IFa$=""THEN4560
4570 IFa$="m"THENRUN10
4580 IFa$="u"THEN4600
4590 GOTO4560
4600 GOSUB1381
4610 PRINT"ready."
4620 POKE19,54:INPUTa$
4630 PRINT:a$="let me take over now."
4635 GOTO4650
4640 FORi=1TOLEN(a$):PRINTMID$(a$,i,1);:FORd=1TO200
4642 NEXT:NEXT:PRINT:RETURN
4650 GOSUB4640:FORd=1TO300:NEXT
4660 PRINT:a$="10 print"+CHR$(34)+"hello"+CHR$(34)
4670 GOSUB4640
4680 a$="20 goto 10"
4690 GOSUB4640
4691 PRINT:a$="run":GOSUB4640
4700 PRINT:FORd=1TO750:NEXT
4710 PRINT"hello"
4720 GOTO4710
4800 GOSUB902
4810 PRINT"{home}{down*2}{right*2}{yellow}scare 'em into thinking they"
4820 PRINT"{up}{right*2}broke into the defense department"
4830 PRINT"{right*2}with your modem."
4840 PRINT"{right*2}{light blue}if you don't have a modem, they'll"
4850 PRINT"{up}{right*2}think you have one."
4860 GETa$:IFa$=""THEN4860
4870 IFa$="m"THENRUN10
4880 IFa$="u"THEN4900
4890 GOTO4860
4900 GOSUB1381
4920 FORr=54272TO54296:POKEr,0:NEXT
4930 POKE54296,15:POKE54277,0:POKE54278,240:POKE54275,8:POKE54276,65
4960 PRINT"ready.":POKE19,54:INPUTa$
4970 PRINT:PRINT"{down}dialing norad defense systems{.*3}":POKE54272,12
4980 FORi=1TO4:FORj=1TO25
4990 POKE54273,50:POKE54273,60
5000 FORd=1TO25:NEXT:NEXT:POKE54273,0:FORd=1TO750:NEXT:NEXT
5010 PRINT"{down*2}connect on -- 9600 bps"
5020 PRINT"{down}{right*2}** us government defense systems **"
5030 PRINT"{down}password:";
5040 POKE19,54:INPUTa$
5050 PRINT:PRINT"{down*2}logon complete."
5060 PRINT"{down}welcome, officer nettles."
5070 PRINT"{down}command:";
5080 POKE19,54:INPUTa$:PRINT
5090 PRINT"{down*2}missle silos activated."
5100 FORd=1TO1000:NEXT
5110 PRINT"{down*2}launch confirmation recieved."
5120 FORd=1TO950:NEXT
5130 PRINT"{down*2}launching nuclear warhead #";INT(RND(1)*5000+1)+4000
5135 FORd=1TO1000:NEXT
5140 PRINT:GOTO5070
5200 GOSUB902
5210 PRINT"{home}{down*2}{right*2}{yellow}every time the user types a"
5220 PRINT"{up}{right*2}command, the computer will mix"
5230 PRINT"{right*2}up one of his/her characters and"
5240 PRINT"{up}{right*2}give 'em a syntax error."
5250 PRINT"{down}{right*2}{cyan}is that frustration or what?"
5260 GETa$:IFa$=""THEN5260
5270 IFa$="m"THENRUN10
5280 IFa$="u"THEN5300
5290 GOTO5260
5300 GOSUB1381
5310 PRINT"ready."
5320 POKE19,54:INPUTa$:IFa$=""THENPRINT:GOTO5320
5330 l=LEN(a$)
5340 p=INT(RND(1)*l+1)
5350 c$=MID$(a$,p,1)
5360 h$=CHR$(ASC(c$)+1)
5370 PRINT:PRINTTAB(p-1)"{up}";h$
5380 PRINT:PRINT"?syntax{space*2}error"
5390 GOTO5310
5400 GOSUB902
5410 PRINT"{home}{down*2}{right*2}{156}you always wanted to have an"
5420 PRINT"{up}{right*2}earthquake occur on your computer"
5430 PRINT"{right*2}screen, right?{space*2}here it is."
5440 PRINT"{right*2}{cyan}8.2 on the richter scale."
5450 GETa$:IFa$=""THEN5450
5460 IFa$="m"THENRUN10
5470 IFa$="u"THEN5490
5480 GOTO5450
5490 GOSUB1381
5500 PRINT"ready."
5510 POKE19,54:INPUTa$
5511 FORr=54272TO54296:POKEr,0:NEXT
5512 POKE54296,15:POKE54277,0:POKE54278,240:POKE54275,8:POKE54276,129
5513 POKE54272,12
5514 POKE54273,1
5520 PRINT"{home}{down*11}{right*8}internal micro-quake!"
5530 IFo>5THENx=INT(RND(1)*10+1):o=o-(x/2):POKE54273,o
5540 IFo<10THENy=INT(RND(1)*10+1)+20:o=o+y:POKE54273,o
5550 POKE53270,x:POKE53265,y:GOTO5530
6000 IFPEEK(808)=237THEN6040
6010 PRINT"{home}"TAB(25)"{down*13}{yellow}disable stop"
6020 POKE808,237:POKE54296,15:POKE54296,0
6030 GOTO290
6040 PRINT"{home}"TAB(25)"{down*13}{yellow}enable stop "
6050 POKE808,234:POKE54296,15:POKE54296,0
6060 GOTO290
7000 m$="{right}m a x i m u m{space*2}o v e r d r i v e"
7010 IFc=1THENPRINT"{home}{down*2}{right*3}{white}"m$:FORd=1TO100:NEXT
7020 IFc=2THENPRINT"{home}{down*2}{right*3}{light gray}"m$
7030 IFc=3THENPRINT"{home}{down*2}{right*3}{gray}"m$
7040 IFc=4THENPRINT"{home}{down*2}{right*3}{dark gray}"m$
7050 IFc=5THENPRINT"{home}{down*2}{right*3}{gray}"m$
7060 IFc=6THENPRINT"{home}{down*2}{right*3}{light gray}"m$
7070 IFc=7THENc=0
7080 c=c+1:FORd=1TO25:NEXT:RETURN
stop tok64
(bastext 1.0)