start tok64 d64-7IwCAD
100 POKE53281,1:PRINT"{clear}"SPC(250)"{black}{space*2}word match "
110 FORp=1TO2e3:NEXT:PRINTSPC(90)"{blue}{space*2}touch a key{.*3}"
120 GETa$:IFa$=""THEN120
130 DIMn$(12):PRINT"{blue}{clear}names, please!"
140 PRINT"{home}{down*15}to play against the computer,"
145 PRINT"enter '64' as player two"
150 PRINT"{home}{down}":FORn=1TO2:PRINT"{down}player"n;:INPUTn$(n):NEXT:PRINT"{clear}"
160 o=54272
161 s=54272:FORe=sTOs+28:POKEe,0:NEXT
162 POKE54296,15:POKE54277,66:POKE54278,210
163 POKE54276,17:POKE54272,63
164 j=20:FORt=1TO200:POKE54273,j:j=RND(0)*150+1:NEXT:POKE54276,16
165 FORt=1TO200:NEXT
170 DIMw$(12),r%(28),w1$(6),c%(2),sq%(12),bk%(2)
180 DATAcar,cat,boy,hat,hit,top,ate,eat,pit,pat,got,him,her,why,how,tin,ill,who
190 DATArun,you,ace,bed,ink,aim,art,tot,tie,end
200 FORn=1TO28
210 z=INT(RND(1)*28)+1:IFr%(z)<>0THEN210
220 r%(z)=n:NEXT
230 FORn=1TO6:FORq=1TOr%(n):READw$:NEXT:w1$(n)=w$:RESTORE:NEXT
235 FORq=1TO28:READw$:NEXT
240 c%(1)=2:c%(2)=5:bk%(1)=172:bk%(2)=236
250 FORn=1TO12:r%(n)=0:NEXT
260 FORn=1TO11STEP2
270 z=INT(RND(1)*12)+1:y=INT(RND(1)*12)+1
280 IFr%(z)<>0ORr%(y)<>0ORz=yTHEN270
290 r%(z)=n:r%(y)=n+1
300 NEXT
310 FORn=1TO12:r%(n)=INT((r%(n)-1)/2)+1:w$(n)=w1$(r%(n)):NEXT
320 FORn=1TO4
330 PRINT"{black} {reverse on}{space*31}"
340 FORz=1TO3
350 PRINT" {reverse on} {reverse off}{space*9}{reverse on} {reverse off}{space*9}{reverse on} {reverse off}{space*9}{reverse on} {reverse off}"
360 NEXTz,n
370 PRINT" {reverse on}{space*31}"
380 PRINT"{home}{down*2}{156}"
390 FORn=1TO9STEP3
400 PRINTTAB(5)nSPC(7)n+1SPC(7)n+2
410 PRINT"{down*2}":NEXT
420 PRINT"{right*6}10{right*8}11{right*8}12"
430 d$="{home}{down*18}"
440 sp$="{space*39}"
450 PRINTd$sp$sp$
460 FORn=1TO12:READsq%(n):NEXT
470 DATA1108,1118,1128,1268,1278,1288,1428,1438,1448,1588,1598,1608
480 REM game
490 x=1
500 PRINTd$"{red}which blocks, "n$(x)"/"
510 POKEbk,bk%(x)
520 IFn$(x)="64"THENGOSUB1070
530 PRINTd$"{down}"sp$d$"{down}{156}{reverse on}block a?{black}{reverse off}";
540 GETa$:IFa$=CHR$(13)THENi=VAL(an$):an$="":GOSUB1060:ON(i>12)+2GOTO530,570
550 IFa$<"0"ORa$>"9"THEN540
560 PRINTa$;:an$=an$+a$:GOTO540
570 ON(r%(i)=0)+2GOTO530,650
580 PRINTd$"{down*2}"sp$d$"{down*2}{blue}{reverse on}block b?{black}{reverse off}";:
590 GETa$:IFa$=CHR$(13)THENj=VAL(an$):an$="":GOSUB1060:ON(j>12)+2GOTO580,620
600 IFa$<"0"ORa$>"9"THEN590
610 PRINTa$;:an$=an$+a$:GOTO590
620 ON(r%(j)=0)+2GOTO580,630
630 IFi=jTHEN580
640 PRINTd$sp$sp$sp$sp$;:GOTO680
650 FORn=1TO3
660 POKEsq%(i)+n+40+o,6:POKEsq%(i)+n+40,ASC(MID$(w$(i),n,1))-64:NEXT
670 ON(n$(x)="64")+2GOTO1090,580
680 FORn=1TO3
690 POKEsq%(j)+n+40+o,6:POKEsq%(j)+n+40,ASC(MID$(w$(j),n,1))-64
700 NEXT
710 IFr%(i)=r%(j)THEN810
720 PRINTd$sp$d$TAB(12)"{red}{reverse on}no match-{reverse off}"
730 REM no match
731 s=54272:FORe=sTOs+28:POKEe,0:NEXT
732 POKE54296,15:POKE54277,51:POKE54278,164
733 POKE54275,8:POKE54274,100
734 POKE54273,2:POKE54272,135:POKE54276,65
735 FORt=1TO200:NEXT:POKE54276,64
740 FORp=1TO2e3:NEXT:PRINTd$sp$
750 i$=STR$(i):i$=RIGHT$(i$,LEN(i$)-1):j$=STR$(j):j$=RIGHT$(j$,LEN(j$)-1)
760 POKEsq%(i)+41,32:POKEsq%(j)+41,32:POKEsq%(i)+43,32:POKEsq%(j)+43,32
770 FORn=1TOLEN(i$):POKEsq%(i)+41+n,ASC(MID$(i$,n,1)):POKEsq%(i)+41+n+o,4:NEXT
780 FORn=1TOLEN(j$):POKEsq%(j)+41+n,ASC(MID$(j$,n,1)):POKEsq%(j)+41+n+o,4:NEXT
790 IFx=1THENx=2:GOTO500
800 x=1:GOTO500
810 REM rightans
820 PRINTd$sp$sp$d$"{space*12}{black}{156}{reverse on}match{!*4}{reverse off}"
830 REM match!!
831 s=54272:FORe=sTOs+28:POKEe,0:NEXT
832 POKE54296,10:POKE54277,35:POKE54278,163
833 POKE54273,33:POKE54272,135:POKE54276,17
834 FORt=1TO100:NEXT
835 POKE54273,42:POKE54272,62  :POKE54276,17
836 FORt=1TO100:NEXT
837 POKE54273,50  :POKE54272,60  :POKE54276,17
838 FORt=1TO600:NEXT:POKE54276,16
840 IFx=1THENs1=s1+1
850 IFx=2THENs2=s2+1
860 FORp=1TO2e3:NEXT
870 q=sq%(i):r=sq%(j)
880 FORn=1TO3
890 FORw=q-2TOq+6:POKEw+o,c%(x):POKEw,160:NEXT:q=q+40:NEXT
900 FOR n=1TO3
910 FORw=r-2TOr+6:POKEw+o,c%(x):POKEw,160:NEXT:r=r+40:NEXT
920 PRINTd$sp$
930 cr=cr+1:IFcr=6THEN960
940 r%(i)=0:r%(j)=0
950 GOTO 500
960 FORn=1TO5:FORz=250TO150STEP-2:POKEs,z:NEXTz,n:POKEs,0
970 PRINTd$" the game is over-
980 FORp=1TO2e3:NEXT
990 IFs1>s2THENPRINTd$sp$d$n$(1)" wins{!*3}"
1000 IFs2>s1THENPRINTd$sp$d$n$(2)" wins{!*3}"
1010 IFs2=s1THENPRINTd$sp$d$" it's a tie{!*3}"
1020 FORp=1TO2e3:NEXT:PRINTd$"{down}want another?(y/n)"
1030 GET a$ :IFa$="n"THEN PRINT"{clear}{blue}":POKEbk,27:END
1040 IFa$="y"THEN RUN 130
1050 GOTO 1030
1060 REM sound for beginning
1061 s=54272:FORe=sTOs+28:POKEe,0:NEXT
1062 POKE54296,15:POKE54277,51:POKE54278,246
1063 POKE54276,17  :POKE54273,1  :POKE54272,135
1064 FORt=1TO200STEP16  :POKE54273,t/2+50:NEXT:POKE54276,16:FORt=1TO500:NEXT
1065 RETURN
1070 REM c-64 plays
1080 i=INT(RND(1)*12)+1:ON(r%(i)=0)+2GOTO1080,650
1090 j=INT(RND(1)*12)+1:IFj=iTHEN1090
1100 IFr%(j)=0THEN1090
1110 PRINTd$sp$d$"64 picks"i"and"j"{left}."
1120 FORp=1TO2e3:NEXT:GOTO680
stop tok64
(bastext 1.0)