start tok64 d64-DKfyIg
100 POKE51,255:POKE52,79:CLR:POKE53280,0:POKE53281,0:PRINTCHR$(14)CHR$(8)
110 RESTORE:GOSUB730:ta=2:DIMhd(24),hd$(24)
120 si=54272:POKE54295,0:POKE54296,15:POKEsi+2,0:POKEsi+3,8
130 POKEsi+5,0:POKEsi+6,240:POKEsi+4,17:si=54273
140 DIMj(255):j(120)=1:j(247)=2:j(208)=3:j(160)=4:j(234)=5
150 PRINT"{clear}"CHR$(142)"highscore to date{light blue}"hd
160 a=1024:x=0:x1=1:y=21:y1=-1:p1=a+960:l=1884:zx%=1:an=0
170 FORi=1TOta:POKE2023-i,81:POKE56295-i,7:NEXT
180 PRINT"{down}{reverse on}{orange}{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P"
190 PRINT"{up}{reverse on} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n}"
200 PRINT"{up}{reverse on}{green}{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P"
210 PRINT"{up}{reverse on} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n}"
220 PRINT"{up}{reverse on}{blue}{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P"
230 PRINT"{up}{reverse on} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n}"
240 PRINT"{up}{reverse on}{gray}{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P{cm y}P"
250 PRINT"{up}{reverse on} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n} {cm n}{down*13}{dark gray}{reverse off}{cm u*4}"
260 PRINT"{orange}your score:{gray}"pu"{up}":FORi=0TO400:NEXT
270 POKEsi+3,17
280 SYS20481:POKEsi,0:sw=sw+1:IFsw=4THENsw=0:SYS20481
290 GETbr$:IFbr$<>" "THEN310
300 GETbr$:IFbr$<>" "THEN300
310 x=x+x1:IFx<0ORx>39THENx=x-x1:x1=-SGN(x1)*INT(2*RND(1)+1):POKEsi,10
320 y=y+y1
330 IFy<1THENy=y-y1:y1=-y1:POKEsi,15
340 IFzx%=0THENIFPEEK(p1)<>120THENPOKEp1,32
350 zx%=0:p1=a+40*y+x:IFy>23THEN540
360 IFPEEK(p1)<>32THEN380
370 POKEp1,81:POKEp1+54272,7:GOTO280
380 dd=PEEK(p1)
390 ONj(dd)GOTO410,420,440,460,480
400 GOTO520
410 y1=-y1:POKEp1,120:POKEp1+54272,11:POKEsi,20:POKEsi,15:zx%=1:GOTO280
420 POKEp1,32:POKEp1+1,32:POKEp1+40,32:POKEp1+41,32:POKEsi,y*8:POKEsi,y*5
430 GOTO490
440 POKEp1,32:POKEp1-1,32:POKEp1+39,32:POKEp1+40,32:POKEsi,y*8:POKEsi,y*5
450 GOTO490
460 POKEp1,32:POKEp1+1,32:POKEp1-39,32:POKEp1-40,32:POKEsi,y*8:POKEsi,y*5
470 GOTO490
480 POKEp1,32:POKEp1-1,32:POKEp1-41,32:POKEp1-40,32:POKEsi,y*8:POKEsi,y*5
490 pu=pu+(12-y)*5:an=an+1:IFan>79THENan=0:GOSUB950:PRINT"{clear}":POKE20480,1:GOTO150
500 pn=pn+(12-y)*5
510 IFpn>5000THENpn=0:ta=ta+1:POKE2023-ta,81:POKE56295-ta,7:GOSUB880
520 PRINT"{orange}your score:{gray}"pu"{up}"
530 y1=-y1:POKEp1,81:POKEp1+54272,7:GOTO280
540 x=0:x1=INT(2*RND(1)+1):y=21:y1=-1
550 POKE2023-ta,32
560 ta=ta-1:IFta>=0THENPOKEsi+3,33:FORi=70TO180:GOSUB720:NEXT:zx%=1:GOTO270
570 PRINT"{clear}{blue}{space*6}{cm a}{sh asterisk*22}{cm s}"CHR$(14)
580 PRINT"{space*6}{sh -}{space*22}{sh -}"
590 PRINT"{space*6}{sh -} {dark gray}{reverse on} G a m e{space*2}o v e r{space*3}{reverse off}{blue} {sh -}"
600 PRINT"{space*6}{sh -}{space*22}{sh -}"
610 PRINT"{space*6}{cm z}{sh asterisk*22}{cm x}"
620 FORi=0TO10:POKEsi,i*2:PRINT"{home}{down*2}"TAB(8)"{green} G a m e{space*2}o v e r ! ":GOSUB1000
630 POKEsi,20-i*2:PRINT"{home}{down*2}"TAB(8)"{reverse on}{dark gray} G a m e{space*2}o v e r ! {reverse off}":GOSUB1000:NEXT
640 PRINT"{cm -}{down*3}{space*9}Your score:"pu
650 FORi=0TO800:NEXT:POKE198,0
660 ta=0:IFpu>hdTHENhd=pu:PRINT"{orange}{down}{space*4}Well done, new high score !!"
670 GOSUB1010
680 PRINT"{home}{down*23} {reverse on}{space*2}For playing again, press any key ! {home}"
690 an=0:pu=0:pn=0:ta=2
700 IF PEEK(203)=64ANDPEEK(653)=0THEN700
710 PRINT"{clear}":POKE20480,1:GOTO150
720 POKEsi,i/4:POKEsi,i/3:POKEsi,i/6:RETURN
730 PRINT"{141}{clear}{reverse on}{space*11}Use following keys{space*12}"
740 PRINT"{orange}{down}{space*16}{cm a}{sh asterisk*3}{cm r}{sh asterisk*3}{cm s}"
750 PRINT"{space*7}{gray}{reverse on}Left{reverse off}{orange} <-- {orange}{sh -}{dark gray}{reverse on} N {reverse off}{orange}{sh -}{dark gray}{reverse on} M {reverse off}{orange}{sh -} --> {gray}{reverse on}Right{reverse off}"
760 PRINT"{orange}{space*16}{cm z}{sh asterisk*3}{cm e}{sh asterisk*3}{cm x}"
770 PRINT"{down}{brown} You{space*2}must hit with{space*2}your{space*2}racket and a"
780 PRINT"{down} ball{space*2}the bricks out{space*2}of the wall ! If"
790 PRINT"{down} the ball drops{space*2}down the floor you get"
800 PRINT"{down} a new one. At beginning you have three"
810 PRINT"{down} balls, but{space*2}every 5{0*3}{space*2}points you get"
820 PRINT"{down} one more. When{space*2}no balls are left, you"
830 PRINT"{down} lose and the game breaks."
840 PRINT"{down*2}{green}{reverse on}{space*3}All right ?{space*2}Then press any key !{space*4}{home}"
850 y=700:FORi=20480TO20549:READa:POKEi,a:NEXT
860 y=y-1:IFy>0ANDPEEK(203)=64ANDPEEK(653)=0THEN860
870 RETURN
880 PRINT"{orange}your score:{gray}"pu"{up}":POKEsi+3,65
890 POKEp1,81:POKEp1+54272,7:FORi=0TO100
900 PRINT"{home}{down*15}{orange}"TAB(8)"***** new ball ! *****"
910 POKEsi,i:POKEsi,i/2:POKEsi,100-i
920 PRINT"{home}{down*15}{reverse on}{dark gray}"TAB(8)"***** new ball ! *****{reverse off}"
930 NEXT:PRINT"{home}{down*15}"TAB(8)"{space*22}{down*8}"
940 POKEsi+3,17:RETURN
950 PRINT"{orange}your score:{gray}"pu"{up}":POKEsi+3,65
960 FORi=0TO180:POKEsi+3,17:POKEsi,i/3:POKEsi+3,33:POKEsi,i/2.5
970 POKEp1,81:POKEp1+54272,7
980 POKEsi+3,65:POKEsi,90-i/2:NEXT
990 POKEsi+3,17:RETURN
1000 FORj=0TO100:NEXT:RETURN
1010 PRINT"{home}{down*10}{dark gray}{space*5}Please give your initials :"
1020 PRINT"{down}{orange}{space*10}{reverse on}{space*3}M{space*3}{reverse off} {brown}-->{space*2}up
1030 PRINT"{orange}{space*10}{reverse on}{space*3}N{space*3}{reverse off} {brown}-->{space*2}down
1040 PRINT"{orange}{space*10}{reverse on} Space {reverse off} {brown}-->{space*2}fix
1050 PRINT"{light blue}{down*3}"TAB(18)"{-*3}"
1060 PRINT"{home}{down*17}":POKE650,128:le=64:le$="":POKEsi+3,65
1070 FORi=0TO2
1080 GETa$:IFa$<>"m"ANDa$<>"n"ANDa$<>" "THEN1080
1090 POKEsi,le:POKEsi,le/3
1100 IFa$="m"THENle=le+1:IFle>90THENIFle<95THENle=95
1110 IFa$="m"THENIFle>95THENle=45
1120 IFa$="m"THENIFle>45THENIFle<65THENle=65
1130 IFa$="n"THENle=le-1:IFle<45THENle=95
1140 IFa$="n"THENIFle<95THENIFle>90THENle=90
1150 IFa$="n"THENIFle<65THENIFle>45THENle=45
1160 IFa$<>" "THEN1220
1170 IFle=95THENle$="":i=0:PRINT"{home}{down*18}"TAB(18)"{-*3}":le=65:GOTO1220
1180 IFle=45THENle=32:GOTO1200
1190 le=le+128
1200 le$=le$+CHR$(le):FORj=0TO100:NEXT:POKEsi,0:le=45
1210 PRINT"{home}{down*18}"TAB(18)le$:GOTO1250
1220 IFle<>45ANDle<>95THENze=le+128:GOTO1240
1230 ze=le
1240 POKEsi,0:PRINT"{home}{down*18}"TAB(18+i)CHR$(ze):GOTO1080
1250 NEXTi
1260 PRINT"{home}{down*10}{space*32}"
1270 PRINT"{down}{space*30}"
1280 PRINT"{space*31}"
1290 PRINT"{space*31}"
1300 PRINT"{down*3}"TAB(18)"{space*3}"
1310 FORi=1TO24
1320 IFpu>hd(i)THENGOSUB1420:i=24
1330 NEXT
1340 IFle><45THENze=le+32
1350 PRINT"{home}{down*8}{green} {reverse on}{space*9}Hall of fame:{space*14}{down}{reverse off}"
1360 FORi=1TO12:PRINT"{orange}";
1370 PRINTTAB(3)RIGHT$("{space*2}"+STR$(i),2)"{space*2}{brown}"RIGHT$("{space*7}"+STR$(hd(i)),6);
1380 PRINT" {dark gray}"hd$(i)"{orange}";
1390 PRINTTAB(22)RIGHT$("{space*2}"+STR$(i+12),2)"{space*2}{brown}"RIGHT$("{space*7}"+STR$(hd(i+12)),6);
1400 PRINT" {dark gray}"hd$(i+12)
1410 NEXT:RETURN
1420 FORj=24TOiSTEP-1
1430 hd(j)=hd(j-1):hd$(j)=hd$(j-1)
1440 NEXT
1450 hd(i)=pu:hd$(i)=le$:RETURN
1460 DATA1,164,203,174,,80,192,36,240,29,192,39,240,1,96,202,208,1,96,142,,80
1470 DATA169,120,157,151,7,169,11,157,151,219,232,169,32,157,155,7,96,232,224,37
1480 DATA 208,1,96,142,,80,169,120,157,155,7,169,11,157,155,219,202,169,32,157
1490 DATA151,7,96,,,,,
stop tok64
(bastext 1.0)