start tok64 d64-alTv7y
0 REM       >menu creator v4.1<
1 :
2 REM    (c) 1987 by:  rocky moore
3 :
4 SYS65418:k=PEEK(45)+PEEK(46)*256:a=k-1094:p=k-1027:SYSa:t$(0)=",8":t$(1)=",8,1"
5 ln$="{sh asterisk*10}":ln$="{pink}"+ln$+ln$+ln$+ln$:sp$="{space*19}":sp$=sp$+sp$
6 POKE53280,12:POKE53281,0:y=1:r$(0)="{reverse on}{white}":r$(1)="{reverse off}{light blue}":x(0)=2:x(1)=22
8 READn:n=n-1:DIMs(n),f$(n),t(n),e$(n),c$(n)
10 FORi=0TOn:READs(i),f$(i),t(i),e$(i),c$(i):NEXT
12 PRINT"{clear}";CHR$(9)CHR$(142)CHR$(8):y=0:SYSp,14,0:PRINT"{light blue}U{cm r}IU{sh asterisk}IUIIU I"
13 SYSp,36,0:PRINT"{yellow}v{white}4{yellow}.{white}1"
14 SYSp,14,1:PRINT"{blue}{sh -*3}{cm q}{sh asterisk} {sh -*4} {sh -}"
16 SYSp,14,2:PRINT"{156}J KJ{sh asterisk}KJJKJ{sh asterisk}K":mx=15:IFmx>(n-g)THENmx=n-g
18 SYSp,8,4:PRINT"{red}created by:{space*2}{white}rocky moore":r=1:PRINTln$
19 flash=1
20 a$="(c) 1987 software unlimited"
21 x=20-LEN(a$)/2:SYSp,x,6:PRINT"{cyan}";a$
22 FORy=0TOmx:GOSUB50:NEXT:y=0:SYSp,5,22:PRINT"{156}use cursor key to move cursor"
24 SYSp,15,18:PRINT"{pink}comment{yellow}:"
26 SYSp,0,21:PRINTln$
28 i=23:IFn>mxTHENi=24:SYSp,4,23:PRINT"{yellow}press the [n] key for next page"
30 SYSp,6,i:PRINT"{cyan}press [return] to load file{home}":POKE198,0
32 r=(r+1)*-(r<1):GOSUB50:t=0
34 GETa$:t=t+1:IFa$=""ANDt<20THEN34
36 IFa$="{down}"THENr=1:GOSUB50:y=y+1:GOSUB56:GOTO32
38 IFa$="{right}"ANDy+8<mx+1THENr=1:GOSUB50:y=y+8:GOSUB56:GOTO32
40 IFa$="{up}"THENr=1:GOSUB50:y=y-1:GOSUB56:GOTO32
42 IFa$="{left}"ANDy-8=>0THENr=1:GOSUB50:y=y-8:GOSUB56:GOTO32
44 IFa$="n"THENg=(g+16)*-(g<=n-16):GOTO12
46 IFa$=CHR$(13)THEN62
48 GOTO32
50 rl=y-(8*-(y=>8)):SYSp,x(-(y=>8)),rl+9:PRINTr$(r);LEFT$(f$(y+g),16)
52 SYSp,1,20:a$=LEFT$(c$(y+g),38):a=LEN(a$):b$=LEFT$(sp$,19-a/2)
54 PRINT"{reverse off}";b$;a$;b$:RETURN
56 IFy>mxTHENy=0
58 IFy<0THENy=mx
60 RETURN
62 IFs(y+g)THENSYS52224:IF flash=0THENPOKE52722,173
64 PRINT"{clear}{down*3}{black}load";CHR$(34);f$(y+g);CHR$(34);t$(t(y+g)):PRINT"{down*4}";e$(y+g);CHR$(9);"{home}{white}"
66 POKE631,13:POKE632,13:POKE198,2:END
68 :
70 :
98 REM 0=no warp/drive   0= ",8"
100 DATA 16 :REM number filenames
101 DATA 0,"dds", 0,"run","makes a library list"
102 DATA 0,"tape-log", 0,"run","stores your programs on tape"
103 DATA 0,"dir-mod", 0,"run","let's you re-arrange the directory"
104 DATA 0,"sdc", 0,"run","rocky's copy with 1-1541"
105 DATA 0,"s7", 0,"run",""
106 DATA 0,"menu creator", 0,"run","makes a menu like this one"
107 DATA 0,"rocky labeler", 0,"run","prints mailing labels"
108 DATA 0,"graphics 3.5", 0,"run","adds 52 graphics commands to basic"
109 DATA 0,"sd.copy v/2.0", 0,"run","same as sdc{.*3}?"
110 DATA 0,"restore-id.name", 0,"run","this is for when you oops your header"
111 DATA 0,"fast format", 0,"run","formats a disk in 10 seconds"
112 DATA 0,"dir.fix", 0,"run","?"
113 DATA 0,"bam viewer", 0,"run","looks at the block allocation map"
114 DATA 0,"file recover",0,"run","you blow it-we fix it"
115 DATA 0,"ps dump 2.0+",0,"run","prints out 110 ps graphics per page"
116 DATA 0,"commando-64",0,"run","just about does it all{!*3}"
299 :
300 OPEN1,8,15,"i0":PRINT#1,"s:menu":CLOSE1:SAVE"menu",8:VERIFY"menu",8
stop tok64
(bastext 1.0)