start tok64 d64-NbGE2F
1 DATAline 1,line 2,line 3,line 4,line 5
5 fi=1
10 POKE53281,14:POKE53280,6
20 DIMin$(4),fl$(400,4)
30 FORi=0TO4:READin$(i):NEXT
100 REM ******* main menu **************
110 PRINT"{clear}{blue}{reverse on}{space*8}{light green}labeler{space*2}by: rocky{space*2}moore{blue}{space*7}"
120 PRINT"{down}{black}(1) load file":PRINT"{down*2}(2) save file"
125 PRINT"{down*2}(3) add to file"
130 PRINT"{down*2}(4) not finished":PRINT"{down*2}(5) look through each file from (x)"
131 PRINT"{down*2}(6) print mailing labels"
135 PRINT"{down*2}(7) end the program"
140 INPUT"{down}{white}{down}please choose a number";n:IFn<1ORn>7THEN110
150 ONnGOTO200,300,400,100,600,5000,160
160 END
200 REM ******* load file **************
210 PRINT"{clear}{down}{blue}{down*2}{space*5}loading previous data file.{down*4}"
215 OPEN15,8,15:INPUT#15,a,zs$:IFa>20THENPRINTa,zs$:END
216 OPEN5,8,5,"0:labels data,s,r":INPUT#15,a,zs$:IFa >20THENPRINTa,zs$:END
220 GOSUB3000:fi=VAL(w$):POKE53281,1
230 FORfl=1TO400:FORin=0TO4:GOSUB3000:fl$(fl,in)=w$
231 IF w$="end"GOTO240
235 NEXT:NEXT
240 PRINT"{down*4} file is completly loaded.":PRINT"{down*2} please type [f1] to continue."
250 CLOSE5:CLOSE15:POKE53281,14
260 GETa$:IFa$<>"{f1}"THEN260
270 GOTO100
300 REM ******* save file **************
305 PRINT"{clear}{blue}{down*2} saving data base file.{down*3}":OPEN15,8,15:INPUT#15,a,zs$:IFaTHENPRINTa,zs$:END
306 INPUT#15,a,zs$:IFa>20THENPRINTa,zs$:END
310 OPEN5,8,5,"0:labels data,s,w":INPUT#15,a,zs$:IFa>20ANDa<>63THENPRINTa,zs$:END
311 IFa=63THENPRINT#15,"s0:labels data":CLOSE5:GOTO310
315 PRINT#5,STR$(fi)
320 FORpl=1TOfi:FORpn=0TO4:PRINT#5,CHR$(34);fl$(pl,pn);CHR$(34):NEXTpn:NEXTpl
325 PRINT#5,"end":CLOSE5:CLOSE15
330 PRINT"{down*6} file is completly saved.":PRINT"{down*2} please type [f1] to continue
340 POKE53281,14:
350 GETa$:IFa$<>"{f1}"THEN350
360 GOTO100
400 REM ******** new file **************
405 POKE53281,0:PRINT"{white}"
440 PRINT"{clear}{down*2}{156}{down} to go to the comand menu enter menu.":PRINT"{down}{space*7}file number"fi
450 er=0:FORin=0TO4
460 ip$="":PRINT"{down}{light green}"in$(in);:INPUTip$:IFip$="menu"THEN er=1:in=5:GOTO480
465 IFip$="menu"THENRETURN
470 fl$(fi,in)=LEFT$(ip$+"{space*31}",31)
480 NEXT:IFch=1THENRETURN
481 IF er =1 THEN 490
485 fi=fi+1:GOTO440
490 POKE53281,14:POKE53280,6:GOTO100
600 REM ******** brouse ****************
610 INPUT"{clear}{down*2} from what file number ";aa:IFaa<1ORaa>399THEN610
615 a=aa
620 FORfl=aTO400:PRINT"{clear}{black}{down}type [f1] to change file.":PRINT"type [f3] to delete a file."
630 PRINT"type [f5] to goto comand menu.":PRINT"type [f7] to see next file."
635 PRINT"type [shift] and [f1] to go 1 file back."
640 FORin=0TO4:PRINT"{down}{black}"in$(in)": {blue}"TAB(15);fl$(fl,in):NEXT
650 GETa$:IFa$="{f1}"THEN750
660 IFa$="{f3}"THEN700
670 IFa$="{f5}"THEN100
675 IFa$="{f2}"THENa=fl-1:IFa=>aaTHEN620
680 IFa$="{f7}"THENNEXTfl
690 GOTO650
700 REM ******* delete file ************
710 FORin=0TO4:fl$(fl,in)="deleted":NEXT
720 PRINT"************** deleted *****************"
730 GOTO650
750 POKE53280,0:POKE53281,0:PRINT"{clear}":ch=1:fz=fi:fi=fl:GOSUB450:ch=0:fi=fz
760 POKE53280,6:POKE53281,14:GOTO100
1000 REM ******** compare **************
1010 PRINT"?{clear}{down*2}{black}":FORi=0TO4:PRINT"{down}("RIGHT$(STR$(i),1)") "in$(i):NEXT
1020 INPUT"{down*3} enter number";in:IFin<0ORin>7THEN1000
1030 PRINT"{clear}{down*3}(1) greater than":PRINT"{down*2}(2) less than":PRINT"{down*2}(3) equal to"
1040 PRINT"{down*2}(4) greater than or equal to":PRINT"{down*2}(5) less than or equal to"
1050 INPUT"{down*3}please choose the number";sn:IFsn<1ORsn>5THEN1030
1060 INPUT"{clear}{down*2}comparison";cp$
1070 FORfl=1TO400:ONsnGOSUB2100,2200,2300,2400,2500
1080 NEXT
1090 GOTO100
2100 REM ***** compare > ***************
2110 IFVAL(cp$)>VAL(fl$(fl,in))THEN3000
2120 RETURN
2200 REM ***** compare < ***************
2210 IFVAL(cp$)>VAL(fl$(fl,in))THEN3000
2220 RETURN
2300 REM ***** compare = ***************
2310 IFfl$(fl,in)=cp$THEN3000
2320 RETURN
2400 REM ***** compare => **************
2410 IFVAL(cp$)=>VAL(fl$(fl,in))THEN3000
2420 RETURN
2500 REM ***** compare <= **************
2510 IFVAL(cp$)<=VAL(fl$(fl,in))THEN3000
2520 RETURN
3000 w$=""
3010 INPUT#5,w$:RETURN
5000 REM ** print labels **
5010 INPUT"{clear}{down*3} starting,ending record number";fs,fe:IF fs =0OR fe=0GOTO100
5015 INPUT"{down} number of lines between labels";fq:IFfq<1ORfq>6GOTO5015
5020 OPEN4,4:FOR fl=fsTOfe:PRINT"{home}{down*4}files #"fl:FORin=0TO4
5030 PRINT#4,fl$(fl,in)
5040 NEXT:FORi=1TOfq:PRINT#4:NEXT:NEXT:PRINT#4:CLOSE4
5050 GOTO 100
stop tok64
(bastext 1.0)