start tok64 d64-Bu7Z4R
0 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
1 REM %                              %
2 REM %       restore-id.name        %
3 REM %                              %
4 REM % donated to the public domain %
5 REM %           6/1985             %
6 REM %                              %
7 REM %   created by: rocky moore    %
8 REM %                              %
9 REM %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
10 FORi=0TO38:sp$=sp$+" ":ss$=ss$+CHR$(160):NEXT:sp$="{up}"+sp$+"{up*3}"
20 PRINT"{clear}{space*11}>restore-id.name<
30 PRINT"{down}{space*14}created by:
40 PRINT"{down}{space*14}rocky moore
50 PRINT"{down*3} this will change the name of a disk
60 PRINT"{down} and restore the proper disk id into
80 PRINT"{down} the header of the disk directory.
85 INPUT"{down*2} new disk name";f$:IFf$=""ORLEN(f$)>16THENPRINTsp$:GOTO85
86 PRINTsp$:fl$=LEFT$(f$+ss$,18)
90 PRINT"{down*2} insert the disk to be restored and
100 PRINT"{down} press the return key."
110 POKE198,0:WAIT198,1:GETa$:IFa$<>CHR$(13)THEN110
120 OPEN1,8,15,"i0":OPEN2,8,2,"#":GOSUB500:IFeTHEN400
130 PRINT#1,"u1:2 0 18 0":PRINT#1,"m-r";CHR$(18)CHR$(0)CHR$(2):GET#1,a$,b$
140 fl$=fl$+a$+b$+CHR$(160)+"2a"+LEFT$(ss$,5)
150 PRINT#1,"b-p 2 144":PRINT#2,fl$:PRINT#1,"u2:2 0 18 0":GOSUB500:IFeTHEN400
160 CLOSE2:CLOSE1:PRINT"{down*2} done{.*5}":END
400 CLOSE2:CLOSE1:PRINT"{down*2} disk error:"e,e$,t,s:END
500 INPUT#1,e,e$,t,s:RETURN
stop tok64
(bastext 1.0)