start tok64 d64-vXNP6j
0 POKE53280,0:POKE53281,0:POKE53265,PEEK(53265)AND239
3 PRINT"{clear}":FORj=0TO39:POKE55296+j,6:NEXT:POKE53265,PEEK(53265)OR16:POKE198,0
7 FORj=1TO3:GETa$:IFa$<>""THEN9
8 NEXT
9 PRINT"{clear}"
10 v=53248:READf:DIMf$(f):FORj=1TOf:READf$(j):NEXT
12 FORj=832TO895:POKEj,255:NEXT:FORj=0TO14STEP2:POKEv+j,24+16.5*j:NEXT
13 l$="0 1 2 3 4 5 6 7 8 910{1*3}21314151617181920"
20 y=95:GOSUB90
21 PRINT"{yellow}{space*7}U{cm r}IU{sh asterisk}IUIIU I"
22 PRINT"{orange}{space*7}{sh -*3}{cm q}{sh asterisk} {sh -*4} {sh -}"
23 PRINT"{brown}{space*7}J KJ{sh asterisk}KJJKJ{sh asterisk}K"
24 PRINT"{home}{down*5}":FORk=1TOf:POKEv+21,254:PRINT"{right*2}{white}";MID$(l$,k*2,2);"{cyan}{right*3}";f$(k)
25 FORy=90+k*8TO98+k*8:GOSUB90:NEXT:NEXT
28 d$="{home}{down*23}"
29 a(1)=11:a(2)=12:a(3)=15:a(4)=1:a(5)=15:a(6)=12:a(7)=11:POKE198,0
30 a1$="use crsr keys to move arrow"
31 a2$="{space*3}push return to select{space*3}"
32 p$="{space*2}please choose a program{space*2}"
33 y=1:x=10:dx=-1:POKE53248+21,0
40 c=c+1:IFc>7THENc=0
41 POKE646,a(c):PRINTd$;p$
42 IFc=0THENd=d+1:IFd=10THENp$=a1$
43 IFd=15THENp$=a2$:d=7
44 x=x+dx:IFx<1ORx>9THENdx=-dx
45 PRINTLEFT$(d$,y+6);TAB(23+x);"{yellow} {arrow left}{sh asterisk}"
49 a=0:GETa$:IFa$=""THEN40
50 yy=y:IFa$="{right}"ORa$="{down}"THENy=y+1:a=1:IFy>fTHENy=1
51 IFa$="{left}"ORa$="{up}"THENy=y-1:a=1:IFy<1THENy=f
52 IFa$=CHR$(13)THEN60
53 IFa=0THEN40
54 PRINTLEFT$(d$,yy+6);TAB(23);"{space*15}":x=10:dx=-1
55 PRINTLEFT$(d$,y+6);TAB(23);"{yellow}{space*2}{arrow left}{sh asterisk*10}{space*2}":x=1:dx=1
59 GOTO40
60 PRINT"{clear}"
61 POKEv+21,0:FORj=832TO895:POKEj,0:NEXT:POKEv+29,0:POKEv+23,0
62 FORj=0TO7:POKEv+39+j,j+1:NEXT:FORj=0TO15:POKEv+j,0:NEXT
64 POKE53280,0:POKE53281,0
65 PRINT"{clear}";LEFT$(d$,15);TAB(9);"{white}loading:{white}";f$(y)
66 PRINT"{home}{black}{down*2}load"CHR$(34);f$(y);CHR$(34);",8,1"
67 PRINT"{down*4}printchr$(147):poke646,14:run{home}";
68 POKE631,13:POKE632,13:POKE198,2:END
69 GOTO69
90 FORj=3TO15STEP2:POKEv+j,y:NEXT:RETURN
99 DATA 10:REM number of filenames
100 DATA "directory asst."
101 DATA "directory sort"
102 DATA "directory file"
103 DATA "directory master"
104 DATA "disk doctor 64.4"
105 DATA "disk doctor plus"
106 DATA "disk cleaner"
107 DATA "metabasic"
108 DATA "mlx 64 2.02"
109 DATA "disk handler"
112 DATA "error location"
199 DATA "exit":REM do not delete this
300 SAVE"@0:1st a menu",8
400 VERIFY"1st a menu",8
stop tok64
(bastext 1.0)