start tok64 d64-way9po
10 REM lines changed from mlx version 2.00 are 750,765,770 and 860
20 REM line changed from mlx version 2.01 is 300
100 PRINT"{clear}{light green}";CHR$(142);CHR$(8);:POKE53281,1:POKE53280,1
101 POKE788,52:REM disable run/stop
110 PRINT"{reverse on}{space*40}";
120 PRINT"{reverse on}{space*14}{right}{reverse off}{cm asterisk}{sh pound}{reverse on}{right} {right}{space*2}{cm asterisk}{reverse off}{cm asterisk}{sh pound}{reverse on}{sh pound}{reverse on}{space*14}";
130 PRINT"{reverse on}{space*14}{right} {cm g}{right} {right*2} {reverse off}{sh pound}{reverse on}{sh pound}{cm asterisk}{reverse off}{cm asterisk}{reverse on}{space*14}";
140 PRINT"{reverse on}{space*40}"
200 PRINT"{down*2}{156}{black} machine language editor version 2.02{down*5}"
210 PRINT"{gray}{up*2}starting address?{space*8}{left*9}";
215 INPUTs:f=1-f:c$=CHR$(31+119*f)
220 IFs<256OR(s>40960ANDs<49152)ORs>53247THENGOSUB3000:GOTO210
225 PRINT:PRINT:PRINT
230 PRINT"{gray}{up*2}ending address?{space*8}{left*9}";:INPUTe:f=1-f:c$=CHR$(31+119*f)
240 IFe<256OR(e>40960ANDe<49152)ORe>53247THENGOSUB3000:GOTO230
250 IFe<sTHENPRINTc$;"{reverse on}ending < start{space*2}":GOSUB1000:GOTO 230
260 PRINT:PRINT:PRINT
300 PRINT"{clear}";CHR$(14):ad=s
310 a=1:PRINTRIGHT$("{0*4}"+MID$(STR$(ad),2),5);":";
315 FOR j=aTO6
320 GOSUB570:IFn=-1THENj=j+n:GOTO320
390 IFn=-211THEN710
400 IFn=-204THEN 790
410 IFn=-206THENPRINT:INPUT"{down}Enter New Address";zz
415 IFn=-206THENIFzz<sORzz>eTHENPRINT"{reverse on}out of range":GOSUB1000:GOTO410
417 IFn=-206THENad=zz:PRINT:GOTO310
420 IF n<>-196 THEN 480
430 PRINT:INPUT"Display:From";f:PRINT,"To";:INPUTt
440 IFf<sORf>eORt<sORt>eTHENPRINT"At least";s;"{left}, not more than";e:GOTO430
450 FORi=fTOtSTEP6:PRINT:PRINTRIGHT$("{0*4}"+MID$(STR$(i),2),5);":";
451 FORk=0TO5:n=PEEK(i+k):PRINTRIGHT$("00"+MID$(STR$(n),2),3);",";
460 GETa$:IFa$>""THENPRINT:PRINT:GOTO310
470 NEXTk:PRINTCHR$(20);:NEXTi:PRINT:PRINT:GOTO310
480 IFn<0 THEN PRINT:GOTO310
490 a(j)=n:NEXTj
500 cksum=ad-INT(ad/256)*256:FORi=1TO6:cksum=(cksum+a(i))AND255:NEXT
510 PRINTCHR$(18);:GOSUB570:PRINTCHR$(146);
511 IFn=-1THENa=6:GOTO315
515 PRINTCHR$(20):IFn=cksumTHEN530
520 PRINT:PRINT"Line Entered Wrong : Re-enter":PRINT:GOSUB1000:GOTO310
530 GOSUB2000
540 FORi=1TO6:POKEad+i-1,a(i):NEXT:POKE54272,0:POKE54273,0
550 ad=ad+6:IF ad<e THEN 310
560 GOTO 710
570 n=0:z=0
580 PRINT"{cm pound}";
581 GETa$:IFa$=""THEN581
582 av=-(a$="m")-2*(a$=",")-3*(a$=".")-4*(a$="j")-5*(a$="k")-6*(a$="l")
583 av=av-7*(a$="u")-8*(a$="i")-9*(a$="o"):IFa$="h"THENa$="0"
584 IFav>0THENa$=CHR$(48+av)
585 PRINTCHR$(20);:a=ASC(a$):IFa=13ORa=44ORa=32THEN670
590 IFa>128THENn=-a:RETURN
600 IFa<>20 THEN 630
610 GOSUB690:IFi=1ANDt=44THENn=-1:PRINT"{reverse off}{left} {left}";:GOTO690
620 GOTO570
630 IFa<48ORa>57THEN580
640 PRINTa$;:n=n*10+a-48
650 IFn>255 THEN a=20:GOSUB1000:GOTO600
660 z=z+1:IFz<3THEN580
670 IFz=0THENGOSUB1000:GOTO570
680 PRINT",";:RETURN
690 s%=PEEK(209)+256*PEEK(210)+PEEK(211)
691 FORi=1TO3:t=PEEK(s%-i)
695 IFt<>44ANDt<>58THENPOKEs%-i,32:NEXT
700 PRINTLEFT$("{left*3}",i-1);:RETURN
710 PRINT"{clear}{reverse on}*** Save ***{down*3}"
715 PRINT"{down*2}(Press {reverse on}RETURN{reverse off}alone to cancel save){down}"
720 f$="":INPUT"{down} Filename";f$:IFf$=""THENPRINT:PRINT:GOTO 310
730 PRINT:PRINT"{down*2}{reverse on}T{reverse off}ape or {reverse on}D{reverse off}isk: (T/D)"
740 GETa$:IFa$<>"t"ANDa$<>"d"THEN740
750 dv=1-7*(a$="d"):IFdv=8THENf$="0:"+f$:OPEN15,8,15,"s"+f$:CLOSE15
760 t$=f$:zk=PEEK(53)+256*PEEK(54)-LEN(t$):POKE782,zk/256
762 POKE781,zk-PEEK(782)*256:POKE780,LEN(t$):SYS65469
763 POKE780,1:POKE781,dv:POKE782,1:SYS65466
765 k=s:POKE254,k/256:POKE253,k-PEEK(254)*256:POKE780,253
766 k=e+1:POKE782,k/256:POKE781,k-PEEK(782)*256:SYS65496
770 IF(PEEK(783)AND1)OR(191ANDst)THEN780
775 PRINT"{down}Done.{down}":GOTO 310
780 PRINT"{down}Error on Save.{space*2}Try again.":IFdv=1THEN720
781 OPEN15,8,15:INPUT#15,e1$,e2$:PRINTe1$;e2$:CLOSE15:GOTO720
790 PRINT"{clear}{reverse on}*** Load ***{down*2}"
795 PRINT"{down*2}(Press {reverse on}RETURN{reverse off} alone to cancel load)"
800 f$="":INPUT"{down*2} Filename";f$:IFf$=""THENPRINT:GOTO310
810 PRINT:PRINT"{down*2}{reverse on}T{reverse off}ape or {reverse on}D{reverse off}isk: (T/D)"
820 GETa$:IFa$<>"t"ANDa$<>"d"THEN820
830 dv=1-7*(a$="d"):IFdv=8THENf$="0:"+f$
840 t$=f$:zk=PEEK(53)+256*PEEK(54)-LEN(t$):POKE782,zk/256
841 POKE781,zk-PEEK(782)*256:POKE780,LEN(t$):SYS65469
845 POKE780,1:POKE781,dv:POKE782,1:SYS65466
850 POKE780,0:SYS65493
860 IF(PEEK(783)AND1)OR(191ANDst)THEN870
865 PRINT"{down}Done.":GOTO310
870 PRINT"{down}Error on Load.{space*2}Try again.{down}":IFdv=1THEN800
880 OPEN15,8,15:INPUT#15,e1$,e2$:PRINTe1$;e2$:CLOSE15:GOTO800
1000 REM buzzer
1001 POKE54296,15:POKE54277,45:POKE54278,165
1002 POKE54276,33:POKE 54273,6:POKE54272,5
1003 FORt=1TO200:NEXT:POKE54276,32:POKE54273,0:POKE54272,0:RETURN
2000 REM bell sound
2001 POKE54296,15:POKE54277,0:POKE54278,247
2002 POKE 54276,17:POKE54273,40:POKE54272,0
2003 FORt=1TO100:NEXT:POKE54276,16:RETURN
3000 PRINTc$;"{reverse on}not zero page or rom":GOTO1000
stop tok64
(bastext 1.0)