start tok64 d64-PpnmsF
10 REM ***tracker***
20 RESTORE:CLR
30 c=0:FORa=828TO948:READb:POKEa,b:c=c+b:NEXT
40 c=0:FORa=49152TO49364:READ b:POKEa,b:c=c+b:NEXT
50 POKE49248,0
60 FORa=49500TO49539:READb:POKEa,b:NEXT
70 FORa=49542 TO 49564:READb:POKEa,b:NEXT
80 PRINTCHR$(8);CHR$(142);CHR$(147);
90 POKE 55,0:POKE 56,127:DIM nu$(495)
100 POKE53280,0:POKE53281,0
110 SYS 49500
120 n$(1)="seq":n$(2)="prg":n$(3)="usr":n$(4)="rel"
130 sp$="{space*25}"
140 GOSUB2520
150 a$=""
160 PRINT"{sh asterisk*7}{cm r}{sh asterisk*23}{cm r}{sh asterisk*8}";
170 PRINT"{space*7}{sh -}number of entries #";nu
180 PRINT"{right*31}{up}{sh -}"
190 PRINT"{space*7}{cm z}{sh asterisk*23}{cm x}"
200 PRINT"enter the letter for the command"
210 PRINT
220 PRINT"a) abandon library"
230 PRINT"b) load tracker library"
240 PRINT"c) save tracker library"
250 PRINT"d) continue with entries"
260 PRINT"e) put in alphabetic order"
270 PRINT"f) look at enteries"
280 PRINT"g) delete an entry"
290 PRINT"h) edit an entry"
300 PRINT"i) print the entries"
310 PRINT"j) display the directory"
315 PRINT "k) notes to the user"
320 GETa$:IFa$>"k"ORa$<"a"THENGOTO320
330 a=ASC(a$)-64:IFa=1THENGOTO450:REM abandon file
340 IFnu=0 AND a>2 AND a<>10 AND a<>4 AND a<>11 THEN GOSUB2490:GOTO140
350 IFa=2THENGOTO730
360 IFa=3THENGOTO1180
370 IFa=4THENGOTO530
380 IFa=5THENGOTO1120
390 IFa=6THENGOTO2190
400 IFa=7THENGOTO2400
410 IFa=8THENGOTO980
420 IFa=9THENGOTO1340
430 IFa=10THENGOTO1840
435 IFa=11THENGOTO2900
440 END
450 GOSUB2520:PRINT"{space*12}abandon library"
460 PRINT"{sh asterisk*40}";
470 :PRINT"are you sure you want to abandon this{space*3}";
480 PRINT"library? (y/n){space*26}";
490 GETa$:IFa$=""THEN490
500 IFa$="y"THENSYS49525:POKE55,0:POKE56,160:SYS58260
510 IFa$<>"n"THEN140
520 GOTO 140
530 IFnu=495THENGOSUB2600:GOTO140
540 GOSUB 2520
550 PRINT"{space*13}enter entries"
560 PRINT"{sh asterisk*40}";
570 PRINT"enter 'end' or (return) to stop enteringentries"
580 PRINT
590 nu=nu+1:PRINTnu") "
600 nu$(nu)=""
610 z=nu:GOSUB 640
620 IFnu$(nu)="end"ORnu$(nu)=""THENnu=nu-1:nu$(nu+1)="":GOTO140
630 GOTO 530
640 PRINT"{home}{down*12}{right*6}";LEFT$(nu$(z)+"{reverse on} {reverse off}{space*2}",27)
650 PRINT"{home}{down*12}{right*31}{reverse on}{:*8}{reverse off}"
660 GETa$:IFa$=""THEN660
670 IFASC(a$)=13THENRETURN
680 IFASC(a$)=20ANDLEN(nu$(nu))>0THENnu$(z)=LEFT$(nu$(z),LEN(nu$(z))-1)
690 IFLEN(nu$(z))=25THENFORzz=1TO200:NEXT:GOTO660
700 IFASC(a$)<32ORASC(a$)>95THENGOTO640
710 nu$(z)=nu$(z)+a$:GOTO640
720 GOTO530
730 GOSUB2520
740 PRINT"{space*13}load library"
750 PRINT"{sh asterisk*40}";
760 PRINT"insert your disk with the tracker{space*7}library saved on it, and press";
770 PRINT" {reverse on}space{reverse off}."
780 GETa$:IFa$<>" "THENGOTO780
790 OPEN 2,8,2:CLOSE2:IF st=0 THEN 830
800 PRINT "{down}turn disk drive on, and press a key"
810 GET a$:IFa$=""THEN810
820 PRINT"{up}{space*35}":PRINT"{up*2}";
825 GOTO 790
830 OPEN2,8,2,"tracker library,s,r":INPUT#2,a$:CLOSE2:IFst=0THEN880
840 PRINT"{down}error, file was not found."
850 PRINT"press {reverse on}space{reverse off} to return to main menu":OPEN15,8,15,"i":CLOSE 15
860 GETa$:IFa$<>CHR$(32)THEN860
870 GOTO 140
880 IF nu=0 THEN 940
890 PRINT"{down}{red}danger{!*3}{white}{space*2}all names in memory will be{space*2}erased.{space*2}press {reverse on}space{reverse off} to ";
900 PRINT"continue.":PRINT"or any other key to quit."
910 GET a$:IFa$=""THEN910
920 IF a$=" "THEN GOTO 940
930 GOTO 140
940 PRINT"{down}please wait, loading the tracker library"
950 CLOSE1:OPEN1,8,8,"0:tracker library,s,r":INPUT#1,nu
960 FORa=1TOnu:INPUT#1,nu$(a):NEXTa:CLOSE1
970 GOTO140
980 GOSUB2520:PRINT"{space*18}edit"
990 PRINT"{sh asterisk*40}";
1000 PRINT"{down}which entry do you wish to edit?"
1010 PRINT"(1 -";nu;", 0 for none) ";
1020 INPUTz:IFz>nuTHEN980
1030 IFz=0THEN140
1040 IFz<1THEN980
1050 PRINT:PRINT"are you sure you want to edit":PRINT"{reverse on}";nu$(z);"{reverse off}?"
1060 GETa$:IF a$="n"THEN 980
1070 IF a$<>"y"THEN1060
1080 GOSUB 2520:PRINT"{space*17}edit"
1090 PRINT"{sh asterisk*40}";
1100 PRINT:PRINT:PRINT:PRINTnu") "
1110 GOSUB 640:GOTO 140
1120 GOSUB2520:PRINT"{space*14}alphabetize"
1130 PRINT"{sh asterisk*40}";
1140 PRINT"please wait putting in alphabetic order"
1150 n2=INT(nu/256):n1=nu-256*n2:POKE49366,n1:POKE49367,n2
1160 SYS49152
1170 GOTO140
1180 GOSUB2520:PRINT"{space*11}save library"
1190 PRINT"{sh asterisk*40}";
1200 PRINT"insert the disk you want to save the{space*4}library onto. then press {reverse on}space{reverse off}"
1210 GETa$:IFa$=""THENGOTO1210
1220 IFa$<>" "THEN1210
1221 OPEN 2,8,2:CLOSE2:IF st=0 THEN 1230
1222 PRINT "{down}turn disk drive on, and press a key"
1223 GET a$:IFa$=""THEN1223
1224 PRINT"{up}{space*35}":PRINT"{up*2}";
1225 GOTO1221
1230 OPEN1,8,8,"tracker library,s,r":INPUT#1,a$:CLOSE1:IFst<>0THEN1290
1240 PRINT"{down}file already exists, replace (y/n) ?"
1250 GETa$:IFa$=""THEN1250
1260 IF a$="y"THENGOTO1290
1270 IF a$<>"n"THEN65535
1280 GOTO140
1290 PRINT"{down}please wait, saving tracker library"
1300 CLOSE1:OPEN1,8,8,"@0:tracker library,s,w":PRINT#1,nu:FORa=1TOnu
1310 PRINT#1,nu$(a):NEXT
1320 CLOSE1
1330 GOTO140
1340 GOSUB2520
1350 PRINT"{space*13}print library"
1360 PRINT"{sh asterisk*40}";
1370 PRINT"{down}please enter title of library:"
1380 INPUT tl$
1390 PRINT"{down}please enter today's date (mm/dd/yy)."
1400 INPUTda$
1401 PRINT"{down*2}get the printer ready and press {reverse on}space{reverse off}":PRINT"{space*12}when ready."
1402 GETa$:IFa$=""THEN1402
1403 IF a$=" "THEN1410
1404 GOTO 140
1410 GOSUB2520
1420 PRINT"{space*13}print library"
1430 PRINT"{sh asterisk*40}";
1440 PRINT"printing file"
1450 OPEN4,4
1460 ww=nu
1470 tr=0
1480 a=INT(79-LEN(tl$))/2:FORb=1TOa:PRINT#4," ";:NEXTb:PRINT#4,tl$
1490 a=INT(79-LEN(tl$))/2:FORb=1TOa:PRINT#4," ";:NEXTb
1500 FORb=1TOLEN(tl$):PRINT#4,"{sh asterisk}";:NEXTb:PRINT#4
1510 PRINT#4,"{space*36}library"
1520 a=INT(79-LEN(da$))/2:FORb=1TOa:PRINT#4," ";:NEXTb:PRINT#4,da$;
1530 d=69-a-LEN(da$):FORa=1TOd:PRINT#4," ";:NEXTa:PRINT#4,"( page";tr+1;")"
1540 FORa=1TO79:PRINT#4,"{sh asterisk}";:NEXT:PRINT#4
1550 IFww>165THENww=165
1560 IFww<55THENGOTO1590
1570 IFww<110THENGOTO1630
1580 GOTO1750
1590 CLOSE4:OPEN4,4
1600 FORa=1TOww:PRINT#4,LEFT$(nu$((165*tr)+a)+sp$,25):NEXT
1610 FORa=61 TO ww STEP-1:PRINT#4:NEXT
1620 CLOSE4:GOTO140
1630 CLOSE4:OPEN4,4
1640 FORb=1TO55
1650 PRINT#4,LEFT$(nu$((165*tr)+b)+sp$,25);"{space*2}";LEFT$(nu$((165*tr)+b+55)+sp$,25)
1660 IFww=55+bTHENb=b+1:GOTO1680
1670 NEXTb:GOTO1690
1680 FORc=bTO55:PRINT#4,LEFT$(nu$((165*tr)+c)+sp$,25):NEXTc:GOTO1690
1690 REM check for next page
1700 FORa=1 TO 6:PRINT#4:NEXT
1705 IFnu<=wwTHEN140
1710 IF nu<330 AND tr=1 THEN 140
1720 IF tr=0 THEN tr=1:ww=nu-165:GOTO1480
1730 IF tr=1 THEN tr=2:ww=nu-330:GOTO1480
1740 GOTO 140
1750 REM
1760 CLOSE4:OPEN4,4
1770 FORb=1TO55
1780 PRINT#4,LEFT$(nu$((tr*165)+b)+sp$,25);"{space*2}";LEFT$(nu$((tr*165)+b+55)+sp$,25);
1790 PRINT#4,"{space*2}";LEFT$(nu$((tr*165+b+110))+sp$,25)
1800 IFww=104+bTHENb=b+1:GOTO1820
1810 NEXTb:GOTO1690
1820 FORc=bTO54:PRINT#4,LEFT$(nu$((tr*165)+c)+sp$,25);"{space*2}";
1830 PRINT#4,LEFT$(nu$((tr*165)+c+54)+sp$,25):NEXTc:GOTO1690
1840 GOSUB 2520:PRINT"{space*13}read directory"
1850 PRINT"{sh asterisk*40}";
1860 PRINT"{down*3}{right*6}insert a disk to read, and"
1870 PRINT"{down}{right*4}press the {reverse on}space bar{reverse off} when ready"
1880 GETa$:IFa$<>CHR$(32)THEN1880
1890 SYS 49525:PRINT"{clear}{white}hold space to slow, or return to exit.{down}"
1900 OPEN 15,8,15,"i":CLOSE15:IFst=0THEN1950
1910 PRINT"{down*2}{red}error{!*3} {white}unable to read disk."
1920 PRINT"press {reverse on}space{reverse off} to continue."
1930 GETa$:IFa$<>" "THEN1930
1940 GOTO 140
1950 OPEN1,8,2,"$":IFst=0THEN1970
1960 CLOSE1:GOTO 1910
1970 FOR x=1 TO142:GET#1,a$:NEXT
1980 IFst<>0THEN1910
1990 PRINT"{clear}{white}0 {reverse on}";CHR$(34);
2000 FORl=1TO16:GET#1,a$:PRINTa$;:NEXT:GET#1,a$,a$:PRINTCHR$(34);" ";
2010 FORl=1TO5:GET#1,a$:PRINTa$;:NEXT
2020 FORl=1TO89:GET#1,a$:NEXT:PRINT
2030 FORp=1TO8:GET#1,t$,a$,a$:IFt$<CHR$(128)THENFORa=1TO27:GET#1,a$:NEXT:GOTO2130
2040 GETa$:IFa$=""THEN2070
2050 IF a$=" "THENFORa=1TO500:NEXT:GOTO2070
2060 IF a$=CHR$(13)THENCLOSE1:SYS49500:GOTO140
2070 na$="":FORl=1TO16:GET#1,a$:IFa$=CHR$(160)THEN2090
2080 na$=na$+a$
2090 NEXTl:na$=LEFT$(na$+CHR$(34)+"{space*16}",16)
2100 GET#1,a$,a$,a$,a$,a$,a$,a$,a$,a$,l$,h$:l=ASC(l$+CHR$(0))+256*ASC(h$+CHR$(0))
2110 si$=STR$(l)
2120 PRINT"{left}";LEFT$(si$+"{space*3}",4);" ";CHR$(34);na$;"{space*2}";n$(ASC(t$)-128)
2130 IFstTHENCLOSE1:GOTO2160
2140 IFp<8THENGET#1,a$,a$
2150 NEXTp:GOTO2030
2160 PRINT:PRINT"{right*4}press the {reverse on}space bar{reverse off} when ready"
2170 GETa$:IFa$<>CHR$(32)THEN2170
2180 SYS49500:GOTO140
2190 PRINT"{down}";:IFnu<10THENGOSUB2310:GOTO140
2200 FORa=1TOnuSTEP10:GOSUB2520
2210 PRINT"{space*12}look at entries"
2220 PRINT"{sh asterisk*40}";
2230 FORb=aTOa+9
2240 IFb>nuTHEN2350
2250 PRINTb")"nu$(b):NEXTb
2260 PRINT"{down}{reverse on}{space*7}press any key to continue{space*8}";
2270 PRINT"{reverse on}{space*8}or (return) to exit{space*13}{reverse off}";
2280 GETa$:IFa$=""THEN2280
2290 IF ASC(a$)=13 THEN GOTO 140
2300 NEXT a:GOTO 140
2310 GOSUB 2520
2320 PRINT"{space*12}look at entries"
2330 PRINT"{sh asterisk*40}";
2340 FORa=1TOnu:PRINTa")"nu$(a):NEXTa
2350 PRINT"{down}{reverse on}{space*7}press any key to continue{space*8}";
2360 PRINT"{reverse on}{space*8}or (return) to exit{space*13}{reverse off}";
2370 GETa$:IFa$=""THEN GOTO 2370
2380 IFASC(a$)=13 THEN GOTO 140
2390 GOTO 140
2400 GOSUB 2520:PRINT"{space*13}delete a entry"
2410 PRINT"{sh asterisk*40}";
2420 PRINT"{down}which entry do you wish to delete"
2430 PRINT"( 1 -";nu;") ?"
2440 INPUTa:IFa<1ORa>nuTHENGOTO 2400
2450 PRINT"{down}are you sure you want to delete":PRINT"{reverse on}"nu$(a)"{reverse off} (y/n)?"
2460 GETa$:IFa$="n"THEN GOTO 140
2470 IFa$<>"y"THEN GOTO 2460
2480 FORb=aTOnu-1:nu$(b)=nu$(b+1):NEXT:nu$(nu)="":nu=nu-1:GOTO 140
2490 GOSUB 2520:PRINT "{down*4}{space*11}{reverse on}no entries in memory"
2500 FORb=1TO2000:NEXT:RETURN
2510 END
2520 PRINT"{clear}{white}{reverse off}{cm a}{sh asterisk*38}{cm s}";
2530 PRINT"{sh -}{space*7}{red}public domain presents:{white}{space*8}{sh -}";
2540 PRINT"{sh -}{space*7}{red}{reverse on}{space*8}tracker{space*8}{reverse off}{white}{space*8}{sh -}";
2550 PRINT"{sh -}{space*7}{cyan}{reverse on}{space*11}by{space*10}{cm g}{reverse off}{white}{space*7}{sh -}";
2560 PRINT"{sh -}{space*7}{156}{reverse on}{space*7}jason olds{space*6}{cm g}{reverse off}{white}{space*7}{sh -}";
2570 PRINT"{sh -}{space*8}{green}{reverse on}{cm t*22} {reverse off}{white}{space*7}{sh -}";
2580 PRINT"{cm z}{sh asterisk*38}{cm x}";
2590 RETURN
2600 GOSUB 2520:PRINT"{down*4}{space*13}{reverse on}no more memory{reverse off}"
2610 :FORb=1TO2000:NEXT:RETURN
2620 DATA174,172,3,232,224,15,208,2,162,1,142,172,3,162,0,173,172,3,157,81,216
2630 DATA232,224,36,208,248,174,173,3,232,224,15,208,2,162,1,142,173,3,162,0
2640 DATA173,173,3,157,121,216,232,224,36,208,248,174,174,3,232,224,15,208,2
2650 DATA162,1,142,174,3,162,0,173,174,3,157,161,216,232,224,36,208,248,174
2660 DATA175,3,232,224,15,208,2,162,1,142,175,3,162,0,173,175,3,157,201,216,232
2670 DATA224,36,208,248,108,132,193,0,0,0,0,0,1,2,3,4,0,0,0,0,0
2680 DATA173,214,192,208,6,173,215,192,208,1,96,165,47,24,105,10,133,34,165
2690 DATA48,105,0,133,35,76,163,192,160,0,177,34,72,177,36,145,34,104,145,36
2700 DATA200,192,3,208,241,76,116,192,169,0,141,218,192,168,177,34,240,59
2710 DATA141,213,192,177,36,240,219,205,213,192,176,8,141,213,192,169,1,141
2720 DATA218,192,200,177,34,133,251,177,36,133,253,200,177,34,133,252,177,36
2730 DATA133,254,160,0,177,253,209,251,144,180,208,11,200,206,213,192,208
2740 DATA242,173,218,192,208,167,165,36,24,105,3,133,36,165,37,105,0,133,37
2750 DATA173,216,192,208,3,206,217,192,206,216,192,173,216,192,208,158,173
2760 DATA217,192,208,153,165,34,24,105,3,133,34,165,35,105,0,133,35,173,214
2770 DATA192,208,3,206,215,192,206,214,192,173,214,192,208,6,173,215,192,208
2780 DATA1,96,173,214,192,141,216,192,173,215,192,141,217,192,165,34,24,105
2790 DATA3,133,36,165,35,105,0,133,37,76,47,192
2800 DATA173,20,3,141,132,193,173,21,3,141,133,193,120,169,134,141,20,3,169,193
2810 DATA141,21,3,88,96,120,173,132,193,141,20,3,173,133,193,141,21,3,88,96
2820 DATA174,0,194,232,224,10,208,8,162,0,142,0,194,76,60,3,142,0,194,108,132
2830 DATA193,255
2900 REM ***notes to user***
2910 GOSUB 2520
2920 PRINT "{space*11}notes to the user{space*12}";
2930 PRINT "{sh asterisk*40}";
2940 PRINT "{yellow}{space*2}the whole idea behind this program was";
2950 PRINT "to have a listing of all the programs"
2960 PRINT "in my inventory. the first time i wrote"
2990 PRINT"this program it did barely what i had"
3000 PRINT"indended it to do.{space*2}but i decided that"
3010 PRINT"it was a good enough idea to write it"
3020 PRINT"better and try to sell it.{space*2}well here it";
3030 PRINT"is and it hasn't sold.":PRINT "{space*2}i've donated it";
3040 PRINT" to public domain in{space*3}hopes that a couple";
3050 PRINT" people might use it and remember my";
3060 PRINT" name."
3070 PRINT "{down}{space*9}{white}press {reverse on}return{reverse off} to exit."
3080 GETa$:IFa$<>CHR$(13)THEN3080
3090 GOTO 140
stop tok64
(bastext 1.0)