start tok64 d64-LORKOf
10 PRINT"{clear}":POKE 53280,4:POKE 53281,1
20 REM printing lab by jerry reuter 109 barbara dr ladson s.c. 29456
30 k$="{reverse on}{yellow} welcome to the printing lab c-64/128 ":xr$="{home}{down*4}":GOSUB 1410
40 k$="{reverse on}{yellow}{space*4}designed by jerry reuter{space*9}":xr$=xr$+"{down*2}":GOSUB 1410
50 k$="{reverse on}{yellow} for the commodore 64 or 128 computer ":xr$=xr$+"{down*2}":GOSUB 1410
60 k$="{reverse on}{yellow}{space*2}and the commodore mps-1{0*3} printer{space*2}":xr$=xr$+"{down*2}":GOSUB 1410
70 FOR x=1 TO 450:NEXT
80 k$="{reverse on}{red}{space*3}please make sure your printer is{space*3}":xr$=xr$+"{down*4}":GOSUB 1410
90 k$="{reverse on}{red} turned on, and the paper is lined up ":xr$=xr$+"{down*2}":GOSUB 1410
100 k$="{reverse on}{red} properly, then press any key to view ":xr$=xr$+"{down*2}":GOSUB 1410
110 k$="{reverse on}{red} the screen menu of printing options. ":xr$=xr$+"{down*2}":GOSUB 1410
120 GET a$:IF a$=""THEN 120
130 GOSUB 1430:GOSUB 1450
140 k$="{reverse on}{white} 1=print the vic chip memory map (40) ":xr$="{home}{down*2}":GOSUB 1410
150 k$="{reverse on}{red} 2=print the vic chip color map (40){space*2}":xr$=xr$+"{down*2}":GOSUB 1410
160 k$="{reverse on}{cyan} 3=print a sheet of memo pad forms 4up":xr$=xr$+"{down*2}":GOSUB 1410
170 k$="{reverse on}{156} 4=print a sheet of shopping lists 4up":xr$=xr$+"{down*2}":GOSUB 1410
180 k$="{reverse on}{green} 5=print a sheet of phone messages 4up":xr$=xr$+"{down*2}":GOSUB 1410
190 k$="{reverse on}{orange} 6=print a greeting card (12 choices) ":xr$=xr$+"{down*2}":GOSUB 1410
200 k$="{reverse on}{pink} 7=go to the custom letterhead {pound}=esc{space*2}":xr$=xr$+"{down*2}":GOSUB 1410
210 k$="{reverse on}{blue} 8=go to the typewriter w/normal print":xr$=xr$+"{down*2}":GOSUB 1410
220 k$="{reverse on}{yellow} 9=go to{space*2}typewriter w/enhanced print ":xr$=xr$+"{down*2}":GOSUB 1410
230 k$="{reverse on}{light gray} 10=reset the printer defaults & quit ":xr$=xr$+"{down*2}":GOSUB 1410
240 k$="{reverse on}{light blue} enter your choice, and press <return>":xr$=xr$+"{down*2}":GOSUB 1410
250 INPUT a$:x=VAL(a$):IF x<1 OR x>10 THEN PRINT"{up*2}":GOTO 250
260 ON x GOTO 270,340,410,450,490,610,980,1180,1300,1500
270 GOSUB 1430:PRINT"{clear}":OPEN 4,4,0:PRINT#4,CHR$(14)+CHR$(31)
280 PRINT#4,"vic chip memory map (40 col.)":PRINT#4,CHR$(15)
285 PRINT#4:GOSUB 1490
290 PRINT#4,SPC(16);"{1*10}{2*10}{3*10}"
300 PRINT#4,SPC(6);"0123456789012345678901234567890123456789"
305 PRINT#4:PRINT#4
310 FOR i=1024 TO 1984 STEP 40
320 PRINT#4,i;:FOR x=0 TO 39:PRINT#4,"O";:NEXT:PRINT#4,"G":PRINT CHR$(13):NEXT
330 FOR x=0 TO 45:PRINT#4,"{cm t}";:NEXT:GOSUB 1470:PRINT"{clear}":GOSUB 1450:GOTO 140
340 GOSUB 1430:PRINT"{clear}":OPEN 4,4,0:PRINT#4,CHR$(14)+CHR$(31)
350 PRINT#4,"vic chip color map (40 col.)":PRINT#4,CHR$(15)
355 PRINT#4:GOSUB 1490
360 PRINT#4,SPC(17);"{1*10}{2*10}{3*10}"
370 PRINT#4,SPC(7);"0123456789012345678901234567890123456789"
375 PRINT#4:PRINT#4
380 FOR i=55296 TO 56256 STEP 40
390 PRINT#4,i;:FOR x=0 TO 39:PRINT#4,"O";:NEXT:PRINT#4,"G":PRINT CHR$(13):NEXT
400 FOR x=0 TO 46:PRINT#4,"{cm t}";:NEXT:GOSUB 1470:PRINT"{clear}":GOSUB 1450:GOTO 140
410 GOSUB 1430:PRINT"{clear}":OPEN 4,4,0:FOR p=1 TO 2:PRINT#4,CHR$(14)+CHR$(31)
420 FOR x=1 TO 2:PRINT#4,"memoZmemoZmemoZmemo{space*2}";:NEXT x
425 PRINT#4:PRINT#4,CHR$(159)
430 FOR l=1 TO 13:PRINT#4,"{cm @*19}{space*2}{cm @*19}":PRINT#4
440 NEXT l:NEXT p:PRINT"{clear}":GOSUB 1450:GOTO 140
450 GOSUB 1430:PRINT"{clear}":OPEN 4,4,0:PRINT#4,CHR$(14)+CHR$(31):FOR x=1 TO 4
460 PRINT#4,"ZshoppingZ";:NEXT:PRINT#4:FOR x=1 TO 4
470 PRINT#4,"Z{space*2}list{space*2}Z";:NEXT:PRINT#4,CHR$(159):FOR l=1 TO 29:FOR x=1 TO 4
480 PRINT#4," {cm @*8} ";:NEXT:PRINT#4:PRINT#4:NEXT:PRINT"{clear}"
485 GOSUB 1450:GOTO 140
490 GOSUB 1430:PRINT"{clear}":OPEN 4,4,0:FOR m=1 TO 2:PRINT#4,CHR$(31):FOR x=1 TO 2
500 PRINT#4,"to {cm @*15} from {cm @*14}{space*2}";:NEXT x:PRINT#4
510 PRINT#4,CHR$(14)+CHR$(31)
520 PRINT#4,"while you were out! while you were out!"
525 PRINT#4,CHR$(15):FOR x=1 TO 2
530 PRINT#4,"m {cm @*16} of {cm @*16}{space*2}";:NEXT x
535 PRINT#4:PRINT#4
540 FOR x=1 TO 2:PRINT#4,"ph# {cm @*14} ext# {cm @*14}{space*2}";
545 NEXT x:PRINT#4
550 PRINT#4
560 FOR x=1 TO 2:PRINT#4,"called{space*2}[], urgent [], please call [],{space*2}";
565 NEXT x:PRINT#4:PRINT#4
570 FOR x=1 TO 2:PRINT#4,"message {cm @*30}{space*2}";:NEXT x
580 PRINT#4:PRINT#4,CHR$(159):FOR z=1 TO 8
590 FOR x=1 TO 2:PRINT#4,"{cm @*38}{space*2}";:NEXT x
595 PRINT#4
600 PRINT#4:NEXT z:PRINT#4:NEXT m:PRINT"{clear}":GOSUB 1450:GOTO 140
610 GOSUB 1430:PRINT"{clear}":OPEN 4,4:PRINT#4,CHR$(14)+CHR$(31):FOR m=1 TO 19
620 PRINT"{clear}{reverse on} select cover design, and press return{space*2}":PRINT
630 PRINT"{down}{right*11}{reverse on} a=basketweave ":PRINT"{right*11}{reverse on} b=hearts{space*6}"
640 PRINT"{right*11}{reverse on} c=x's and o's ":PRINT"{right*11}{reverse on} d=diamonds{space*4}"
650 PRINT"{right*11}{reverse on} e=playing card":PRINT"{right*11}{reverse on} f=checker brd."
660 PRINT"{right*11}{reverse on} g=brick work{space*2}":PRINT"{right*11}{reverse on} h=mosaic tile "
670 PRINT"{right*11}{reverse on} i=geometric{space*3}":PRINT"{right*11}{reverse on} j=diagonals{space*3}"
680 PRINT"{right*11}{reverse on} k=deco-art i{space*2}":PRINT"{right*11}{reverse on} l=deco-art ii "
690 INPUT cv$
695 IF ASC(cv$)<65 OR ASC(cv$)>76 OR LEN(cv$)=>2 THEN PRINT"{up*2}":cv$="":GOTO 690
700 PRINT:PRINT"{right*11}{down}{reverse on} printing{.*3}{space*2}";cv$:PRINT
710 IF cv$="a"THEN a$="P":b$="{sh @}":n=9:PRINT#4,CHR$(14):GOTO 830
720 IF cv$="b"THEN a$="S":b$=" ":n=17:PRINT#4,CHR$(15):GOTO 830
730 IF cv$="c"THEN a$="x":b$="o":n=9:PRINT#4,CHR$(14):GOTO 830
740 IF cv$="d"THEN a$="N":b$="M":n=17:PRINT#4,CHR$(15):GOTO 830
750 IF cv$="e"THEN a$="AS":b$="ZX":n=9:PRINT#4,CHR$(15):GOTO 830
760 IF cv$="f"THEN a$="{cm +}":b$=" ":n=17:PRINT#4,CHR$(15):GOTO 830
770 IF cv$="g"THEN a$="{cm e}":b$="{cm r}":n=17:PRINT#4,CHR$(15):GOTO830
780 IF cv$="h"THEN a$="IU":b$="KJ":n=9:PRINT#4,CHR$(15):GOTO 830
790 IF cv$="i"THEN a$="{sh pound}":b$="{cm asterisk}":n=9:PRINT#4,CHR$(14):GOTO 830
800 IF cv$="k"THEN a$="V":b$="{sh +}":n=9:PRINT#4,CHR$(14):GOTO 830
810 IF cv$="j"THEN a$="{sh @}":b$="O":n=9:PRINT#4,CHR$(14):GOTO 830
820 IF cv$="l"THEN a$="{cm asterisk}":b$="{sh pound}":n=18:PRINT#4,CHR$(15):GOTO 830
830 PRINT#4,CHR$(31):FOR m=1 TO 19:FOR x=1 TO n:PRINT#4,a$;b$;:NEXT
835 GOSUB 1490:PRINT#4
840 FOR x=1 TO n:PRINT#4,b$;a$;:NEXT:PRINT#4:NEXT:FOR x=1 TO 13:PRINT#4:NEXT
850 PRINT"{reverse on} enter the inside message,{space*3}"
855 PRINT"{reverse on} one line and press <return> "
860 GET a$:IF a$=""THEN 860:PRINT
870 an$=an$+a$:PRINT a$;:IF a$="{pound}"THEN a$="":an$="":GOTO 930
880 IF a$=CHR$(20)THEN PRINT:PRINT"{reverse on} re-type line ":a$="":an$="":GOTO 860
890 IF a$=CHR$(13)THEN 910
900 GOTO 860
910 PRINT#4,CHR$(15):kk=INT(52-(LEN(an$)/2)):PRINT#4,SPC(kk),;an$:PRINT#4
920 an$="":a$="":GOTO 850
930 PRINT"{reverse on} type a one liner on back ? (y/n) ":PRINT
940 GET a$:IF a$=""THEN 940:IF a$<>"y"THEN 960
950 PRINT:INPUT"{reverse on} what is the credit to print ";ff$:PRINT#4,SPC(5),;ff$
955 PRINT#4
960 PRINT"{clear}":GOSUB 1450:GOTO 140
970 PRINT"{reverse on} rem <{pound}> key to escape, <return>=print{space*2}":PRINT
980 GOSUB 1430:PRINT"{clear}"
985 OPEN 4,4,0:PRINT"{reverse on}{space*2}custom letterhead mode is now active"
990 PRINT:INPUT"{reverse on} e=enhanced, n=normal, {pound}=quit, (e/n/{pound}) ";m$
1000 IF m$<>"e"AND m$<>"n"AND m$<>"{pound}"THEN 990
1010 IF m$="{pound}"THEN 1130
1020 IF m$<>"e"THEN 1030
1025 PRINT#4,CHR$(31)+CHR$(14):PRINT"{reverse on} type in up to 19 .spaces max"
1030 IF m$<>"n"THEN 1040
1035 PRINT#4,CHR$(31)+CHR$(15):PRINT"{reverse on} type in up to 59 .spaces max"
1040 an$=""
1050 GET a$:IF a$=""THEN 1050
1060 an$=an$+a$:PRINT a$;:IF a$=CHR$(13)THEN 1100
1070 IF a$<>CHR$(20)THEN 1080
1075 a$="":an$="":PRINT:PRINT"{reverse on} re-type line please ":GOTO 1040
1080 IF a$="{pound}"THEN an$="":a$=""GOTO 1120
1090 GOTO 1050
1100 IF m$="e"THEN xt=INT(10-(LEN(an$)/2)):PRINT#4,SPC(xt),;an$:GOTO 990
1110 IF m$="n"THEN xt=INT(30-(LEN(an$)/2)):PRINT#4,SPC(xt),;an$:GOTO 990
1120 PRINT"{clear}":GOSUB 1450:GOTO 140
1130 PRINT"{reverse on} should i draw a line across the top,{space*2}"
1140 PRINT"{reverse on} to separate the letterhead (y/n) {sh space}?{space*3}"
1150 GET a$:IF a$=""THEN 1150
1160 IF a$<>"y"THEN 1170
1165 PRINT#4,CHR$(14)CHR$(159):FOR x=1 TO 40:PRINT#4,"{cm @}";:NEXT:GOTO 1120
1170 GOTO 1120
1180 GOSUB 1430:PRINT"{clear}":OPEN 4,4,0:PRINT#4,CHR$(31)
1190 PRINT"{reverse on} typewriter with normal print nlq mode{space*2}"
1200 PRINT"{reverse on} is now active. type in up to 80 cols.{space*2}"
1210 PRINT"{reverse on} rem <{pound}> key to escape, <return>=print{space*2}":PRINT
1220 an$=""
1230 GET a$:IF a$=""THEN 1230
1240 an$=an$+a$:PRINT a$;
1250 IF a$=CHR$(13)THEN PRINT#4,an$:GOTO 1220
1260 IF a$=CHR$(20)THEN PRINT:PRINT"{reverse on} re-enter line {white}":GOTO 1220
1270 IF a$="{pound}"THEN an$="":a$="":GOTO 1290
1280 GOTO 1230
1290 PRINT#4,CHR$(15):PRINT"{clear}":GOSUB 1450:GOTO 140
1300 GOSUB 1430:PRINT"{clear}":OPEN 4,4,0:PRINT#4,CHR$(31)+CHR$(14)
1310 PRINT"{reverse on} typewriter with enhanced print nlq mode"
1320 PRINT"{reverse on} is now active. type in up to 40 cols.{space*2}"
1330 an$=""
1340 GET a$:IF a$=""THEN 1340
1350 an$=an$+a$:PRINT a$;
1360 IF a$=CHR$(13)THEN PRINT#4,an$:GOTO 1330
1370 IF a$=CHR$(20)THEN PRINT:PRINT"{reverse on} re-enter line {white}":GOTO 1330
1380 IF a$="{pound}"THEN an$="":GOTO 1400
1390 GOTO 1340
1400 PRINT#4,CHR$(15):PRINT"{clear}":GOSUB 1450:GOTO 140
1410 p=LEN(k$):tx=40-p/2:FOR d=1 TO LEN(k$)-20
1420 PRINT xr$SPC(tx)LEFT$(k$,d)RIGHT$(k$,p-(p-d)):tx=tx-1:NEXT:RETURN
1430 FOR x=1124 TO 2044 STEP 80
1440 FOR l=19 TO 0 STEP-1:POKE x-l,32:POKE x+l,32:NEXT:NEXT:RETURN
1450 OPEN 10,4,10:PRINT#10:CLOSE 10:CLOSE 4:x=0:i=0:p=0:l=0:z=0:m=0:n=0:kk=0
1460 xt=0:a$="":b$="":an$="":ff$="":tx=0:cv$="":xr$="":RETURN
1470 PRINT#4:PRINT#4,"add the number at the top to the number at the side"
1480 PRINT#4:PRINT#4,"for the proper location on the 40 column screen."
1485 RETURN
1490 OPEN 6,4,6:PRINT#6,CHR$(22):CLOSE 6:RETURN
1500 GOSUB 1450:PRINT"{clear}":PRINT"{home}{right*2}{down*2}{reverse on} end printing lab{.*3}":x=PEEK(65534)
1510 IF x=72 THEN SYS 64738
1520 IF x=23 THEN SYS 65341
stop tok64
(bastext 1.0)