start tok64 d64-GaL8uM
100 REM monopole cbm-64
130 PRINT"{clear}{white}":POKE53280,0:POKE53281,0:CLR:GOSUB1590
140 pg$="{space*2}purple, lt. blue, maroon, orange,{space*7}red, yellow, green, dk. blue"
150 DIMpn$(42),d(42,1),ch$(16),cc$(16),p(42,9),pt$(42),c$(42),ps(42),h(42),mg(42)
160 DIM p$(2),pl(2),o(2),jt(2),m(2),cj(2)
170 GOSUB320:INPUT"do you want auction rule (y or n)";q$:IFLEFT$(q$,1)="y"THENaf=1
180 INPUT"{down}want free parking jackpot option ";q$:IFLEFT$(q$,1)="y"THENpf=1:fp=500
190 m(1)=1500:m(2)=1500:pl(1)=1:pl(2)=1:dv=2
200 cd$="{down*25}":cr$="{right*40}"
210 zq=RND(-ti):x1=8:y1=10:x2=23:y2=10:rx=6:ry=18:tn=832:tt=886
220 e$="{reverse on}{space*18}{reverse off}":rm$="{reverse on}hit{space*2}'r' or 't'{reverse off}"
230 PRINT"{clear}{down*2}{cyan}{space*5}please wait while i set up.{white}"
240 FORi=1TO4:p(6+((i-1)*10),8)=100:NEXT:p(13,8)=75:p(29,8)=75
250 ch=INT(RND(1)*16)+1:cc=INT(RND(1)*16)+1
260 FORi=1TO41:FORj=0TO1:READd(i,j):NEXT:NEXT
270 p$(1)="{reverse on}{space*3}player 1{reverse off}":p$(2)="{reverse on}{space*3}player 2{reverse off}"
280 FORi=1TO41:READpn$(i):NEXT:FORi=1TO41:READpt$(i):IFpt$(i)<>"p"THEN300
290 READc$(i):FORj=1TO9:READp(i,j):NEXTj
300 NEXTi
310 FORi=1TO16:READch$(i):NEXT:FORi=1TO16:READcc$(i):NEXT:GOTO390
320 PRINT"{light blue} {cm n}{cm b}{space*2}{reverse on}{cm b}{reverse off}{cm h}{cm n}{cm y*3}{cm h}{cm n}{cm b}{space*3}{cm h}{cm n}{cm y*3}{cm h}{cm n}{cm y*2}P{cm n}{cm y*3}{cm h}{cm n}{space*4}O{cm y}"
322 PRINT" {cm n} {cm b}{reverse on}{cm b}{reverse off} {cm h}{cm n}{space*3}{cm h}{cm n} {cm b}{space*2}{cm h}{cm n}{space*3}{cm h}{cm n}{cm p*2}{sh @}{cm n}{space*3}{cm h}{cm n}{space*4}L"
324 PRINT" {cm n}{space*4}{cm h}{cm n}{space*3}{cm h}{cm n}{space*2}{cm b} {cm h}{cm n}{space*3}{cm h}{cm n}{space*3}{cm n}{space*3}{cm h}{cm n}{space*4}O"
330 PRINT" {cm n}{space*4}{cm h}{cm n}{cm p*3}{cm h}{cm n}{space*3}{cm b}{cm h}{cm n}{cm p*3}{cm h}{cm n}{space*3}{cm n}{cm p*3}{cm h}{cm n}{cm p*3} L{cm p}{white}"
360 PRINT"{down*3}hit 'r' to roll dice and 't' for{space*8}transaction menu."
370 PRINT"{down} '0' can be used to return from most{space*5}subroutines"
380 PRINT:PRINT"{down}developed properties may not be traded.":PRINT:RETURN
390 POKE54277,79:POKE54284,79:POKE54291,79
392 POKE54278,248:POKE54286,248:POKE54292,248
394 POKE54276,33:POKE54288,33:POKE54290,33
396 g(1)=54272:g(2)=54273:g(3)=54279:g(4)=54280:g(5)=54286:g(6)=54287
398 FORi=1TO6:POKEg(i),0:NEXT
399 POKE54296,15:IFPEEK(832)<>160THENGOSUB6370
400 GOSUB1320:FORpk=1TO2:POKEd(1,pk-1),48+pk:o(pk)=d(1,pk-1):pt=pk:NEXT:GOSUB6470
410 GOSUB1620:IFr1=r2THEN410
420 pt=(r1>r2)+2
430 POKEd(pl(1),0),49:POKEd(pl(2),1),50
440 pt$=STR$(pt)
450 ms$="{reverse on}{green}player"+pt$+" starts{reverse off}{white}"
460 x=rx:y=ry:z$=ms$:GOSUB1570:FORde=1TO1500:NEXT:z$=e$:GOSUB1570:GOTO680
470 dv=2:mf=0:jb=0
480 IFpl(pt)=41THEN590
490 jt(pt)=0
500 GOSUB1620:df=1
510 IFdb=3THENSYStn:GOSUB3150:SYStt:GOSUB6470:GOTO620
520 FORm=1TOdr:pl(pt)=pl(pt)+1
530 POKEo(pt),160:IFpl(pt)>40THENpl(pt)=pl(pt)-40:SYStn:GOSUB1700:SYStt
540 POKEd(pl(pt),pt-1),48+pt
550 o(pt)=d(pl(pt),pt-1)
560 FORt=1TO50STEP6+pt:FORi=1TO6:POKEg(i),t:NEXT:NEXT
580 FORi=1TO6:POKEg(i),0:NEXT:NEXTm
590 POKEd(pl(pt),pt-1),48+pt:GOSUB6470
600 SYStn:GOSUB1770:SYStt:GOSUB6470:IFm(pt)<0THENGOSUB6200:SYStt
610 IFpl(pt)=11THENPOKEd(41,pt-1),160:POKEd(11,pt-1),48+pt
620 IFjbTHENjb=0:POKEo(pt),160:o(pt)=d(pl(pt),pt-1):GOTO520
630 IFmfTHENmf=0:POKEo(pt),160:o(pt)=d(pl(pt),pt-1):GOTO590
640 IFjeTHENje=0:POKEo(pt),160:o(pt)=d(pl(pt),pt-1):GOTO680
650 IFjfTHENjf=0:POKEd(pl(pt),pt-1),48+pt:POKEo(pt),160:o(pt)=d(pl(pt),pt-1)
660 IFdbTHEN680
670 pt=3-pt
680 z$=p$(pt):x=rx:y=ry-1:GOSUB1570
690 z$=rm$:x=rx:y=ry:GOSUB1570
700 GETbc$:IFbc$<>""THEN700
710 GETa$:IFa$=""THEN710
720 IFa$="t"THENSYStn:GOSUB4080:SYStt:GOSUB6470:GOTO680
730 z$=e$:x=rx:y=ry:GOSUB1570
740 GOTO470
750 DATA1978,1938,1974,1973,1931,1930,1968,1967,1925,1924,1922,1921
760 DATA1959,1958,1956,1955,1953,1952,1950,1949,1944,1904
770 DATA1824,1825,1744,1745,1664,1665,1584,1585,1505,1506,1424,1425
780 DATA1346,1347,1264,1265,1184,1185,1104,1105
790 DATA1029,1030,1032,1033,1035,1036,1038,1039,1081,1082,1044,1045
800 DATA1047,1048,1130,1131,1053,1054,1096,1097
810 DATA1217,1218,1297,1298,1377,1378,1457,1458,1536,1537,1617,1618
820 DATA1697,1698,1777,1778,1857,1858,1906,1907
830 DATA"{green}>go<{light gray}","{light gray}old kent road.{light gray}","{yellow}community chest{light gray}","{light gray}whitechapel road.{light gray}"
835 DATA"{light blue}income tax{light gray}"
840 DATA"{gray}kings cross.{light gray}","{cyan}the angel.{light gray}","{pink}chance{light gray}","{cyan}euston road.{light gray}"
845 DATA"{cyan}pentonville road.{light gray}"
850 DATA"{pink}just visiting{light gray}","{156}pall mall{light gray}","{light green}electric company{light gray}","{156}whitehall.{light gray}"
860 DATA"{156}n'thumberland av.{light gray}","{gray}marylebone stat.{light gray}","{orange}bow street{light gray}"
865 DATA"{yellow}community chest{light gray}"
870 DATA"{orange}marlborough st.{light gray}","{orange}vine street.{light gray}","{brown}free parking{light gray}","{red}strand.{light gray}"
880 DATA"{pink}chance{light gray}","{red}fleet street.{light gray}","{red}trafalgar sq.{light gray}","{gray}fenchurch st.{light gray}"
885 DATA"{yellow}leicester sq.{light gray}"
890 DATA"{yellow}coventry st.{light gray}","{light green}water works{light gray}","{yellow}piccadilly{light gray}","{pink}go{light gray} {light blue}to{light gray} {white}jail{light gray}"
895 DATA"{green}regent street.{light gray}"
900 DATA"{green}oxford street.{light gray}","{yellow}community chest{light gray}","{green}bond street.{light gray}"
905 DATA"{gray}liverpool st.{light gray}"
910 DATA"{pink}chance{light gray}","{blue}park lane{light gray}","{light blue}super tax{light gray}","{blue}mayfair{light gray}","{pink}in jail{light gray}"
920 DATAgo,p,purple,60,2,10,30,90,160,250,30,50,cc,p,purple,60,4,20,60,180,320
930 DATA450,30,50,it,rr,p,lt. blue,100,6,30,90,270,400,550,50,50,ch,p,lt. blue
940 DATA 100,6,30,90,270,400,550,50,50,p,lt. blue,120,8,40,100,300,450,600,60,50
950 DATAjv,p,maroon,140,10,50,150,450,625,750,70,100,u,p,maroon,140,10,50,150,450
960 DATA625,750,70,100,p,maroon,160,12,60,180,500,700,900,80,100,rr
970 DATAp,orange,180,14,70,200,550,750,950,90,100,cc,p,orange
980 DATA 180,14,70,200,550,750,950,90,100
990 DATAp,orange,200,16,80,220,600,800,1000,100,100,fp,p,red
1000 DATA 220,18,90,250,700,875
1010 DATA1050,110,150,ch,p,red,220,18,90,250,700,875,1050,110,150,p,red,240
1020 DATA 20,100,300
1030 DATA750,925,1100,120,150,rr,p,yellow,260,22,110,330,800,975,1150,130,150
1040 DATA p,yellow,260
1050 DATA22,110,330,800,975,1150,130,150,u,p,yellow,280,24,120,360,850,1025,1200
1060 DATA 140
1070 DATA150,gtj,p,green,300,26,130,390,900,1100,1275,150,200,p,green
1080 DATA 300,26,130,390,900
1090 DATA1100,1275,150,200,cc,p,green,320,28,150,450,1000,1200,1400
1100 DATA 160,200,rr,ch
1110 DATAp,dk. blue,350,35,175,500,1100,1300,1500,175,200,lt,p,dk. blue
1120 DATA 400,50,200,600,1400
1130 DATA1700,2000,200,200,ij
1140 DATA pay poor tax  {pound}15,go directly to jail,advance to go(collect {pound}200)
1150 DATA your building and loan matures            collect {pound}150
1160 DATA advance token to nearest station        {pound} pay owner twice rent
1170 DATAadvance to trafalgar sq.,bank pays you dividend of {pound}50
1180 DATAget out of jail free,pay each player {pound}50,advance to pall mall
1190 DATAtake a ride on to kings cross,go back three spaces,advance to mayfair
1200 DATAmake general repairs  {pound}25 for each house{pound}100 for each hotel
1210 DATA advance token to nearest station        {pound} pay owner twice rent
1220 DATA advance token to nearest utility        roll dice & pay 10*# shown
1230 DATA get out of jail free,go to jail,advance to go(collect {pound}200)
1240 DATA from sale of stock you get {pound}45,collect {pound}50 from every player
1250 DATA receive for services {pound}25,pay school fee of {pound}150,tax refund collect {pound}20
1260 DATA assessed for repairs  {pound}40 per house     {pound}115 per hotel
1270 DATA you have won second prize in a beauty   contest collect {pound}10
1280 DATA you inherit {pound}100,xmas fund matures collect {pound}100,pay hospital {pound}100
1290 DATA bank error  in your favor collect {pound}200,doctors fee pay {pound}50
1300 DATA life insurance matures collect {pound}100
1310 GOTO6360
1320 PRINT"{clear}{reverse on}{brown}{space*3}{sh space}{light gray}{cm g}{sh space*2}{cm g}{sh space*2}{cm g}{sh space*2}{cm g}{sh space*2}{gray}{cm b*3}{light gray}{cm g}{sh space*2}{cm g}{space*2}{cm g}{light green}ww{light gray}{cm g}{sh space*2}{pink}{cm g}gtj{reverse off}"
1330 PRINT"{reverse on}{brown}{sh space}fp{sh space}{light gray}{cm g}{sh space*2}{cm g}{pink}?{light gray}{sh space}{cm g}{sh space*2}{cm g}{sh space*2}{gray}{cm g}{sh space*2}{light gray}{cm g}{sh space*2}{cm g}{sh space} {cm g}{light green}{cm a}{cm e}{light gray}{cm g}{sh space*2}{light blue}{cm g}{space*3}{reverse off}"
1340 PRINT"{reverse on}{brown}{space*3}{sh space}{red}{space*3}{light gray}{cm g}{sh space*2}{red} {sh space*2}{cm g}{space*2}{gray}fss{yellow}{cm g}{space*2}{cm g}{sh space*2}{light gray}{cm g}{sh space*2}{yellow} {sh space*2}{white}{cm g}EW {light gray}{reverse off}"
1350 PRINT"{reverse on}{cm t*3}{orange} {light gray}O{cm t*26}{green} {light gray}{cm t*3}{reverse off}"
1360 PRINT"{reverse on}{space*3}{orange} {light gray}{cm g}{space*2}NM{space*22}{green} {light gray}{sh space}{space*2}{reverse off}"
1370 PRINT"{reverse on}{cm t*3}{orange}{cm t}{light gray}{cm g} {yellow}N{space*2}{light gray}M 1-{space*18}{green}{cm t}{light gray}{cm t*3}{reverse off}"
1380 PRINT"{reverse on}{space*3}{orange} {light gray}{cm g}N{yellow}c c{light gray}N{space*21}{green} {light gray}{space*3}{reverse off}"
1390 PRINT"{reverse on}{cm t*4}{cm g}M{yellow}{space*2}N{light gray}{space*2}2-{space*18}O{cm t*3}{reverse off}"
1400 PRINT"{reverse on}{yellow}cc{light gray}{space*2}{cm g} MN{space*23}{yellow}cc{light gray}{space*2}{reverse off}"
1410 PRINT"{reverse on}{cm t*3}{orange} {light gray}{cm g}{space*3}{cm @*3}{space*12}{cm @*3}{space*5}{green} {light gray}{cm t*3}{reverse off}"
1420 PRINT"{reverse on}{space*3}{orange} {light gray}{cm g}{space*2}{cm m}{white}{space*3}{light gray}{cm g}{space*10}{cm m}{white}{space*3}{light gray}{cm g}{space*4}{green} {light gray}{space*3}{reverse off}"
1430 PRINT"{reverse on}{gray}{cm b}ms{cm b}{light gray}{cm g}{space*2}{cm m}{white}{space*3}{light gray}{cm g} {white}monopole{light gray} {cm m}{white}{space*3}{light gray}{cm g}{space*3}{cm m}{gray}{cm b}ls{cm b}{reverse off}"
1440 PRINT"{reverse on}{cm b}{space*2}{cm b}{light gray}{cm g}{space*2}{cm m}{white}{space*3}{light gray}{cm g}{space*2}{white}cbm-64{light gray}{space*2}{cm m}{white}{space*3}{light gray}{cm g}{space*3}{cm m}{gray}{cm b}{space*2}{cm b}{light gray}{reverse off}"
1450 PRINT"{reverse on}{cm t*3}{156} {light gray}{cm g}{space*3}{cm t*3}{space*12}{cm t*3}{space*5}O{cm t*3}{reverse off}"
1460 PRINT"{reverse on}{space*3}{156} {light gray}{cm g}{space*26}{cm g}{pink}?{light gray}{space*2}{reverse off}"
1470 PRINT"{reverse on}{cm t*3}{156}{cm t}{light gray}{cm g}{space*22}NM{space*2}{blue} {light gray}{cm t*3}{reverse off}"
1480 PRINT"{reverse on}{space*3}{156} {light gray}{cm g}{space*21}{pink}N{space*2}{light gray}M {blue} {light gray}{space*3}{reverse off}"
1490 PRINT"{reverse on}{cm t}{light green}ec{light gray}{cm t}{cm g}{space*20}N{pink}{?*3}{light gray}N {light blue}tax{light gray}{cm t}{reverse off}"
1500 PRINT"{reverse on}{space*4}{cm g}{space*20}M{pink}{space*2}N{light gray}{space*2}{cm g}{space*3}{reverse off}"
1510 PRINT"{reverse on}{cm t*3}{156} {light gray}{cm g}{space*21}MN{space*3}{blue} {light gray}{cm t*3}{reverse off}"
1520 PRINT"{reverse on}{space*3}{156} {light gray}{cm g}{space*26}{blue} {light gray}{space*3}{reverse off}"
1530 PRINT"{reverse on}{pink}{cm t}{light gray}O{cm t*2}{cyan}{space*3}{cm g}{space*2}{light gray}O{cm t*2}{cyan}{space*3}{gray}Okc{light gray}O{cm t*2}{reverse off}{space*3}{reverse on}O{cm t*2}{reverse off}{space*3}{reverse on}{green}O{cm t*3}{reverse off}"
1540 PRINT"{reverse on}{pink} {light gray}{cm g}{space*2}{cm g}{space*2}{cm g}{space*2}{cm g}{pink}?{light gray}{sh space}{cm g}{sh space*2}{gray}{cm g}{sh space*2}{light gray}{cm g}{sh space*2}{cm g}{sh space*2}{cm g}{space*2}{cm g}{space*2}{green}{cm g}go {reverse off}"
1550 PRINT"{reverse on}{pink} {cm t*3}{light gray}{cm g}{space*2}{cm g}{space*2}{cm g}{space*2}{cm g}{space*2}{gray}{cm b*3}{light blue}tax{light gray}{cm g}{space*2}{cm g}{yellow}cc{light gray}{cm g}{space*2}{green}{cm g}{arrow left}{sh asterisk} {reverse off}{white}"
1560 RETURN
1570 PRINT"{home}{light gray}";LEFT$(cr$,x);LEFT$(cd$,y);z$;"{white}"
1580 RETURN
1590 dc$(1)="{reverse on}{space*3}{down}{left*3} Q {down}{left*3}{space*3}{reverse off}":dc$(2)="{reverse on}{space*2}Q{down}{left*3}{space*3}{down}{left*3}Q{space*2}{reverse off}"
1600 dc$(3)="{reverse on}Q{space*2}{down}{left*3} Q {down}{left*3}{space*2}Q{reverse off}":dc$(4)="{reverse on}Q Q{down}{left*3}{space*3}{down}{left*3}Q Q{reverse off}"
1610 dc$(5)="{reverse on}Q Q{down}{left*3} Q {down}{left*3}Q Q{reverse off}":dc$(6)="{reverse on}Q Q{down}{left*3}Q Q{down}{left*3}Q Q{reverse off}":RETURN
1620 ct=0
1630 r1=INT(RND(1)*6)+1:r2=INT(RND(1)*6)+1:dr=r1+r2
1635 FORi=1TO6:POKEg(i),dr*10:NEXT
1640 PRINT"{home}";LEFT$(cr$,x1);LEFT$(cd$,y1);dc$(r1)
1650 PRINT"{home}";LEFT$(cr$,x2);LEFT$(cd$,y2);dc$(r2)
1655 FORi=1TO6:POKEg(i),0:NEXT
1660 ct=ct+1:IFct<7THENFORdelay=1TO75:NEXT:GOTO1630
1670 IFr1=r2THENdb=db+1:GOTO1690
1680 db=0
1690 RETURN
1700 PRINT"{clear}":PRINT
1710 PRINT" collect {pound}200 as you pass{space*2}{reverse on}{green}{cm d}{cm i}{right}{cm d}{cm f}{down}{left*5}{cm c}{cm v}{right}{cm c}{cm v}{white}{reverse off}"
1720 m(pt)=m(pt)+200:PRINT:PRINT:PRINT
1730 PRINT"{right*8}{reverse on}hit any key to continue{reverse off}"
1740 GETw$:IFw$<>""THEN1740
1750 GETk$:IFk$=""THEN1750
1760 RETURN
1770 POKE198,0:pt$=pt$(pl(pt))
1780 IFpt$="p"THEN1900
1790 IFpt$="rr"THEN2380
1800 IFpt$="go"THENRETURN
1810 IFpt$="u"THEN2700
1820 IFpt$="fp"THEN3010
1830 IFpt$="jv"THENRETURN
1840 IFpt$="gtj"THEN3150
1850 IFpt$="it"THEN3210
1860 IFpt$="lt"THEN3190
1870 IFpt$="cc"THEN3230
1880 IFpt$="ch"THEN3470
1890 IFpt$="ij"THEN3880
1900 PRINT"{clear}";TAB(15);"title deed"
1910 IFgfTHEN1950
1920 PRINT" player"pt
1930 po=3-pt
1940 pl=pl(pt):p7=pt
1950 PRINTTAB(20-(LEN(pn$(pl))-1)/2)"{reverse on}";pn$(pl)"{reverse off}"
1955 PRINTLEFT$(pn$(pl),1):qr=PEEK(646):POKE53280,qr:PRINT"{up*2}{white}"
1960 PRINT
1970 PRINT"{space*17}rent {pound}";p(pl,2)
1980 PRINT"{space*11}with 1 house{space*2}{pound}";p(pl,3)
1990 PRINT"{space*11}with 2 houses{space*2}";p(pl,4)
2000 PRINT"{space*11}with 3 houses{space*2}";p(pl,5)
2010 PRINT"{space*11}with 4 houses{space*2}";p(pl,6)
2020 PRINT"{space*11}with hotel{space*2}{pound}";p(pl,7)
2030 PRINT
2040 PRINT"{space*11}mortage value{space*2}{pound}";p(pl,8)
2050 PRINT"{space*10}houses cost {pound}";p(pl,9);"each"
2060 PRINT"{space*6}hotels, {pound}";p(pl,9);". plus 4 houses"
2070 IFgfTHENPRINT:PRINT:GOSUB1730:POKE53280,0:RETURN
2080 PRINT:FORi=1TO41:IFc$(pl)=c$(i)ANDi<>plTHENGOSUB2100
2090 NEXT:GOTO2120
2100 IFps(i)THENPRINT" "pn$(i)"{white}{space*2}owned by {reverse on}player #"ps(i):RETURN
2110 PRINT" "pn$(i)"{white} still for sale.":RETURN
2120 PRINT
2130 IFmg(pl)=1THENPRINT" mortaged for {pound}"p(pl,8)
2140 PRINT" cost{space*3}{pound}";p(pl,1)
2150 IFps(pl)=0THEN2200
2160 PRINT" {reverse on}owned{reverse off} by player"ps(pl):IFh(pl)THENPRINT"{reverse on}with";
2170 IFh(pl)<5THENPRINTh(pl)"houses."
2180 IFh(pl)=5THENPRINT" a {reverse on}hotel"
2190 GOTO2250
2200 PRINT" you have {pound}";m(p7)
2210 PRINT" do you wish to buy this property";:INPUT"{space*2}{cm b}{left*3}";a$:a$=LEFT$(a$,1)
2220 IFa$="n"THEN2310
2230 IFa$<>"y"THENPRINT"{up*2}":GOTO2210
2240 PRINT" ok you bought ";pn$(pl)"{white}":m(p7)=m(p7)-p(pl,1):ps(pl)=pt:GOTO2300
2250 ow=p(pl,h(pl)+2):IFps(pl)=ptTHEN2300
2260 IFmg(pl)THEN2300
2270 p5=po:p6=ps(pl):GOSUB2320:IFoaTHENIFh(pl)=0THENow=ow*2
2280 m(pt)=m(pt)-ow:m(ps(pl))=m(ps(pl))+ow:PRINT" you owe $";ow
2290 m(ps(pl))=m(ps(pl))+ow
2300 GOSUB1730:POKE53280,0:RETURN
2310 GOSUB6040:GOTO2300
2320 mg=0:oa=0:pc=0:FORi=1TO41:IFc$(pl)=c$(i)ANDps(i)=p5THENpc=pc+1:IFmg(i)THENmg=mg
2330 NEXT
2340 IFpc=2ANDc$(pl)="purple"THENoa=1:RETURN
2350 IFpc=2ANDc$(pl)="dk. blue"THENoa=1:RETURN
2360 IFpc=3THENoa=1:RETURN
2370 RETURN
2380 PRINT"{clear}":pl=pl(pt)
2390 PRINT"player"pt
2400 PRINT"{space*19}{pink}X{gray} {reverse on}{cm d}{reverse off}"
2410 PRINT"{space*19}{reverse on}{space*3}{reverse off}"
2420 PRINT"{space*18}N{brown}W W{white}"
2430 PRINT
2440 PRINTTAB(20-LEN(pn$(pl))/2)"{reverse on}";pn$(pl)"{white}{reverse off}"
2442 POKE54276,129:POKE54288,17:POKE54290,17
2443 ko=129:FORt=1TO2:FORi=1TO6:POKEg(i),ko:NEXT:FORdl=1TO400:NEXT
2444 FORi=1TO6:POKEg(i),0:NEXT:FORdl=1TO60:NEXT:NEXT
2445 POKE54276,33:POKE54288,33:POKE54290,33     
2450 PRINT:PRINT"rent{space*21}{pound}25"
2460 PRINT"if 2 r.r.'s are owned{space*5}50"
2470 PRINT"if 3 r.r.'s are owned{space*4}100"
2480 PRINT"if 4 r.r.'s are owned{space*4}200"
2490 PRINT
2500 PRINT"mortage value{space*12}{pound}100"
2510 PRINT:IFmg(pl)=1THENPRINT"mortaged for {pound}100":GOTO2690
2520 PRINT"cost{space*3}{pound}200"
2530 PRINT:FORi=1TO41:IFpt$(i)="rr"THENGOSUB2550
2540 NEXT:GOTO2570
2550 IFps(i)THENPRINTpn$(i)"{white} owned by player #";ps(i):RETURN
2560 PRINTpn$(i)"{white} still for sale.":RETURN
2570 IFps(pl)THENPRINT"{reverse on}owned{reverse off} by player#";ps(pl):GOTO2650
2580 PRINT"you have {pound}"m(pt)
2590 PRINT"do you wish to buy it";:INPUT"{space*2}{cm b}{left*3}";b$:b$=LEFT$(b$,1)
2600 IFb$="n"THENGOSUB6040:GOTO2690
2610 IFb$<>"y"THENPRINT"{up*2}":GOTO2590
2620 m(pt)=m(pt)-200:ps(pl)=pt
2630 PRINT"ok you bought it"
2640 GOTO2690
2650 ow=0:o7=0
2660 IFps(pl)=ptTHEN2690
2670 ow=25:FORi=6TO36STEP10:IFpt$(i)="rr"ANDps(i)=ps(pl)THENow=ow*2
2680 NEXT:ow=ow/dv:PRINT"you owe {pound}";ow:m(pt)=m(pt)-ow:m(ps(pl))=m(ps(pl))+ow
2690 GOSUB1730:RETURN
2700 PRINT"{clear}"
2710 PRINT"player"pt
2720 PRINT"{space*12}{yellow}N{cm t}M{space*5}{gray}WQW{space*4}"
2730 PRINT"{space*12}{yellow}M{pink}^{yellow}N{space*4}{gray}{cm q}{sh asterisk}{cm e}{sh asterisk*3}I "
2740 PRINT"{space*13}{yellow}{cm g*2}{space*4}{gray}{cm q}{sh asterisk*4}IH "
2750 PRINT"{space*13}{cm +}{space*10}{cm z}{cm x}{white} ":PRINT
2760 pl=pl(pt)
2770 PRINTTAB(20-LEN(pn$(pl))/2)"{reverse on}";pn$(pl)"{white}{reverse off}"
2780 PRINT:PRINT"if one 'utility is owned pay 4 times theamount shown on dice"
2790 PRINT
2800 PRINT"if both owned pay 10 V amount on dice"
2810 d1=INT(RND(1)*6)+1:d2=INT(RND(1)*6)+1
2820 IFdfTHENd1=r1:d2=r2
2830 PRINT:PRINT"mortage value{space*2}{pound}75":PRINT
2840 IFmg(pl)=1THENPRINT"mortaged for {pound}75":GOTO3000
2850 IFps(42-pl)THENPRINTpn$(42-pl)"{white} owned by player"ps(42-pl):GOTO2870
2860 PRINTpn$(42-pl)"{white} still for sale."
2870 PRINT:IFps(pl)THENPRINT"{reverse on}owned{reverse off} by player#";ps(pl):GOTO2950
2880 PRINT"you have {pound}"m(pt)
2890 INPUT"do you wish to buy it{space*2}{cm b}{left*3}";b$:b$=LEFT$(b$,1)
2900 IFb$="n"THENGOSUB6040:GOTO3000
2910 IFb$<>"y"THENPRINT"{up*2}":GOTO2890
2920 PRINT"ok you bought ";pn$(pl)"{white}"
2930 m(pt)=m(pt)-150
2940 ps(pl)=pt:GOTO3000
2950 IFps(pl)=ptTHEN3000
2960 PRINT"dice show"d1"and"d2"."
2970 mt=4:IFps(13)=ps(pl)ANDps(29)=ps(pl)THENmt=10
2980 IFdf=0THENmt=10
2990 ow=mt*(d1+d2):PRINT"you owe {pound}";ow:m(pt)=m(pt)-ow:m(ps(pl))=m(ps(pl))+ow
3000 mt=0:GOSUB1730:RETURN
3010 PRINT"{clear}"
3020 PRINT"{space*17}{orange}free
3030 PRINT"{space*16}{green}U{C*5}I"
3040 PRINT"{space*16}B {cyan}{cm a}{sh asterisk}{cm s}{green} H
3050 PRINT"{space*16}{sh -} {cyan}{cm z}{sh asterisk}{cm x}{green} {sh -}
3060 PRINT"{space*16}H {brown}UCI{green} B
3070 PRINT"{space*14}U{sh asterisk}{cm x} {brown}B{gray}Q{brown}H{green} {cm z}{sh asterisk}I
3080 PRINT"{space*14}{sh -}{space*3}{brown}JFK{green}{space*3}{sh -}
3090 PRINT"{space*14}{cm z}{sh asterisk}{gray}{cm pound}{green}{sh asterisk*5}{gray}{cm pound}{green}{sh asterisk}{cm x}
3100 PRINT"{space*16}{gray}{cm +}{space*5}{cm +}
3110 PRINT:PRINT"{space*16}{orange}parking{white}":PRINT
3120 IFpf=0THENGOSUB1730:RETURN
3130 PRINT:PRINT"{space*7}you get the free parking"
3140 PRINT"{space*10}jackpot of {pound}"fp"!":m(pt)=m(pt)+fp:fp=0:PRINT:GOSUB1730:RETURN
3150 PRINT"{clear}";TAB(15);"go to jail"
3160 IFdb=3THENPRINT:PRINT" for rolling doubles 3 times in a row!":PRINT
3170 PRINTTAB(16);"{dark gray}{cm a}{cm r*6}{cm s}":FORi=1TO5:PRINTTAB(16);"{sh -*8}":NEXT
3175 PRINTTAB(16);"{cm z}{cm e*6}{cm x}":PRINT:pl(pt)=41:jf=1:db=0
3180 FORko=1TO3:FORt=60TO110STEP1.7:FORi=1TO6:POKEg(i),t:NEXT:NEXT
3182 FORdl=1TO10:NEXT
3183 FORt=110TO60STEP-1.7:FORi=1TO6:POKEg(i),t:NEXT:NEXT:NEXT
3184 FORi=1TO6:POKEg(i),0:NEXT
3185 PRINT"{white}";:GOSUB1730:RETURN
3190 PRINT"{clear}";TAB(15);"super tax":PRINT:PRINTTAB(16);"pay $75"
3200 PRINT:PRINT:PRINT:m(pt)=m(pt)-75:fp=fp+75:GOSUB1730:RETURN
3210 PRINT"{clear}";TAB(15);"income tax":PRINT:PRINTTAB(16);"pay $200"
3220 PRINT:PRINT:PRINT:m(pt)=m(pt)-200:fp=fp+200:GOSUB1730:RETURN
3230 cc=cc+1:IFcc>16THENcc=cc-16
3240 po=3-pt:cc$=cc$(cc):IFcc=1ANDcj(1)THENcc=cc+1:cc$=cc$(cc)
3250 PRINT"{clear}{down}{space*11}{yellow}community chest{white}{down*2}":PRINTcc$"{down*2}"
3260 IFcc=1THENcj(1)=pt
3270 IFcc=2THENGOSUB1730:GOTO3150
3280 IFcc=3THENpl(pt)=1:mf=1:GOSUB1730:GOSUB1700:RETURN
3290 IFcc=4THENm(pt)=m(pt)+45
3300 IFcc=5THENm(pt)=m(pt)+50:m(po)=m(po)-50
3310 IFcc=6THENm(pt)=m(pt)+25
3320 IFcc=7THENm(pt)=m(pt)-150:fp=fp+150
3330 IFcc=8THENm(pt)=m(pt)+20
3340 IFcc=9THENGOSUB3430
3350 IFcc=10THENm(pt)=m(pt)+10
3360 IFcc=11THENm(pt)=m(pt)+100
3370 IFcc=12THENm(pt)=m(pt)+100
3380 IFcc=13THENm(pt)=m(pt)-100
3390 IFcc=14THENm(pt)=m(pt)+200
3400 IFcc=15THENm(pt)=m(pt)-50
3410 IFcc=16THENm(pt)=m(pt)+100
3420 GOSUB1730:RETURN
3430 yp=0:FORi=1TO40
3440 IFps(i)=(pt)ANDh(i)<5THENyp=yp+(40*h(i))
3450 IFps(i)=(pt)ANDh(i)=5THENyp=yp+115
3460 NEXT:PRINT"{down}you pay $"yp:m(pt)=m(pt)-yp:fp=fp+yp:RETURN
3470 ch=ch+1:IFch>16THENch=ch-16
3480 po=3-pt:ch$=ch$(ch):IFch=8ANDcj(2)THENch=ch+1:ch$=ch$(ch)
3490 PRINT"{clear}{down}{space*10}{pink}? ? chance ? ?{white}{down*2}":PRINTch$"{down*2}"
3500 IFch=1THENm(pt)=m(pt)-15:fp=fp+15
3510 IFch=2THENGOSUB1730:GOTO3150
3520 IFch=3THENpl(pt)=1:mf=1:GOSUB1730:GOSUB1700:RETURN
3530 IFch=4THENm(pt)=m(pt)+150
3540 IFch=5THENGOSUB3670:mf=1
3550 IFch=6THENGOSUB3710:mf=1
3560 IFch=7THENm(pt)=m(pt)+50
3570 IFch=8THENcj(2)=pt
3580 IFch=9THENm(pt)=m(pt)-50:m(po)=m(po)+50
3590 IFch=10THENGOSUB3730:mf=1
3600 IFch=11THENGOSUB3750:mf=1
3610 IFch=12THENpl(pt)=pl(pt)-3:mf=1
3620 IFch=13THENGOSUB3770:mf=1
3630 IFch=14THENGOSUB3790
3640 IFch=15THENGOSUB3670:mf=1
3650 IFch=16THENGOSUB3830:mf=1
3660 GOSUB1730:RETURN
3670 pl(pt)=pl(pt)+1:IFpl(pt)>40THENGOSUB6540:pl(pt)=pl(pt)-40
3680 IFpt$(pl(pt))="rr"THEN3700
3690 GOTO3670
3700 dv=1:RETURN
3710 IFpl(pt)>25THENGOSUB6540
3720 pl(pt)=25:RETURN
3730 IFpl(pt)>12THENGOSUB6540
3740 pl(pt)=12:RETURN
3750 IFpl(pt)>6THENGOSUB6540
3760 pl(pt)=6:RETURN
3770 pl(pt)=40:RETURN
3780 RETURN
3790 df=0:yp=0:FORi=1TO40
3800 IFps(i)=(pt)ANDh(i)<5THENyp=yp+(25*h(i))
3810 IFps(i)=(pt)ANDh(i)=5THENyp=yp+100
3820 NEXT:PRINT"you pay $"yp:m(pt)=m(pt)-yp:fp=fp=yp:RETURN
3830 pl(pt)=pl(pt)+1
3840 IFpl(pt)>40THENGOSUB6540:pl(pt)=pl(pt)-40
3850 IFpt$(pl(pt))="u"THEN3870
3860 GOTO3830
3870 mf=1:RETURN
3880 PRINT"{clear}{down}"
3890 jt(pt)=jt(pt)+1
3900 PRINT"player #"pt"is in jail"
3910 PRINT:PRINT"you have been in"jt(pt)"turns"
3920 PRINT"you may:{space*2}1.{space*2}pay {pound}50"
3930 PRINT"{space*10}2.{space*2}use{space*2}a 'get out of jail{space*17}free card."
3940 PRINT"{space*10}3.{space*2}try to roll doubles."
3950 PRINT:INPUT"choice";i:IFi<1ORi>3THEN3950
3960 IFi=1THENm(pt)=m(pt)-50:fp=fp+50:pl(pt)=11:GOSUB1730:je=1:RETURN
3970 IFi=2ANDcj(1)=ptTHENcj(1)=0:pl(pt)=11:GOSUB1730:je=1:RETURN
3980 IFi=2ANDcj(2)=ptTHENcj(2)=0:pl(pt)=11:GOSUB1730:je=1:RETURN
3990 IFi=2THENPRINT"you don't have a card":GOTO3950
4000 IFi=3THENGOSUB1620:IFdbTHEN4060
4010 PRINT"you didn't roll doubles."
4020 IFjt(pt)>2THENPRINT"you must pay the {pound}50":m(pt)=m(pt)-50:pl(pt)=11:jb=1
4030 IFjt(pt)>2THENGOSUB1730:fp=fp+50:RETURN
4040 GOSUB1730:RETURN
4050 IFpl(pt)=11THENGOSUB1730:je=1:RETURN
4060 PRINT"you made it out{!*3}":pl(pt)=11:GOSUB1730:jb=1:db=0:RETURN
4070 GOTO6200
4080 PRINT"{clear}":IFpfTHENPRINT"money in free parking jackpot {pound}";fp
4090 PRINT"player 1 has {pound}";m(1):PRINT"player 2 has {pound}";m(2)
4100 PRINT:PRINT"player";pt"up."
4110 PRINT:PRINT:PRINTTAB(15);"options"
4120 PRINT
4130 PRINT"{space*3}r=review properties"
4140 PRINT"{space*3}l=list all properties"
4150 PRINT"{space*3}b=build houses/hotels"
4160 PRINT"{space*3}s=sell properties to other player"
4170 PRINT"{space*3}m=mortage properties(sell houses)"
4180 PRINT"{space*3}d=display title deeds"
4190 PRINT"{space*3}q=return to game"
4200 PRINT"{space*2}xx=end game":PRINT
4210 INPUT"choice{space*2}{cm b}{left*3}";c$
4220 IFc$="{cm b}"THEN4210
4230 IFc$="r"THENGOSUB4320
4240 IFc$="l"THENGOSUB4490
4250 IFc$="b"THENGOSUB4640
4260 IFc$="s"THENGOSUB5080
4270 IFc$="m"THENGOSUB5440
4280 IFc$="d"THENGOSUB6510
4290 IFc$="q"THENRETURN
4300 IFc$="xx"THEN6280
4310 GOTO4080
4320 INPUT"for which player (1 or 2)";pn
4330 IFpn<1ORpn>2THEN4320
4340 PRINT"{clear}{down}"
4350 PRINTTAB(6)"properties for player ";pn
4360 PRINT
4370 FORi=1TO40:po$="":IFps(i)=pnTHENPRINTpn$(i);
4380 IFps(i)<>pnTHEN4450
4390 IFpt$(i)<>"p"THEN4430
4400 PRINTSPC(20-(LEN(pn$(i))-2));"{white} -";:IFh(i)<5THENpo$=STR$(h(i))+" hs"
4410 IFh(i)=5THENpo$=" {reverse on}hotel{reverse off}"
4420 po$=po$+"/{pound}"+MID$(STR$(p(i,h(i)+2)),2)
4430 IFmg(i)=1THENpo$="- mortaged"
4440 PRINTpo$
4450 NEXT
4460 PRINT:IFcj(1)=pnORcj(2)=pnTHENPRINT"{white}get out of jail free card."
4470 PRINT"{white}player"pn"has {pound}";m(pn)
4480 PRINT:GOSUB1730:RETURN
4490 PRINT"{clear}"
4500 tt$="name{space*28}owner/{down}{left*6}#houses":PRINTtt$
4510 FORk=1TO40:IFpt$(k)<>"p"ANDpt$(k)<>"rr"ANDpt$(k)<>"u"THEN4600
4520 PRINTpn$(k)"{white}";TAB(21);
4530 PRINTTAB(33)
4540 p$=STR$(ps(k)):pp$=MID$(STR$(h(k)),2):IFh(k)>4THENpp$="h"
4550 IFpt$(k)<>"p"THENpp$="x"
4560 IFmg(k)THENpp$="{reverse on}mg{reverse off}"
4570 p$=p$+" -"+pp$
4580 IFps(k)=0THENp$=" none"
4590 PRINTp$
4600 IFk=20THENPRINT:GOSUB1730:PRINT"{clear}":PRINTtt$
4610 NEXTk
4620 PRINT:GOSUB1730
4630 RETURN
4640 PRINT"{clear}{down*2}"
4650 ho=0
4660 PRINT" on which group":PRINTpg$
4670 PRINT
4680 INPUT"which color";c$
4690 FORi8=1TO41:IFc$=LEFT$(c$(i8),LEN(c$))THENpl=i8:c$=c$(i8):GOTO4720
4700 NEXTi8
4710 PRINT"illegal group":GOTO4680
4720 p7=pt
4730 p5=p7:GOSUB2320:IFmgTHENoa=0
4740 IFoaTHEN4770
4750 PRINT"sorry you either don't own all the prop-erty in that group or some";
4760 PRINT" is mortaged.":GOSUB1730:RETURN
4770 PRINT"{space*3}property name{space*4}# of houses(5=hotel)"
4780 hs=0:FORi=plTOpl+4:IFc$=c$(i)THENPRINTpn$(i)"{white}";TAB(30);h(i):hs=hs+h(i)
4790 NEXT
4800 PRINT:PRINT"houses for this group cost $"p(pl,9)"each"
4810 PRINT"hotels cost {pound}"p(pl,9)"+ 4 houses or {pound}";(p(pl,9)*5)
4820 PRINT
4830 PRINT"you have {pound}"m(pt)
4840 PRINT"hotels automatically added after 4th{space*4}house"
4850 PRINT"how{space*2}many houses do you want to buy (max=";:mx=((5*pc)-hs):PRINTmx")"
4860 INPUThn:IFhn>mxTHENGOTO4850
4870 h7=INT(hn/pc):h8=hn-(h7*pc)
4880 IFm(p7)<(hn*p(pl,9))THENPRINT"you don't have enough money!":GOTO4850
4890 IFhn=0THENPRINT"ok":GOSUB1730:RETURN
4900 m(p7)=m(p7)-(hn*p(pl,9)):FORe=plTOpl+4:IFc$=c$(e)THENh(e)=h(e)+h7
4910 NEXT
4920 IFh8THEN4940
4930 GOTO5070
4940 PRINT"you have"h8"houses left over"
4950 PRINT:f1=0:FORf=plTOpl+4:IFc$=c$(f)THENf1=f1+1:PRINTf1,pn$(f);"{space*2}"h(f)
4960 NEXT:PRINT:FORg=1TOh8
4970 PRINT"where do you want house #"g;:INPUThl:IFhl=hoTHENPRINT"can't":GOTO4970
4980 f2=0:f1=0:f9=0
4990 FORf=plTOpl+3:IFc$=c$(f)THENf1=f1+1:IFf1=hlTHENf9=f
5000 NEXTf
5010 IFf9=0THENPRINT"no such number":GOTO4970
5020 h2=0:FORf=plTOpl+3:IFc$=c$(f)THENIFh(f9)>h(f)THENh2=h2+1
5030 NEXT
5040 IFh2THENPRINT"illegal distribution of houses!":GOTO4970
5050 ho=hl:h(f9)=h(f9)+1
5060 NEXTg
5070 PRINT"done":GOSUB1730:RETURN
5080 INPUT"what player has a property to sell";p1
5090 IFp1=0THENGOSUB1730:RETURN
5100 p2=p1+1:IFp2>2THENp2=p2-2
5110 PRINT"is it a property";:INPUTq$:IFLEFT$(q$,1)="n"THEN5320
5120 PRINT"in what color group":PRINTpg$
5130 PRINT:INPUT"which";c$
5140 FORi6=1TO41:IFc$=LEFT$(c$(i6),LEN(c$))THENpl=i6:c$=c$(i6):GOTO5170
5150 NEXTi6
5160 PRINT"illegal group":GOTO5130
5170 PRINT"#{space*2}property";TAB(30);"owner"
5180 ho=0:ct=0:FORi=plTOpl+4:IFc$=c$(i)THENct=ct+1:PRINTct"{space*3}"pn$(i)"{white}";TAB(35);ps(i)
5190 IFh(i)THENho=1
5200 NEXT
5210 PRINT:PRINT"what number does player"p1"want{space*10}to sell"
5220 INPUTtp
5230 ct=0:FORi=plTOpl+4:IFc$=c$(i)THENct=ct+1:IFct=tpTHENt4=i:ff=1
5240 NEXT
5250 IFff=0THENPRINT"illegal number":GOTO5210
5260 IFps(t4)<>p1THENPRINT"player #"p1"does not own it.":GOTO5080
5270 IFhoTHENPRINT"you have houses on that group you can't sell it.":GOTO5310
5280 INPUT "what is the agreed selling price";sp
5290 m(p1)=m(p1)+sp:m(p2)=m(p2)-sp:ps(t4)=p2
5300 PRINT"player #"p2"bought "pn$(t4)"{white}":PRINT"for {pound}"sp
5310 PRINT:GOSUB1730:RETURN
5320 PRINT"property";TAB(30);"owner"
5330 FORi=6TO36STEP10:n=n+1:PRINTn"{space*2}"pn$(i)"{white}";TAB(35);ps(i):NEXT:n=0
5340 PRINT" 5{space*3}"pn$(13)"{white}";TAB(35);ps(13):PRINT" 6{space*3}"pn$(29)"{white}";TAB(35);ps(29)
5350 INPUT"which #";nm:IFnm=0THENRETURN
5360 IFnm<1ORnm>6THEN5350
5370 IFnm=5ANDps(13)=p1THENsn=13:GOTO5410
5380 IFnm=6ANDps(29)=p1THENsn=29:GOTO5410
5390 IFnm>0ANDnm<5THENsn=6+((nm-1)*10):IFps(sn)=p1THENGOTO5410
5400 PRINT"you don't own it.":GOTO5320
5410 INPUT"agreed price";sp
5420 m(p1)=m(p1)+sp:m(p2)=m(p2)-sp:ps(sn)=p2
5430 GOSUB1730:RETURN
5440 PRINT"{clear}{down}":PRINT"{space*2}options{down}":PRINT"0{space*2}return to main menu":PRINT"1{space*2}mortage property"
5450 PRINT"2{space*2}mortage railroad":PRINT"3{space*2}mortage utility"
5460 PRINT"4{space*2}lift mortage(at 10% interest)":PRINT"5{space*2}sell houses":PRINT
5470 INPUT"choice";gg:IFgg<0ORgg>5THEN5470
5480 IFgg=0THENGOSUB1730:RETURN
5490 ONggGOSUB5510,5740,5830,5910,6550
5500 GOTO5440
5510 PRINT:PRINT"on which group is the property to be":PRINT"mortaged located?":PRINTpg$
5520 PRINT:INPUT"color group";c$
5530 FORi6=1TO41:IFc$=LEFT$(c$(i6),LEN(c$))THENpl=i6:c$=c$(i6):GOTO5560
5540 NEXTi6
5550 PRINT"illegal group":GOTO5520
5560 cm=0:FORi=plTOpl+3:IFc$=c$(i)THENcm=cm+h(i)
5570 NEXT
5580 IFcmTHENPRINT"can't mortage properties with houses{space*4}still on that group.":GOTO5730
5590 PRINT"#{space*2}property";TAB(25);"owner"
5600 ct=0:FORi=plTOpl+4:IFc$<>c$(i)THEN5630
5610 ct=ct+1:PRINTct"{space*3}"pn$(i)"{white}";TAB(27)ps(i);:pp$="":IFmg(i)THENpp$="mortaged"
5620 PRINTpp$
5630 NEXT
5640 PRINT:PRINT"what number is to be mortaged.";:INPUTtp
5650 IFtp=0THENGOSUB1730:RETURN
5660 ct=0:FORi=plTOpl+4:IFc$=c$(i)THENct=ct+1:IFct=tpTHENt4=i:ff=1
5670 NEXT
5680 IFff=0THENPRINT"illegal number":GOTO5640
5690 IFps(t4)<>ptTHENPRINT"you don't own it.":GOSUB1730:GOTO5440
5700 IFmg(t4)=1THENPRINT"already mortaged":GOTO5640
5710 PRINT:PRINT"ok":mg(t4)=1
5720 PRINT"you got {pound}"p(t4,8)"for your mortage.":m(pt)=m(pt)+p(t4,8)
5730 GOSUB1730:RETURN
5740 rc=0:FORi=6TO36STEP10:IFpt$(i)="rr"THENrc=rc+1:PRINTrc"{space*2}"pn$(i)"{white}{space*5}plr.#"ps(i)
5750 NEXT
5760 INPUT"which #";rg
5770 IFrg<1ORrg>4THEN5760
5780 rg=6+((rg-1)*10)
5790 IFps(rg)<>ptTHENPRINT"you don't own it.":GOSUB1730:GOTO5440
5800 IFmg(rg)=1THENPRINT"already mortaged.":GOSUB1730:GOTO5440
5810 mg(rg)=1:PRINT"you get {pound}100 for mortage.":m(pt)=m(pt)+100
5820 GOSUB1730:RETURN
5830 u(1)=13:u(2)=29
5840 FORi=1TO2:PRINTi"{space*2}"pn$(u(i))"{white}":NEXT
5850 INPUT"which?";um
5860 IFum<1ORum>2THEN5850
5870 IFps(u(um))<>ptTHENPRINT"you don't own it.":GOSUB1730:GOTO5440
5880 IFmg(u(um))=1THENPRINT"already mortaged.":GOSUB1730:GOTO5440
5890 mg(u(um))=1:PRINT"you get {pound}75 for mortage.":m(pt)=m(pt)+75
5900 GOSUB1730:RETURN
5910 PRINT:PRINT"these are the properties that are under a mortage."
5920 ml=0:FORi=1TO41:IFps(i)=(pt)ANDmg(i)=1THENml=ml+1:PRINTml"{space*2}"pn$(i)"{white}"
5930 NEXT
5940 IFml=0THENPRINT"you have no mortaged properties.":GOSUB1730:RETURN
5950 PRINT:INPUT"which mortage do you wan't to lift";lf
5960 IFlf<1ORlf>mlTHENPRINT"illegal":GOTO5950
5970 ml=0:FORi=1TO41:IFps(i)=(pt)ANDmg(i)=1THENml=ml+1:IFml=lfTHENft=i
5980 NEXT
5990 PRINT"the mortage is for {pound}"p(ft,8)
6000 PRINT"you must pay {pound}";:py=p(ft,8)*1.10:PRINTpy
6010 IFpy>m(pt)THENPRINT"you don't have the money.":GOSUB1730:RETURN
6020 m(pt)=m(pt)-py:mg(ft)=0
6030 GOSUB1730:RETURN
6040 IFafTHEN6060
6050 RETURN
6060 pl=pl(pt):PRINTpn$(pl)"{white} will now be auctioned"
6070 PRINT"to the highest bidder"
6080 po=3-pt:PRINT:hb=0:pa=pt:ac=0:PRINT:hb=0:pa=pt:ac=0
6090 pa=3-pa
6100 PRINT"player"pa"what's your bid";:INPUTbd:bd=INT(bd):ac=ac+1
6110 IFbd=0THENON(ac>1)+2GOTO6140,6090
6120 IFbd<=hbTHENPRINT"you must bid higher than"hb"or bid '0'":GOTO6100
6130 hb=bd:hr=pa:GOTO6090
6140 IFhb=0THEN6190
6150 PRINTpn$(pl)"{white} goes to"
6160 PRINT"player"hr" for $"hb
6170 m(hr)=m(hr)-hb:ps(pl)=hr
6180 RETURN
6190 PRINT:PRINTpn$(pl)"{white} has not been purchased.":RETURN
6200 PRINT"{clear}":PRINT"player #"pt"is broke!!"
6210 PRINT"{down}if you can't raise {pound}"ABS(m(pt))"then you are out of the game."
6220 PRINT"do not hit 'q' (return to game) until{space*3}you finish trying to";
6230 PRINT" raise money"
6240 GOSUB1730:GOSUB4080
6250 IFm(pt)>=0THENRETURN
6260 IFm(pt)<0THENPRINT"you are bankrupt{!*3}":pt=3-pt
6270 PRINT" --player #"pt"wins!-- ":END
6280 PRINT"game over"
6290 PRINT"the winner is ";
6300 IFm(1)>m(2)THENPRINT"player #1 with {pound}"m(1)
6310 IFm(2)>m(1)THENPRINT"player #2 with {pound}"m(2)
6320 IF m(2)=m(1)THENPRINT"neither,{space*2}it's a tie!"
6330 PRINT"player 1 ={space*2}{pound}";m(1)
6340 PRINT"player 2 ={space*2}{pound}";m(2)
6350 PRINT
6360 POKE54296,0:FORi=1TO6:POKEg(i),0:END
6370 FORj=832TO939
6380 READi:POKEj,i:NEXT
6390 DATA 160,0,185,0,4,153,0,192,185,0,5,153,0,193,185,0,6,153,0
6400 DATA 194,185,0,7,153,0,195,185,0,216,153,0,196,185,0,217,153,0
6410 DATA 197,185,0,218,153,0,198,185
6420 DATA 0,219,153,0,199,200,208,205,96,160,0,185,0,192,153,0,4,185,0,193,153
6430 DATA 0,5,185,0,194,153,0,6,185,0,195,153,0,7,185,0,196,153,0,216,185,0,197
6440 DATA 153,0,217,185,0,198,153,0,218,185,0,199,153,0,219,200,208,205,96
6460 RETURN
6470 FORp4=1TO2
6480 y$="{reverse on}"+pn$(pl(p4))+LEFT$("{space*16}",18-(LEN(pn$(pl(p4)))-2))+"{reverse off}"
6490 mn$="{reverse on}{pound}"+MID$(STR$(m(p4)),2)+"{space*4}{reverse off}":x=13:y=2*p4+3:z$=y$:GOSUB1570
6500 y=y+1:z$=mn$:GOSUB1570:NEXT:RETURN
6510 PRINT"{down}display deeds for which color group:{down}":PRINTpg$:INPUTc$:PRINT
6520 p3=pl:FORi=1TO41:IFc$=LEFT$(c$(i),LEN(c$))THENgf=1:pl=i:GOSUB1900:gf=0
6530 NEXT:pl=p3:RETURN
6540 m(pt)=m(pt)+200:PRINT"{down}collected {pound}200{down}":RETURN
6550 PRINT"on which color group:":PRINTpg$:INPUTc$
6560 pl=0:FORi=41TO1STEP-1:IFc$=LEFT$(c$(i),LEN(c$))THENpl=i:c$=c$(i)
6570 NEXTi:IFplTHEN6590
6580 PRINT"illegal group":GOTO6550
6590 do=0:hn=0:FORi=plTOpl+3:IFps(i)<>(pt)ANDc$=c$(i)THENdo=1
6600 IFc$=c$(i)THENhn=hn+h(i)
6610 NEXT
6620 IFdo=1ORhn=0THENPRINT"you don't own houses on these properties":GOSUB1730:RETURN
6630 PRINT"#{space*2}property";TAB(25);"houses(5=hotel)"
6640 ct=0:FORi=plTOpl+3:IFc$=c$(i)THENct=ct+1:PRINTct"{space*3}"pn$(i)"{white}";TAB(27)h(i)
6650 NEXT
6660 INPUT"want to remove all these houses";a$:IFLEFT$(a$,1)="y"THEN6800
6670 PRINT:INPUT"what # to remove a house from.";tp
6680 IFtp=0THEN RETURN
6690 ct=0:FORi=plTOpl+3:IFc$=c$(i)THENct=ct+1:IFct=tpTHENt4=i:ff=1
6700 NEXT
6710 IFff=0THENPRINT"illegal number":GOTO6670
6720 IFh(t4)=0THENPRINT"no houses there.":GOTO6670
6730 nn=0:nh=h(t4):FORi=plTOpl+3:IFh(i)>nhTHENnn=1
6740 NEXT
6750 IFnnTHENPRINT"you can't remove that house.":GOTO6670
6760 PRINT:PRINT"ok.":h(t4)=h(t4)-1
6770 hm=p(pl,9)/2
6780 PRINT"you got {pound}"hm"for your house":m(pt)=m(pt)+hm
6790 GOSUB1730:GOTO5440
6800 hm=0:FORi=plTOpl+3:IFc$=c$(i)THENhm=hm+(p(pl,9)/2)*h(i):h(i)=0
6810 NEXT:PRINT"you got $"hm"for your houses":m(pt)=m(pt)+hm:GOTO6790
stop tok64
(bastext 1.0)