start tok64 d64-DxqM8d
100 REM bioprinter 6.0
110 DIMa%(12),m$(12)
120 PRINT"{clear}"TAB(9)"{reverse on} b i o p r i n t e r "
130 INPUT"{down}input device #, screen=3 printer=4";dv
140 IFdv<>3ANDdv<>4THEN130
150 OPEN4,dv
160 co=39
170 REM*for80 col:ifdv=4thenco=79
180 s$=CHR$(1):cl=INT((co-10)/2):cn=cl+10
190 FORi=1TO10:cr$=cr$+CHR$(13):NEXT
200 FORi=1TOco:sp$=sp$+" ":as$=as$+" ":ar$=ar$+"--":NEXT
210 FORi=1TO12:READa%(i):NEXT
220 FORi=0TO6:READday$(i):NEXT
230 FORi=1TO12:READm$(i):NEXT
240 READdd$
250 INPUT"{down}input your name";n$
260 LETz=0
270 INPUT"{down}input birth date mm,dd,yy";mb,db,yb
280 ms=INT(ms):ds=INT(ds):ys=INT(ys)
290 INPUT"{down}input start date mm,dd,yy";ms,ds,ys
300 mb=INT(mb):db=INT(db):yb=INT(yb)
310 DEFFNi(x)=INT(cl*SIN(2*{pi}*x/33)+.5)
320 DEFFNe(x)=INT(cl*SIN(2*{pi}*x/28)+.5)
330 DEFFNp(x)=INT(cl*SIN(2*{pi}*x/23)+.5)
340 ts=INT(ds+365.25*ys+a%(ms)+.01*ms-.03)
350 tb=INT(db+365.25*yb+a%(mb)+.01*mb-.03)
360 x=ts-tb
370 INPUT"{down}how many days to run";sp
380 PRINT"{down}would you like the biorhythm theory"
390 INPUT"explained on your printout";p$
400 sp=sp-1
410 rb=tb-1-INT((tb-1)/7)*7
420 PRINT"{clear}";
430 PRINT#4,"{down*3}";s$"********** b i o r h y t h m **********"
440 PRINT#4,LEFT$(cr$,2)
450 IFLEFT$(p$,1)="y"THEN GOSUB1130
460 t$=" analysis for "+n$+" "
470 t2$=s$:GOSUB1060
480 PRINT#4,"{space*17}"
490 t$=" born "+day$(rb)+", "+m$(mb)+STR$(db)+", 19"
500 t$=t$+RIGHT$(STR$(INT(yb/10)),1)+RIGHT$(STR$(yb),1)+" "
510 t2$="":GOSUB1060
520 r=ts-1-INT((ts-1)/7)*7
530 GOTO660
540 t$=" starting date "+day$(r)+","+m$(ms)+STR$(ds)+", 19"
550 t$=t$+RIGHT$(STR$(INT(ys/10)),1)+RIGHT$(STR$(ys),1)+" "
560 t2$="":GOSUB1060
570 t$=STR$(INT(23*(x/23-INT(x/23))))+" days into the physical cycle"
580 t2$="":GOSUB1060
590 t$=STR$(INT(28*(x/28-INT(x/28))))+" days into the emotional cycle"
600 t2$="":GOSUB1060
610 t$=STR$(INT(33*(x/33-INT(x/33))))+" days into the intellectual cycle"
620 t2$="":GOSUB1060
630 t$="p = the physical cycle":t2$="":GOSUB1060
640 t$="e = the emotional cycle":t2$="":GOSUB1060
650 t$="i = the intellectual cycle":t2$="":GOSUB1060
660 PRINT#4
670 PRINT#4,SPC(13)"down{space*16}up"
680 GOSUB1300
690 GOSUB1320
700 REM
710 t$=LEFT$(day$(r),3)+" "+MID$(dd$,2*ds-1,2)+" {cm k}"+m$(ms)
720 f(0)=cn:f$(0)="*"
730 f(1)=cn+FNi(x):f$(1)="i"
740 f(2)=cn+FNe(x):f$(2)="e"
750 f(3)=cn+FNp(x):f$(3)="p"
760 f=0
770 FORi=0TO2
780 FORj=i+1TO3
790 IFf(i)<f(j)THEN850
800 IFf(i)=f(j)ANDf(i)=cnTHENIFf(i)=cnTHENf(i)=0:f$(i)="":f$(j)="c":f=1:GOTO850
810 IFf(i)=f(j)THENf(i)=0:f$(i)="":f$(j)="x":GOTO850
820 q=f(i):q$=f$(i)
830 f(i)=f(j):f$(i)=f$(j)
840 f(j)=q:f$(j)=q$
850 NEXTj,i
860 IFf=1THENt$=t$+LEFT$(ar$,cn-1-LEN(t$))
870 FORi=0TO3
880 w=LEN(t$)
890 IFf(i)<=wTHEN910
900 t$=t$+LEFT$(sp$,f(i)-w)+f$(i)
910 NEXT
920 PRINT#4,t$:x=x+.5:IFINT(x)<>xTHENt$="{space*7}{cm k}":GOTO720
930 IFz=spTHEN1030
940 r=r+1:IFr=7THENr=0
950 ds=ds+1:IFms=4ORms=6ORms=9ORms=11THENl=30:GOTO990
960 IFms=2ANDys/4=INT(ys/4)THENl=29:GOTO990
970 IFms=2THENl=28:GOTO990
980 l=31
990 IFds>lTHENds=ds-l:ms=ms+1:GOTO1010
1000 t$=LEFT$(day$(r),3)+" "+MID$(dd$,2*ds-1,2)+" {cm k}":z=z+1:GOTO720
1010 IFms=13THENms=1:z=z+1:GOTO700
1020 z=z+1:GOTO700
1030 GOSUB1300:GOSUB1320
1040 FORss=1TO3:PRINT#4,:NEXT
1050 GOTO250
1060 ct=INT(co/2)
1070 IFt2$=""THENct=co
1080 t1=INT((ct-LEN(t$))/2)
1090 IFt1<1THENPRINT#4,t$:GOTO1120
1100 t2$=t2$+LEFT$(as$,t1)+t$
1110 PRINT#4,t2$:PRINT#4
1120 RETURN
1130 PRINT#4,"the purpose of biorhythm is to predict"
1140 PRINT#4,"a physical, emotional and intellectual"
1145 PRINT#4,"pattern that indicates your up and"
1150 PRINT#4,"down days for any period of time."
1155 PRINT#4,"{down}{space*3}biorhythm can show which days were"
1160 PRINT#4,"good or bad for you beginning with"
1170 PRINT#4,"your birth.{space*2}it can also show you which"
1175 PRINT#4,"future days will be good or bad for"
1180 PRINT#4,"you."
1182 PRINT#4,"{down}{space*3}these predictions are based on"
1190 PRINT#4,"scientific studies to determine why"
1195 PRINT#4,"accidents occur.{space*2}it was learned"
1200 PRINT#4,"through these studies that a physical"
1210 PRINT#4,"cycle occurs every 23 days, an"
1215 PRINT#4,"emotional cycle occurs every 28 days,"
1220 PRINT#4,"and an intellectual cycle occurs every"
1230 PRINT#4,"33 days."
1232 PRINT#4,"{down}{space*3}the critical days occur during the"
1235 PRINT#4,"transition from positive to negative"
1240 PRINT#4,"states.{space*2}during the critical days you"
1250 PRINT#4,"are more prone to errors, accident and"
1255 PRINT#4,"physical setbacks."
1260 PRINT#4,"{down}{space*3}this biorhythm plot flags the"
1270 PRINT#4,"critical days."
1280 PRINT#4:PRINT#4
1290 RETURN
1300 FORi=1TOco:PRINT#4,"-";:NEXT:PRINT#4
1310 RETURN
1320 FORi=1TOco:PRINT#4,"-";:NEXT:PRINT#4
1330 RETURN
1340 DATA0,31,59,90,120,151,181,212,243,273,304,334
1350 DATAmonday,tuesday,wednesday,thursday,friday,saturday,sunday
1360 DATAjanuary,february,march,april,may,june,july,august
1370 DATAseptember,october,november,december
1380 DATA" 1 2 3 4 5 6 7 8 910{1*3}2131415161718192021{2*3}32425262728293031"
stop tok64
(bastext 1.0)