start tok128 d64-RKqhjA
0 REM dsave"@prg l[s.128.80"
10 REM programl[s.128/80 v1.01--- freeware --- (c) 1990-1994 softwolves software
11 REM 1993: 12-09;18
12 REM 1994: 05-15;05-30
13 REM
14 REM
15 REM
16 REM
17 REM
18 REM
19 REM f]r kopieras och anv[ndas fritt. f]r ej modifieras.
20 IFINT(.1+.9)=.THENPRINT"c128-program":END
24 IFRWINDOW(2)=40THENPRINT"80-kolumnersprogram":END
28 FAST
32 PRINT"arbetar i ca.4 sekunder"
36 DIMb$(255),q$(255),ce$(10),fe$(38),r$(257)
40 FORi=1TO254:b$(i)=CHR$(i):q$(i)=CHR$(i):NEXT
44 b$(255)="pi":q$(255)=b$(255)
48 FORi=1TO26:q$(i+192)="<"+CHR$(i+64)+">":NEXT
52 FORi=128TO254:READb$(i):NEXT
56 FORi=2TO10:READce$(i):NEXT
60 FORi=2TO38:READfe$(i):NEXT
64 READz,q$:DO:q$(z)="<"+q$+">":READz,q$:LOOPWHILEz>.
68 REM *basic 2.0*
72 DATAend,for,next,data,input#,input,dim,read,let,goto,run,if,restore,gosub,return,rem,stop,on,wait,load,save,verify,def,poke,print#,print,cont
76 DATAlist,clr,cmd,sys,open,close,get,new,tab(,to,fn,spc(,then,not,step,"+","-","*","/","^",and,or,">","=","<",sgn,int,abs,usr,fre,pos,sqr,rnd
80 DATAlog,exp,cos,sin,tan,atn,peek,len,str$,val,asc,chr$,left$,right$,mid$,go
84 REM *basic 7.0*
88 DATArgr,rclr,,joy,rdot,dec,hex$,err$,instr,else,resume,trap,tron,troff,sound,vol,auto,pudef,graphic,paint,char,box,circle,gshape,sshape,draw
92 DATAlocate,color,scnclr,scale,help,do,loop,exit,directory,dsave,dload,header,scratch,collect,copy,rename,backup,delete,renumber,key,monitor
96 DATAusing,until,while,
100 REM *$ce-kommandon*
104 DATApot,bump,pen,rsppos,rsprite,rspcolor,xor,rwindow,pointer
108 REM *$fe-kommandon*
112 DATAbank,filter,play,tempo,movspr,sprite,sprcolor,rreg,envelope,sleep,catalog,dopen,append,dclose,bsave,bload,record,concat,dverify,dclear
116 DATAsprsav,collision,begin,bend,window,boot,width,sprdef,quit,stash,,fetch,,swap,off,fast,slow
120 REM *specialtecken*
124 DATA1,cta,2,ctb,3,ctc,4,ctd,5,vit,6,ctf,7,ctg,8,cth,9,cti,10,ctj,11,ctk,12,ctl,14,ctn,15,cto,16,ctp,17,ner,18,rvs p],19,home,20,delete,21,ctu,22,ctv
128 DATA23,ctw,24,ctx,25,cty,26,ctz,27,esc,28,r{pound}d,29,h{pound}ger,30,gr{pound}n,31,bl],60,mindre [n,62,st{pound}rre [n,64,at,94,pil upp,95,pil v[nster,126,pi
132 DATA129,orange,130,understrykning av,133,f1,134,f3,135,f5,136,f7,137,f2,138,f4,139,f6,140,f8,141,sh return,13,return,142,uppercase,143,blinkning av
136 DATA144,svart,145,upp,146,rvs av,147,cls,148,ins[tt,149,brun,150,sk[r,151,m{pound}rkgr],152,mellangr],153,ljusgr{pound}n,154,ljusbl],155,ljusgr],156,lila
140 DATA157,v[nster,158,gul,159,cyan,160,sh space,161,cmk,162,cmi,163,cmt,164,"cm@,cm]",165,cmg,166,"cm+/cm]",167,cmm,168,"cm pund/cm ["
144 DATA169,"sh pund/cm{pound}",170,cmn,171,cmq,172,cmd,173,cmz,174,cms,175,cmp,176,cma,177,cme,178,cmr,179,cnw,180,cmh,181,cmj,182,cml,183,cmy,184,cmu
148 DATA185,cmo,186,"sh@/{?*3}",187,cmf,188,cmc,189,cmx,190,cmv,191,cmb,192,"sh*/sh@",219,"sh+/sh[",220,"cm-/sh{pound}",221,"sh-/sh]",222,pi,223,"cm*/cm-"
152 DATA,
156 COLOR6,9
160 PRINT"{home*2}{142}{clear}{black}{reverse on} programl[s/128 v1.01(c)1994-05-30 softwolves software/peter karlsson{space*2}{ct o}freeware{143} "
164 WINDOW0,1,79,24
168 zz=PEEK(186)
172 PRINT"{clear}{blue}{down*2}{right*2}<== 1 ==>{space*2}{ct n}V[lj program att l[sa in : {142}";f$
176 PRINT"{blue}{down*2}{right*2}<== 2 ==>{space*2}{ct n}Visa diskettkatalog f{pound}r enhet{142}";zz
180 PRINT"{blue}{down*2}{right*2}<== 3 ==>{space*2}{ct n}Byt diskettenhet{142}"
184 PRINT"{blue}{down*2}{right*2}<== 4 ==>{space*2}{ct n}L[s in programmet{142}"
188 DO:GETKEYa$:LOOPUNTILa$>"0"ANDa$<"5":ONVAL(a$)GOSUB192,196,200,208:GOTO172
192 INPUT"{down*2}var god ange ett filnamn ";f$:RETURN
196 DIRECTORYu(zz):GETKEYa$:RETURN
200 INPUT"ange ny diskettenhet ";zz:IFzz<8ORzz>15THENPRINT"felaktig enhet, m]ste vara 8-15":GOTO200:ELSEIFzz-INT(zz)<>.THENPRINT"heltal tack":GOTO200
204 RETURN
208 IFf$=""THENPRINT"{down*2}{ct n}Du m]ste ange ett filnamn!":GETKEYa$:GOTO172
212 PRINT "{clear}{blue}{down*2}{right*2}<== 1 ==>{space*2}{ct n}Utmatning till sk[rm"
216 PRINT "{blue}{down*2}{right*2}<== 2 ==>{space*2}{ct n}Utmatning till skrivare #4, radslut=CR"
220 PRINT "{blue}{down*2}{right*2}<== 3 ==>{space*2}{ct n}Utmatning till skrivare #4, radslut=CRLF"
224 PRINT "{blue}{down*2}{right*2}<== 4 ==>{space*2}{ct n}Utmatning till diskfil p] enhet"zz
228 DO:GETKEYu$:LOOPUNTILu$>"0"ANDu$<"5":ONVAL(u$)GOTO232,236,240,244
232 OPEN4,3:cr$=CHR$(13):GOTO252
236 OPEN4,4,0:cr$=CHR$(13):GOTO252
240 OPEN4,4,0:cr$=CHR$(13)+CHR$(10):GOTO252
244 INPUT"{ct n}Ange filnamn {142}";ff$:cr$=CHR$(13)
248 DOPEN#4,(ff$+",s"),u(zz),w
252 OPEN2,zz,2,f$+",p,r"
256 PRINT"{ct n}Arbetar{.*3}{142}"
260 GET#2,a$,a$:PRINT"{clear}{down}";
264 PRINT#4,"program: "f$cr$;:DO
268 GET#2,a$,b$:IFASC(a$)+ASC(b$)=0THENEXIT
272 POKE241,0:GET#2,a$,b$:PRINT#4,USING"{#*5} ";ASC(a$)+ASC(b$)*256;:POKE241,2
276 rm=.:REM v[rde f{pound}r radl[ngden
280 DO:rm=rm+1:GET#2,r$(rm):LOOPUNTILr$(rm)=""
284 ad=1:r$=""
288 REM * vanlig programtext
292 x=ASC(r$(ad)):ad=ad+1:s$=b$(x):IFad>rmGOTO356:ELSEIFs$=""GOTO300:ELSEr$=r$+s$:IFx=34GOTO316:ELSEGOTO292
296 REM * specialkod (ce,fe)
300 y=ASC(r$(ad)):ad=ad+1:IFad>rmGOTO356
304 IFx=206THENs$=ce$(y):ELSEs$=fe$(y)
308 r$=r$+s$:GOTO292
312 REM * quote mode
316 x=ASC(r$(ad)):y=ASC(r$(ad+1)):z=ASC(r$(ad+2)):ad=ad+1:s$=q$(x):IFad>rmGOTO356
320 IF(x=yAND(LEN(s$)>1ORx=32))OR(x=yANDy=z)THEN336
324 r$=r$+s$
328 IFx=34GOTO292:ELSEGOTO316
332 REM * flera lika i quote mode
336 IFx=32THENs$="<space>":ELSEIFx>47ANDx<58THEN324
340 c=.:DO:c=c+1:LOOPWHILEASC(r$(ad+c))=x
344 r$=r$+"<"+MID$(STR$(c+1),2)+" ":IFLEN(s$)=1THENr$=r$+s$+">":ELSEIFLEN(s$)=3THENr$=r$+"sh"+MID$(s$,2):ELSEr$=r$+MID$(s$,2)
348 ad=ad+c:GOTO316
352 REM * radslut
356 PRINT#4,r$cr$;:LOOP:DCLOSEONu(zz)
360 PRINT#4,"{space*2}sh=shift, cm=commodore, ct=control."cr$;
364 PRINT#4,"{space*2}dubbla h[nvisningar: v[nstra engelskt och h{pound}gra svenskt tangentbord."cr$;
368 PRINT#4,"{space*2}ensam bokstav: shift+bokstaven."cr$;
372 PRINT#4,"{space*2}f[rger [r 40-kolumners/c64-f[rger."cr$;
376 PRINT#4,"listning skapad med programl[s/128 1.01(c)1990-1994 peter karlsson"cr$cr$;:CLOSE4
500 REM  peter karlsson
504 REM  v[rnsta, ullers[ter
508 REM  s-710 40  fr{pound}vi
512 REM  sverige
stop tok128
(bastext 1.0)