start tok64 d64-wwmv1s
10 POKE53280,5:POKE53281,11:PRINT"{clear}{ct h}{ct n}{white}{down}","{left*2}Memory Selection Program
11 PRINT"{down} Written by Jason Finch{space*4}(C) CDU{sh space}1990
12 PRINT"{down*3}{light gray} Use '$' prefix for hexadecimal numbers
13 PRINT"{down*2}{yellow} Enter start location of",," screen memory",,,"{down} :{cyan}1024{left*4}";
14 OPEN1,0:INPUT#1,a$:CLOSE1:PRINT:sm=VAL(a$):IFLEFT$(a$,1)<>"$"THEN17
15 a$=MID$(a$,2):IFa$=""THEN10
16 FORh=1TOLEN(a$):v=ASC(MID$(a$,h,1))-48:v=v+128*(v>144):sm=sm*16+v+(v>9)*7:NEXT
17 IFsm>64512OR(sm<3072ANDsm<>1024)THEN10
18 IFsm/1024=INT(sm/1024)THEN20
19 PRINT"{down*2} {pink}** Value must be divisible by 1024 **":FORt=1TO1500:NEXT:GOTO10
20 PRINT"{down*3}{yellow} Enter start location of character"," information (or bitmap data)
21 PRINT"{down} :{cyan}";:a$="{space*5}":IFsm<16384THENa$="4096 "
22 IFsm<49152ANDsm>32767THENa$="36864"
23 PRINTa$"{left*5}";:OPEN1,0:INPUT#1,a$:CLOSE1:PRINT:cm=VAL(a$):IFLEFT$(a$,1)<>"$"THEN26
24 a$=MID$(a$,2):IFa$=""THEN10
25 FORh=1TOLEN(a$):v=ASC(MID$(a$,h,1))-48:v=v+128*(v>144):cm=cm*16+v+(v>9)*7:NEXT
26 bc=INT(cm/16384):bs=INT(sm/16384):IFbc=bsTHEN28
27 PRINT"{down*2} {pink}** Must be in same bank **":FORt=1TO1500:NEXT:GOTO10
28 IFcm/2048=INT(cm/2048)THEN30
29 PRINT"{down*2} {pink}** Value must be divisible by 2048 **":FORt=1TO1500:NEXT:GOTO10
30 PRINT"{clear}{white}{down}","{left*2}Memory Selection Program
31 PRINT"{down} Written by Jason Finch{space*4}(C) CDU{sh space}1990
32 b$=MID$("Zero One{space*2}Two{space*2}Three",bs*5+1,5):r$="(UDGs)
33 IFcm=4096ORcm=6144ORcm=36864ORcm=38912THENr$="(ROM image)
34 vr=(sm-bs*16384)/64+(cm-bc*16384)/1024:pg=sm/256:pt=1016+sm
35 dd$="PEEK(56576)AND252":IFbs<3THENdd$="("+dd$+")OR"+MID$(STR$(3-bs),2)
36 PRINT"{down*3}{yellow} Selected Bank:{space*3}{cyan}"b$,," {down}{yellow}Screen Memory:{space*2}{cyan}"sm
37 PRINT"{down} {yellow}Character Info: {cyan}"cm;r$:PRINT"{down*2}{light gray} POKE 56578, PEEK(56578)OR3"
38 PRINT"{down} POKE 56576, "dd$:PRINT"{down} POKE 53272,"vr,,,"{down} POKE 648,"pg
39 PRINT"{down*2}{yellow} Sprite Pointers:{cyan}"pt"{left}-"MID$(STR$(pt+7),2):POKE56295,10:c=62:a=0
40 POKE2023,c:a=a+1:IFa=6THENa=0:c=252-c
41 GETa$:IFa$=""THEN40
42 RUN
stop tok64
(bastext 1.0)