start tok128 d64-n7RURp
10 GRAPHICCLR
20 IFPEEK(215)<>128THEN70
30 GRAPHIC5:WINDOW0,0,79,24:FAST
40 PRINT"{clear}{white}{reverse on}{ct n}{space*10}File Reader/Printer/Converter{space*11}by John Crookshank{space*12}"
50 GOTO100
60 STOP
70 GRAPHIC0:WINDOW0,0,39,24:SLOW
80 PRINT"{clear}{reverse on}{white}{ct n}{space*6}File Reader/Printer/Converter{space*5}"
90 PRINT"{space*13}by John Crookshank{space*9}{light green}"
100 PRINT"{yellow}{ct i}{down*2}{space*7}Select One:{light green}"
110 PRINT"{down*2}{ct i}1: Read file to screen"
120 PRINT"{ct i}2: Send file to printer"
130 PRINT"{ct i}3: Expand file to printer"
140 PRINT"{ct i}4: Expand file to disk"
150 PRINT"{ct i}5: Read program DOCs"
160 w=PEEK(215):w$="80 columns":IFw=128THENw$="40 columns"
170 PRINT"{ct i}6: Change to "w$
180 PRINT"{ct i}7: Read disk directory"
190 PRINT"{ct i}8: Exit program"
200 IFPEEK(2816)<>32ORPEEK(2817)<>163THENPRINT"{down*2}{ct i}{space*2}Loading Reader.ML{.*3}":BLOAD"reader.ml",b0,p2816:PRINT"{up}{ct i}{space*26}"
210 POKE3249,0:POKE3250,4:POKE3031,21:POKE3251,0:POKE2825,24
220 CLOSE2:CLOSE15:CLOSE4:x=ds
230 GETKEYi$:IFi$<"1"ORi$>"8"THEN230
240 i=VAL(i$):ONiGOTO300,400,410,500,290,270,560,260
250 GOTO20
260 DCLOSE:END
270 IFw=128THENSLOW:GRAPHIC0:PRINT"{clear}":GRAPHIC5:PRINT"{clear}{down*10}Switch monitor to 40 column mode!":GOTO70
280 GRAPHIC5:PRINT"{clear}":GRAPHIC0:PRINT"{clear}{down*10}Switch monitor to 80 column mode!":SLEEP2:GOTO30
290 f$="reader.doc":GOTO310
300 f$="":INPUT"{down*2}Filename";f$:IFf$=""THEN20
310 DCLOSE:DOPEN#2,(f$):GOSUB590
320 IFPEEK(215)<>128THEN350
330 PRINT"{home}{down*24}{white}{space*7}F7 - Continue reading file.{space*10}F1 - Abort reading file{home}{light green}"
340 WINDOW0,0,79,23:POKE2825,23
350 PRINT"{clear}";:BANK15:SYS2816:BANK0:DCLOSE
360 IFPEEK(3251)=88THEN20:ELSEPRINT"{white}End of file. Press any key{.*3}"
370 GETi$:IFi$<>""THEN370
380 GETi$:IFi$=""THEN380
390 GOTO20
400 p=21:GOTO420
410 p=2:GOTO420
420 f$="":INPUT"{down*2}Filename";f$:IFf$=""THEN20
430 DCLOSE:DOPEN#2,(f$):GOSUB590
440 PRINT"{down}Input secondary address for printer{space*3}7{left*3}";:INPUTsa
450 PRINT"{down}Turn on printer and press RETURN":POKE208,0
460 PRINT"(Press any other key to exit)"
470 GETi$:IFi$=""THEN470
480 IFi$<>CHR$(13)THEN20
490 OPEN4,4,sa:BANK0:POKE3031,p:BANK15:SYS2977:BANK0:PRINT#4:CLOSE4:GOTO20
500 of$="":INPUT"{down*2}Existing file name";of$:IFof$=""THEN20
510 nf$="":INPUT"{down*2}Converted file name";nf$:IFnf$=""THEN20
520 POKE3250,3:DCLOSE:DOPEN#2,(of$):GOSUB590
530 DOPEN#3,(nf$),w:GOSUB590
540 PRINT"{down}{white}Writing new file "CHR$(34)nf$CHR$(34)"{.*3}{light green}"
550 POKE3031,2:BANK15:SYS2977:BANK0:CLOSE2:CLOSE3:CLOSE15:GOTO20
560 PRINT"{clear}";:DCLEAR:GOSUB590:DIRECTORY:PRINT"{white}Press any key{.*3}{light blue}"
570 GETi$:IFi$<>""THEN570
580 GETi$:IFi$=""THEN580:ELSEGOTO20
590 IFds=0THENRETURN
600 PRINT"{down*2}{white}Disk error!":PRINTds$;CHR$(7):SLEEP4:GOTO20
stop tok128
(bastext 1.0)