start tok64 d64-36v4Ox
1 PRINTCHR$(5):POKE53280,9:POKE53281,9
20 PRINT"{clear}{reverse on}{yellow}{space*3}klockan{space*4}{reverse on}{pink} register {reverse on}{yellow}{space*16}{reverse off}{white}";
30 cr$=CHR$(13)
41 PRINT"{reverse on}{yellow}{space*14}{reverse on}{pink} 64 - 1.0 {reverse on}{yellow}{space*16}{reverse off}{white}";
42 PRINT"{reverse on}{yellow}{space*14}{reverse on}{pink} (p) 1985 {reverse on}{yellow}{space*16}{reverse off}{white}";
44 PRINT"{down}{-*40}";
45 PRINT"{down}(1) skapande av fil";
50 PRINT" (2) inskrivning"
60 PRINT"{down}(3) klockan";
70 PRINT"{space*9}(4) post s{pound}kning"
80 PRINT"{down}(5) register";
90 PRINT"{space*8}(6) [ndringar"
91 PRINT"{down}(7) disk inneh]ll";
92 PRINT"{space*3}(8) radera fil"
93 PRINT"{down}(9) formattera disk";
94 PRINT" (0) {reverse on}{yellow}hj[lp{reverse off}{white}{space*8}"
95 PRINT"{down}{space*17}";
96 PRINT"{space*21}"
100 PRINT"{down*5}{-*40}";
110 PRINT"{space*12}(f8) = avsluta"
115 DIMn$(601),e$(601),g$(601),p$(601),pnr$(601),t$(601),q$(601),z$(601)
220 GETa$
230 IFa$="1"THEN1000
240 IFa$="2"THEN2000
250 IFa$="4"THEN3000
260 IFa$="5"THEN4000
270 IFa$="6"THEN5000
271 IFa$="7"THEN7000
272 IFa$="8"THEN8000
273 IFa$="9"THEN8100
275 IFa$="{f8}"THEN6000
276 IFa$="3"THEN6100
277 IFa$="0"THEN40000
311 PRINT"{home}{down*2}{reverse on}{yellow}{right*3}";ti$
320 GOTO220
1000 GOSUB10000:REM**skapande av fil**
1010 PRINT"{home}{down*3}{reverse on}{white}skapande{reverse off}{white}":PRINT"{down}vad ska filen kallas":INPUTb$:i=1
1011 GOSUB20000
1030 b$=b$+",seq,write"
1040 OPEN1,8,15,"i":OPEN2,8,2,b$
1055 CLOSE2:CLOSE1
1070 OPEN2,8,2,"@0:"+b$+",s,w"
1071 j=j+1
1072 n$(j)="0":p$(j)="0":pnr$(j)="0":t$(j)="0":e$(j)="0":g$(j)="0":q$(j)="0"
1073 z$(j)="0":FORk=1TOj
1074 PRINT#2,n$(k)cr$e$(k)cr$g$(k)cr$p$(k)cr$pnr$(k)cr$t$(k)cr$q$(k)cr$z$(k)
1075 NEXTk
1076 CLOSE2:CLOSE1:RUN
2000 GOSUB10000:REM**inskrift av nya poster**
2010 PRINT"{home}{down*3}{reverse on}{white}inskrivning{reverse off}{white}":PRINT"{down}i vilken fil{space*5}":INPUTb$:i=1
2011 GOSUB20000
2020 OPEN1,8,15,"i"
2025 OPEN2,8,2,b$+",s,r"
2031 INPUT#2,n$(i),e$(i),g$(i),p$(i),pnr$(i),t$(i),q$(i),z$(i)
2032 IFn$(i)="0"THEN2034
2033 i=i+1:GOTO2031
2034 CLOSE2
2035 OPEN2,8,2,b$+",s,r"
2036 FORj=1TOi
2037 INPUT#2,n$(j),e$(j),g$(j),p$(j),pnr$(j),t$(j),q$(j),z$(j)
2038 NEXTj
2039 CLOSE2:j=j-1
2040 OPEN2,8,2,"@0:"+b$+",s,w"
2041 GOSUB10000
2042 PRINT"{home}{down*5}{space*15}"
2059 PRINT"{home}{down*3}{reverse on}{white}inskrivning{right*3}{reverse off}{yellow}"j" - ";b$"{white}"
2060 INPUT"{down*2}{white}";n$(j)
2070 INPUT"{white}";e$(j)
2080 INPUT"{white}";g$(j)
2090 INPUT"{white}";p$(j)
2100 INPUT"{white}";pnr$(j)
2110 INPUT"{white}";t$(j)
2111 INPUT"{white}";q$(j)
2112 INPUT"{white}";z$(j)
2130 j=j+1
2140 PRINT"{down}{right*12}flera data (j/n)"
2141 GETx$:IFx$=""THEN2141
2142 IFx$="j"THEN2041:PRINTj
2143 GOSUB20000
2161 n$(j)="0"
2162 p$(j)="0":pnr$(j)="0":t$(j)="0"
2163 e$(j)="0"
2164 g$(j)="0":q$(j)="0":z$(j)="0"
2165 FORk=1TOj
2170 PRINT#2,n$(k)cr$e$(k)cr$g$(k)cr$p$(k)cr$pnr$(k)cr$t$(k)cr$q$(k)cr$z$(k)
2175 NEXTk
2180 CLOSE2:CLOSE1:RUN
3000 GOSUB10000:REM**enstaka postutskrift**
3001 PRINT"{home}{down*3}{reverse on}{white}post s{pound}kning{reverse off}{white}"
3010 PRINT"{down}fr]n vilken fil":INPUTb$:GOSUB20000
3030 OPEN1,8,15,"i":OPEN2,8,2,b$+",s,r"
3190 PRINT"{home}{down*12}vad s{pound}ker du efter":sum=0
3191 PRINT"{space*38}"
3192 INPUT"{up*2}";s$
3193 PRINT"{home}{down*23}{space*37}"
3194 sum=sum+1
3195 PRINT"{home}{down*23}{reverse on}{yellow}"s$"{reverse off}{white}"
3196 PRINT"{home}{down*2}{right*25}{reverse on}{yellow}post nr.";sum"{reverse off}{white}"
3500 INPUT#2,a$(1),a$(2),a$(3),a$(4),a$(5),a$(6),a$(7),a$(8)
3501 IFa$(1)="0"THEN3630
3502 PRINT"{home}{right*25}{reverse on}{yellow}({arrow left}) meny"
3510 f=0
3520 FORi=1TO8:FORz=1TOLEN(a$(i))
3521 IFs$<>LEFT$(a$(i),z)THEN3600
3523 GOSUB10000
3524 PRINT"{home}{down*5}{space*16}"
3525 PRINT"{home}{down*3}{reverse on}{white}post s{pound}kning{reverse off}{white}":PRINT"{down*2}{yellow}"a$(1):PRINT"{yellow}"a$(2)
3540 PRINT"{yellow}"a$(3):PRINT"{yellow}"a$(4)
3560 PRINT"{yellow}"a$(5):PRINT"{yellow}"a$(6)
3561 PRINT"{yellow}"a$(7):PRINT"{yellow}"a$(8)"{white}"
3575 PRINT"{home}{down*23}{right*9}{green}tryck en tangent{white}"
3577 PRINT"{home}{right*25}{reverse on}{yellow}({arrow left}) meny"
3595 GETv$:IFv$=""THEN3595
3596 IFv$=CHR$(95)THEN3630
3600 GETx$
3610 IFx$<>CHR$(95)THENNEXTz:NEXTi:GOTO3193
3611 IFx$=CHR$(95)THEN3630
3612 GOTO3600
3630 CLOSE2:CLOSE1
3640 RUN
4000 GOSUB10000:REM**registerutskrift**
4001 PRINT"{home}{down*3}{reverse on}{white}register{reverse off}{white}"
4010 PRINT"{down}fr]n vilken fil":INPUTb$:GOSUB20000
4020 OPEN1,8,15,"i":OPEN2,8,2,b$+",s,r"
4052 i=1
4060 INPUT#2,n$(i),e$(i),g$(i),p$(i),pnr$(i),t$(i),q$(i),z$(i)
4070 IFn$(i)="0"THEN4200
4080 i=i+1:GOTO4060
4200 CLOSE2:CLOSE1:i=i-1
4210 FORj=1TOi
4211 GOSUB10000
4212 PRINT"{home}{down*5}{space*16}"
4213 PRINT"{home}{down*3}{reverse on}{white}register{right*3}{reverse off}{yellow}"j"- ";b$;" (antal";i;")"
4220 PRINT"{down*2}{yellow}"n$(j):PRINT"{yellow}"e$(j)
4230 PRINT"{yellow}"g$(j):PRINT"{yellow}"p$(j)
4240 PRINT"{yellow}"pnr$(j):PRINT"{yellow}"t$(j)
4241 PRINT"{yellow}"q$(j):PRINT"{yellow}"z$(j)"{white}"
4245 PRINT"{down}{green}{space*11}tryck en tangent !"
4246 PRINT"{home}{right*25}{reverse on}{yellow}(f1) meny"
4247 PRINT"{home}{down}{right*25}{reverse on}{yellow}(f3) backa"
4248 PRINT"{home}{down*2}{right*25}{reverse on}{yellow}(f5) v[lj post"
4260 GETs$:IFs$=""THEN4260
4261 IFs$="{f1}"THENRUN
4262 IFs$="{f3}"THENj=j-2:IFj<1THENj=0
4263 IFs$="{f5}"THENGOSUB30400
4270 NEXTj
4283 RUN
5000 GOSUB10000:REM**uppdatering**
5010 PRINT"{home}{down*3}{reverse on}{white}[ndringar{reverse off}{white}":PRINT"{down}i vilken fil{space*3}":INPUTb$:i=1:GOSUB20000
5020 OPEN1,8,15,"i":OPEN2,8,2,b$+",s,r"
5030 INPUT#2,n$(i),e$(i),g$(i),p$(i),pnr$(i),t$(i),q$(i),z$(i)
5040 IFn$(i)="0"THEN5060
5050 i=i+1:GOTO5030
5060 PRINT"{home}{down*12}vilken post ska [ndras(nr)"
5061 PRINT"{space*38}"
5062 INPUT"{up*2}";a
5070 GOSUB10000:PRINT"{home}{down*3}{reverse on}{white}[ndringar{reverse off}{white}":PRINT"{home}{down*5}{space*16}"
5071 PRINT"{home}{down*5}1.{yellow}";n$(a):PRINT"{down}{white}2.{yellow}";e$(a)
5080 PRINT"{down}{white}3.{yellow}";g$(a):PRINT"{down}{white}4.{yellow}";p$(a)
5100 PRINT"{down}{white}5.{yellow}";pnr$(a):PRINT"{down}{white}6.{yellow}";t$(a)
5101 PRINT"{down}{white}7.{yellow}";q$(a):PRINT"{down}{white}8.{yellow}";z$(a)"{white}"
5120 PRINT"{down*3}{green}vilket data ska [ndras (nr.){yellow}"
5121 PRINT"{home}{right*25}{reverse on}{yellow}(f1) meny{yellow}"
5190 GETs$:IFs$=""THEN5190
5200 IFs$="1"THEN5300
5210 IFs$="2"THEN5400
5220 IFs$="3"THEN5500
5230 IFs$="4"THEN5600
5240 IFs$="5"THEN5700
5241 IFs$="6"THEN5710
5242 IFs$="7"THEN5720
5243 IFs$="{f1}"THENCLOSE2:CLOSE1:RUN
5249 GOSUB10000
5250 PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";z$(a);"){white}"
5251 PRINT"{down*2}{white}8.{yellow}";:INPUTz$(a):GOSUB20000
5260 GOTO5800
5300 GOSUB10000:PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";n$(a);"){white}"
5301 PRINT"{down*2}{white}1.{yellow}";:INPUTn$(a):GOSUB20000
5310 GOTO5800
5400 GOSUB10000:PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";e$(a);"){white}"
5401 PRINT"{down*2}{white}2.{yellow}";:INPUTe$(a):GOSUB20000
5410 GOTO5800
5500 GOSUB10000:PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";g$(a);"){white}"
5501 PRINT"{down*2}{white}3.{yellow}";:INPUTg$(a):GOSUB20000
5510 GOTO5800
5600 GOSUB10000:PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";p$(a);"){white}"
5601 PRINT"{down*2}{white}4.{yellow}";:INPUTp$(a):GOSUB20000
5610 GOTO5800
5700 GOSUB10000:PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";pnr$(a);"){white}"
5701 PRINT"{down*2}{white}5.{yellow}";:INPUTpnr$(a):GOSUB20000
5702 GOTO5800
5710 GOSUB10000:PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";t$(a);"){white}"
5711 PRINT"{down*2}{white}6.{yellow}";:INPUTt$(a):GOSUB20000
5712 GOTO5800
5720 GOSUB10000:PRINT"{home}{down*5}{white}du ska [ndra {yellow}(";q$(a);"){white}"
5721 PRINT"{down*2}{white}7.{yellow}";:INPUTq$(a):GOSUB20000
5722 GOTO5800
5800 CLOSE2
5810 OPEN2,8,2,"@0:"+b$+",s,w"
5820 FORj=1TOi
5830 PRINT#2,n$(j)cr$e$(j)cr$g$(j)cr$p$(j)cr$pnr$(j)cr$t$(j)cr$q$(j)cr$z$(j)
5840 NEXTj
5850 CLOSE2:CLOSE1
5860 RUN
6000 PRINT"{clear}{white}":END
6100 GOSUB10000
6101 PRINT"{home}{down*5}hur mycket [r klockan"
6102 INPUTti$
6103 RUN
7000 GOSUB10000:PRINT"{home}{down*3}{reverse on}{white}fil lista{reverse off}{yellow}":PRINT"{home}{down*5}{space*16}"
7001 OPEN8,8,0,"$0":GET#8,a$,b$
7062 GET#8,a$,b$,a$,b$:c=0
7065 IFa$<>""THENc=ASC(a$)
7067 IFb$<>""THENc=c+ASC(b$)*256
7070 PRINT"{home}{down*5}{right*11}"TAB(8)"{reverse on}"MID$(STR$(c),3);"{reverse on}";
7072 GET#8,b$:IFst<>0THEN7090
7074 IFb$<>CHR$(34)THEN7072
7076 GET#8,b$:IFb$<>CHR$(34)THENPRINTb$;:GOTO7076
7078 GET#8,b$:IFb$=CHR$(32)THEN7078
7080 c$=""
7082 c$=c$+b$:GET#8,b$:IFb$<>""THEN7082
7084 PRINT:PRINT"{up*2}":IFst=0THEN7072
7090 CLOSE8
7092 PRINT"{home}{down*23}{right*8}{green}tryck p] en tangent !"
7094 GETx$:IFx$=""THEN7094
7096 RUN
8000 GOSUB10000:OPEN15,8,15
8001 PRINT"{home}{down*3}{reverse on}{white}radera fil{reverse off}{white}"
8002 PRINT"{home}{down*5}vilken fil ska raderas":INPUTy$:GOSUB20000
8005 PRINT#15,"s0:"y$
8006 CLOSE15
8010 PRINT"{home}{down*23}{space*8}{green}tryck p] en tangent !{space*7}"
8011 GETx$:IFx$=""THEN8011
8012 RUN
8100 GOSUB10000:PRINT"{home}{down*3}{reverse on}{white}formatera disk{reverse off}{yellow}"
8101 PRINT"{home}{down*5}{space*5}t[nk p] att hela disken raderas !"
8102 PRINT"{down}{right*12}forts[tta (j/n)?"
8103 GETx$
8104 IFx$="j"THEN8107
8105 IFx$="n"THENRUN
8106 GOTO8103
8107 GOSUB10000:PRINT"{home}{down*12}{right*8}disken formateras !":OPEN15,8,15
8110 y$="register 64-1.0"
8111 id$="a0"
8112 PRINT#15,"n0:"y$","id$
8120 PRINT"{home}{down*23}{right*8}{green}{space*3}ett {pound}gonblick !{space*3}"
8130 FORt=1TO66350:NEXT
8151 RUN
10000 PRINT"{home}{down*3}{space*40}";
10002 PRINT"{down}{space*40}";
10004 PRINT"{space*40}";
10006 PRINT"{space*40}";
10008 PRINT"{space*40}";
10010 PRINT"{space*40}";
10012 PRINT"{space*40}";
10014 PRINT"{space*40}";
10016 PRINT"{space*40}";
10018 PRINT"{space*40}";
10020 PRINT"{space*40}";
10022 PRINT"{space*40}";
10024 PRINT"{space*40}";
10026 PRINT"{space*40}";
10028 PRINT"{space*40}";
10030 PRINT"{space*40}";
10032 PRINT"{space*40}";
10034 PRINT"{space*40}";
10036 PRINT"{down}{space*40}";
10040 RETURN
20000 PRINT"{home}{down*23}{space*11}{green}ett {pound}gonblick !{white}{space*12}"
20001 RETURN
30400 GOSUB10000
30401 j=0:PRINT"{home}{down*5}{white}fr]n vilken nummer vill du b{pound}rja"
30402 INPUTx
30403 j=j+x-1
30410 RETURN
40000 GOSUB10000:PRINT"{home}{down*3}{reverse on}{white}hj[lp ruta{reverse off}{white}"
40001 PRINT"{down}b{pound}rja med en tom disket och formattera{space*2}";
40002 PRINT"den. sedan tar du och skapar filer som{space*2}";
40003 PRINT"du ska anv[nda t ex adresser, lp, eller ";
40004 PRINT"n]got annat."
40005 PRINT"nu [r det bara och v[lja inskrivning (2)"
40006 PRINT"om det k{pound}r ihop sig d] [r det bara att{space*2}";
40007 PRINT"trycka p] run/stop och restore och 'run'";
40008 PRINT"enda s[ttet att f] program fel, [r n[r{space*2}";
40009 PRINT"man s{pound}ker en fil p] disken som inte{space*5}";
40010 PRINT"finns, s] se till att du har skapat{space*5}";
40011 PRINT"filen f{pound}rst. och se till att du stavar{space*2}";
40012 PRINT"r[tt n[r du f]r fr]gan 'vilken fil' !"
40013 PRINT"{space*13}lycka till"
40014 PRINT"{home}{down*23}{right*9}{green}tryck en tangent{white}"
40100 GETx$:IFx$=""THEN40100
40101 RUN
stop tok64
(bastext 1.0)