start tok64 d64-ROhcx9
10 REM"{delete*6}{space*9}weatherwar
20 REM"{delete*6}{space*6}written by bob carr
30 REM"{delete*6}{space*3}magic carpet software (c)82
40 REM"{delete*6}
50 GOSUB2600:RESTORE
60 PRINT"{clear}{yellow}"TAB(11)"{down*2}{cm d}{F*15}{cm f}":PRINTTAB(11)"{reverse on}{cm k}{reverse off} weatherwar ii {cm k}
70 PRINTTAB(11)"{reverse on}{cm k}{reverse off}{space*2}by bob carr{space*2}{cm k}":PRINTTAB(11)"{cm c}{D*6}I U{D*6}{cm v}
80 PRINT"{space*4}{cm d}{F*13}K J{F*13}{cm f}":PRINT"{space*4}{reverse on}{cm k}{reverse off} magic carpet soft";
90 PRINT"ware (c)82 {cm k}":PRINT"{space*4}{cm c}{D*29}{cm v}
100 POKE53272,21:POKE54296,15:lf=53281:POKElf,0:POKElf-1,0:IFr=0THENGOSUB2270
110 PRINT"{156}{down} a man's home is his castle, defend it!
120 INPUT"{cyan}{down*2}do you want instructions (y/n){space*2}{cm b}{left*3}";a$
130 PRINT"{up*3}";:IFLEFT$(a$,1)="y"THEN1670
140 IFLEFT$(a$,1)<>"n"THENr=1:GOTO60
150 GOSUB2220:j=1:GOSUB1630:z$=ap$:j=2:GOSUB1630:y$=ap$
160 a$="{home}{down*21}"
170 s$="{blue}{space*38}"
180 ss$="{light blue}{space*38}"
190 c$="{white}{cm l}{left}{down}N{left}{down}M{down}M{left}{down}NM{cm @}{left*3}{down}M{space*2}M{left*4}{down}{cm l}{left}{down}N{left*2}{down}N{left}{down}"
200 d$=" {left}{down} {left}{down} {down} {left}{down}{space*3}{left*3}{down}{space*4}{left*4}{down} {left}{down} {left*2}{down} {left}{down}"
210 e$=c$+"M{left}{down}N{left*2}{down}N{left}{down}{cm j}{left*2}{down}N{left*4}{down} {cm @}N {left*4}{down}N {down}{left*3}{cm l}"
220 f$=d$+" {left}{down} {left*2}{down} {left}{down} {left*2}{down} {left*3}{down}{space*2}{left*3}{down} {left*2}{down} "
230 g$=c$+"M{down}{cm j}{left}{down}{cm j}{left}{down}M{down}M{left}{down} M{cm @} {left*2}{down} M{down}{cm j}"
240 h$=d$+" {down} {left}{down} {left}{down} {down} {down}{space*2}{down} {down} "
250 i$=c$+"M{down}M{down}{cm j}{left*2}{down} {cm j}{left*3}{down} N {left*4}{down} N {left*3}{down} {cm j}{left*2}{down} {cm j}"
260 j$=d$+" {down} {down} {left}{down} {left*2}{down} {left*2}{down} {left}{down} {left}{down} "
270 PRINT"{white}{clear}{space*2}{cm z}";:FORv=1TO34:PRINT"{sh asterisk}";:NEXT:PRINT"{cm x}"
280 f=28:g=28:m=3:mm=0:h=1827
290 FORv=1TO20:PRINT"{sh space}"SPC(38)"{sh space}";:NEXT
300 PRINTTAB(4)"{up*5}{yellow}{reverse on}{cm c*2}{cm l}{reverse off}{cm f*5}"SPC(16)"{cm d*5}{reverse on}{cm j}{cm v*2}"
310 PRINT"{right*4}{reverse on}OP{C*5}{reverse off}{cm v}"SPC(16)"{cm c}{reverse on}{C*5}OP"
320 PRINT"{up}{right*4}{reverse on}{cm g}{cm m} {white}{sh +}{yellow} {white}{sh +}{yellow}{cm m}{cm v*2}"SPC(14)"{cm c*2}{cm g}{white}{sh +}{yellow} {white}{sh +}{yellow} {cm g}{cm m}"
330 PRINT"{right*4}{reverse on}{cm g}{cm m} {cm y} {cm y}{cm n}{cm y}P"SPC(14)"O{cm y}{cm h}{cm y} {cm y} {cm g}{cm m}"
340 PRINT"{up} {right*3}{reverse on}{cm h}{cm n}{space*4}{cm n} {cm n}"SPC(14)"{cm h} {cm h}{space*4}{cm h}{cm n}"
350 t$=z$:PRINT"{up}{reverse on}";SPC(4.5+(8-LEN(t$))/2);t$
360 t$=LEFT$(y$,8):PRINT"{up}{reverse on}";SPC(28+(8-LEN(t$))/2);t$
370 PRINTa$;:FORv=1TO40:PRINT"{blue}{reverse on}{cm i}";:NEXT:PRINT:POKE53269,255:GOSUB2220
380 GOSUB1140:IFf<1ANDb=0ORg<1ANDb=0THEN1420
390 m=m+1:IFm>3THENm=1:mm=mm+1:b=0:PRINT"{home}";TAB(15);"{white}{sh asterisk*11}
400 IFm=3ANDRND(1)>.1THEN390
410 PRINT"{home}{down}{reverse off}";:FORv=1TO3:PRINT"{sh space}"s$"{sh space}";:NEXT:PRINT
420 a=1068:aa=RND(1)*26:a=a+aa:b=1-b
430 POKEa,104:POKEa+54272,1:FORv=1TO4:a=a+1:POKEa,102:POKEa+54272,1:NEXT
431 FORv=1TO5:a=a+1:POKEa,104:POKEa+54272,1:NEXT
440 a=a+27:POKEa,104:POKEa+54272,1:FORv=1TO11:a=a+1:POKEa,102:POKEa+54272,1:NEXT
441 POKEa,104:POKEa+54272,1:a=a+33
450 POKEa,104:POKEa+54272,1:FORv=1TO6:a=a+1:POKEa,102:POKEa+54272,1:NEXT
451 POKEa,104:POKEa+54272,1:nn=0
460 PRINTa$"{reverse on}"ss$"{space*2}":PRINT"{up*2}{right*4}";
470 IFm=3THENPRINT"{right}target"SPC(18)"target":GOTO500
480 IFb=0THENPRINT"{right}target"SPC(17)"{reverse on}attacker":GOTO1820
490 PRINT"{reverse on}attacker{reverse off}"SPC(17)"target":GOTO1800
500 ee=INT(RND(1)*100)
510 IFee>50THENee=INT(-ee/2):PRINTa$SPC(14)"{reverse on} wind <{sh asterisk}C"ABS(ee)"{left} {down}":GOTO530
520 PRINTa$SPC(14)"{reverse on} wind {sh asterisk*2}>"ee"{left} {down}{white}"
530 PRINT"{home}"SPC(13)"{white}{sh asterisk*2} {yellow}round"mm"{white}{left} {sh asterisk*3}":GOSUB2220
540 IFct=2THEN2000
550 IFct=1THEN1840
560 IFm<3THEN610
570 FORz=1TO2:PRINTa$"{down*2}"s$:GOSUB2390:GOSUB1370
580 PRINTa$TAB(13)"{yellow}{down*2}{reverse on} act of nature {reverse off}":GOSUB2390:GOSUB1370:NEXT
590 GOSUB1360:PRINT"{up}"s$
600 o=1:b$=MID$("hlrt",INT(RND(1)*4)+1,o):n$=b$:GOTO690
610 IFm<>1THENGOSUB1370:GOTO630
620 PRINT"{home}{white}";TAB(15)" {yellow}round"mm"{white}{left} "
630 t$=z$:IFb=0THENt$=y$
640 PRINTa$"{down}"s$"{space*2}{up}{reverse on}{white}"t$"{reverse off}, pick a weapon":INPUT"{space*3}(h,l,r,t){space*2}{cm b}{left*3}";n$
650 n$=LEFT$(n$,1):IFn$="h"ORn$="l"ORn$="r"ORn$="t"THENb$=n$:GOTO690
660 IFn$="s"THENGOSUB2410
670 IFn$="q"THEN1580
680 PRINTa$"{down}"s$s$:GOTO640
690 w$="rain":IFLEFT$(w$,1)=n$THENff=5:tt=ff:o=2:GOTO740
700 w$="hail":IFLEFT$(w$,1)=n$THENcc=58:ff=4:tt=ff:o=0:GOTO740
710 w$="tornado":IFLEFT$(w$,1)=n$THENcc=102:ff=7:tt=ff:o=1:GOTO740
720 w$="lightning":IFLEFT$(w$,1)=n$THENo=0:GOTO740
730 PRINT"{up*2}":GOTO540
740 PRINTa$"{down}"s$:PRINTs$:PRINT"{white}{up*2}the weapon is {reverse on}"w$
750 IFo=1THENPRINT"{home}{down}";:FORv=1TO40:PRINT"{gray}{cm +*2}";:NEXT:PRINTa$;"{down*2}
760 IFct=2THENct=0:GOTO2060
770 IFct=1THENct=0:GOTO1900
780 IFm=3THENa1=0:IFb$="l"ANDee<1THENa1=-1:GOTO810
790 IFm=3ANDb$="l"ANDee>1THENa1=1
800 IFm<3THENPRINTa$"{down*2}";:INPUT"{right}{white}charge{space*2}{cm b}{left*3}";bb$:a1=VAL(bb$)
810 IFa1<-150THENa1=-150
820 IFa1>150THENa1=150
830 PRINTa$"{down*2}"s$:PRINT"{white}{up} charge is"INT(a1)
840 IFb$="h"THENGOSUB1360:GOTO870
850 IFb$="l"THENGOSUB1360:GOTO1190
860 IFo=1THENPRINT"{home}{down*3}";:FORv=1TO20:PRINT"{gray}{cm +*2}";:NEXT:PRINT:ee=1.5*ee
870 e=(a1+ee)/50:dd=0:gg=104
880 IFo=2ANDe<0THENcc=78:GOTO910
890 IFo=2ANDe>0THENcc=77:GOTO910
900 IFo=2THENcc=118
910 a=1148+aa:bb=0:ff=tt:t=ww:i=0:FORw=1TO17:ww=w
920 IFt=wwTHENw=17:ww=0
930 a=a+(40+e):GOSUB1030:NEXT:POKE54273,0:POKE54277,0
940 IFo<>1THEN1000
950 IFPEEK(c+1)=96ORPEEK(c-1)=96THEN1000
960 POKEc+1,gg:POKEc+54273,1:POKEc-1,gg:IFPEEK(c+2)=96ORPEEK(c-2)=96THEN1000
961 POKEc+54271,1
970 POKEc+2,gg:POKEc+54274,1:POKEc-2,gg:IFe>0ORe=0THENPOKEc-38,32:POKEc-39,32
971 POKEc+54270,1
980 IFe<1THENPOKEc-41,32:POKEc+54231,1:POKEc-42,32:POKEc+54230,1
990 IFgg<>32THENGOSUB2250
1000 IFnn<>1THENGOSUB1360
1010 IFdd=0THENdd=1:cc=32:gg=cc:GOTO910
1020 GOTO380
1030 c=a:FORz=1TOff:c=c+1:d=PEEK(c):IFo=1ANDe<0THENd=PEEK(c-1)
1040 IFd=96THENGOSUB1380:w=17:o=0:RETURN
1050 IFd>102ANDdd=0THENPOKE54276,0:POKE54273,0:GOSUB1120
1060 IFi>2THENw=17
1070 POKEc,cc:POKEc+54272,1:NEXT:bb=1-bb:IFbb=0ANDb$="t"THENff=ff-1
1080 IFw=17THENRETURN
1090 POKE54276,0:POKE54277,0:POKE54272,0:IFcc=32THEN1110
1100 POKE54277,9:POKE54276,17:POKE54273,cc-w*3:POKE54272,cc:RETURN
1110 POKE54277,9:POKE54276,33:POKE54273,cc-12-w:POKE54272,cc:RETURN
1120 FORx=1TO2:POKEc,170:POKEc+54272,1:GOSUB2170:POKEc,58:POKEc+54272,1
1121 GOSUB2170:NEXT:i=i+1:IFo<>0THENw=17
1130 RETURN
1140 f=0:g=-1:p=0:PRINTa$"{down}"s$:PRINTs$
1150 FORy=1TO5:FORx=1TO9:h=h+1:d=PEEK(h):IFd<>32THENp=p+1
1160 NEXT:h=h-49:NEXT
1170 IFg=-1THENf=p:g=0:p=0:h=h+223:GOTO1150
1180 g=p:h=1827:RETURN
1190 a1=a1/33:IFa1<-4THENa1=-4
1200 IFa1>4THENa1=4
1210 IFa1>1THENa1=a1-1
1220 aa=aa+a1+7:IFaa>33THENaa=33
1230 IFaa<6THENaa=6
1240 FORz=1TO3:GOSUB1340:PRINTc$:POKElf,1:POKElf,0:GOSUB1340:PRINTd$:NEXT
1250 GOSUB1350:GOSUB1340:PRINTc$:POKElf,1:POKElf,0:GOSUB1340:PRINTd$:GOSUB1360
1260 IFa1>0THEN1300
1270 IFa1=0THEN1320
1280 FORz=1TO2:GOSUB1340:PRINTe$:POKElf,1:GOSUB2190:POKElf,0:GOSUB1340:PRINTf$
1290 aa=aa+1:NEXT:GOTO380
1300 FORz=1TO2:GOSUB1340:PRINTg$:POKElf,1:GOSUB2190:POKElf,0:GOSUB1340:PRINTh$
1310 aa=aa-1:NEXT:GOTO380
1320 FORz=1TO2:GOSUB1340:PRINTi$:POKElf,1:GOSUB2190:POKElf,0:GOSUB1340:PRINTj$
1330 NEXT:GOTO380
1340 PRINT"{home}{down*4}"SPC(aa);:FORv=1TO25:NEXT:RETURN
1350 FORv=1TO500:NEXT:RETURN
1360 FORv=1TO1000:NEXT:RETURN
1370 FORv=1TO250:NEXT:RETURN
1380 IFnn=1THENRETURN
1390 PRINT"{home}"SPC(13)"{reverse on}{white}out of bounds!":GOSUB2150:FORv=1TO2500:NEXT
1400 PRINT"{home}"SPC(13)"{white}{sh asterisk*2} {yellow}round"mm"{white}{left} {sh asterisk*3}":nn=1:RETURN
1410 FORx=1TO10:GOSUB2250:NEXT:RETURN
1420 PRINTa$;"{reverse on}{space*2}"s$"{reverse off}"s$s$"{home}
1430 POKElf,4:FORv=1TO9:GOSUB2250:NEXT
1440 POKElf,0:b$=y$:p=f*2.44:IFg>0THENb$=z$:p=g*2.44
1450 t=8-(LEN(z$)/2):IFt<0THENt=0
1460 PRINTa$"{white}{reverse on}"TAB(t)z$
1470 t=33-LEN(y$)/2:IFt+LEN(y$)>39THENt=40-LEN(y$)
1480 PRINTa$"{white}{reverse on}{left}"SPC(t)y$
1490 PRINT"{home}{down*13}{right*3}"INT(f*2.33)"{left}% left"
1500 PRINT"{home}{down*13}"SPC(28)INT(g*2.33)"{left}% left"
1510 PRINT"{home}{down*11}{right*10}";
1520 IFf=gTHENPRINT"{space*4}it's a tie!":GOTO1550
1530 PRINT"{up}{left}the winner is ";:IFf<gTHENPRINTy$:s=s+1:GOTO1550
1540 PRINTz$:rr=rr+1
1550 PRINTa$"{down}"s$;:INPUT"{space*2}{white}want to play again (y/n){space*2}{cm b}{left*3}";n$
1560 IFLEFT$(n$,1)="s"THENGOSUB2410
1570 IFLEFT$(n$,1)<>"n"THEN1600
1580 POKE53269,0:PRINT"{clear}{white}{down*2}{space*2}thank you for playing weatherwar ii{down*2}
1590 PRINT"{cyan}{down*2}{space*4}the final score's : {yellow}{up}"y$"="s:PRINTTAB(24)"{down}"z$"="rr"{black}":END
1600 IFLEFT$(n$,1)<>"y"THEN1550
1610 t$=z$:z$=y$:y$=t$:x=s:s=rr:rr=x
1620 GOSUB2270:POKE53269,0:GOTO270
1630 PRINT"{white}{down*2}what's player"j"{left} 's name{space*12}{left*10} {cm b}{left*3}";:INPUTap$
1640 IFLEN(ap$)<2THENPRINT"{up*3}";:GOTO1630
1650 IFLEFT$(ap$,4)="comp"THENap$="computer"
1660 ap$=LEFT$(ap$,8):GOSUB2220:RETURN
1670 PRINT"{clear}{down}"TAB(12)"{yellow}{cm l}{reverse on}WEATHERWAR II{reverse off}{cm j}":POKE53272,22:PRINT"{down}{light gray}The";
1680 PRINT" object is to destroy your OPPONENT'S HOME using Nature's weapons.
1690 PRINT"{down}The forces of HAIL, LIGHTNING, RAIN, and TORNADO are at your command.
1700 PRINT"{down}After WEAPON selection you must show the'CHARGE' you want to apply.
1710 PRINT"{down}Values are to be between -150 and 150,
1720 PRINT" numbers Negative go to the left of the{space*3}screen and Positive ";
1730 PRINT"to the right.":PRINT"{down}A 'WIND FACTOR' is also indicated and
1740 PRINT" must be taken into consideration - or +{space*2}when determining the";
1750 PRINT"'CHARGE' to use.":PRINT"{down}Also, just as in life, a random 'ACT OF ";
1760 PRINT" NATURE'S strikes from time to time.
1770 PRINT"{yellow}{down}{space*8}{cm l}{reverse on}HIT{sh space}ANY{sh space}KEY{sh space}TO{sh space}CONTINUE":FORv=1TO9:GETa$:NEXT
1780 GETa$:IFa$=""THEN1780
1790 GOTO2460
1800 IFLEFT$(z$,4)="comp"THENct=2
1810 GOTO500
1820 IFLEFT$(y$,4)="comp"THENct=1
1830 GOTO500
1840 pb=0:o=1:IFaa<8THENb$="l":n$=b$:li=li+1:IFli<3ANDmm<7THEN690
1850 IFmm=1THENb$="r":n$=b$:GOTO690
1860 pb=pb+1:IFpb>8THENb$="h":n$=b$:GOTO690
1870 b$=MID$("hrt",INT(RND(1)*3)+1,o):n$=b$:IFb$="t"ANDRND(1)<.7THEN1860
1880 IFb$="r"ANDRND(1)<.6ORli>0ORmm>6THEN1860
1890 GOTO690
1900 IFb$="l"ANDaa>3THENa1=mm*-20:GOTO810
1910 IFb$="l"ANDaa<4THENa1=0:GOTO810
1920 h=1668:FORy=0TO4:FORx=0TO8:d=PEEK(h+x):IFd=32THEN1940
1930 p=x:pq=(100-(y*5))/25:qq=x:qp=y:y=5:x=9
1940 NEXT:h=h+40:NEXT:h=1827
1950 a1=(ee*-1)-((aa-p)*pq)-1
1960 IFn$="t"THENee=(ee/1.5)+5:GOTO810
1970 IFaa<4ANDqq>5ANDqp>3THENa1=a1-qq-aa:GOTO810
1980 IFaa<4ANDqq>4THENa1=a1-qq-aa
1990 GOTO810
2000 pb=0:o=1:IFaa>18THENb$="l":n$=b$:lx=lx+1:IFlx<3ANDmm<6THEN690
2010 IFmm=1THENb$="r":n$=b$:GOTO690
2020 pb=pb+1:IFpb>8THENb$="h":n$=b$:GOTO690
2030 b$=MID$("hrt",INT(RND(1)*3)+1,o):n$=b$:IFb$="t"ANDRND(1)<.7THEN2020
2040 IFb$="r"ANDRND(1)<.6ORlx>0ORmm>6THEN2020
2050 GOTO690
2060 IFb$="l"ANDaa<23THENa1=mm*20:GOTO810
2070 IFb$="l"ANDaa>22THENa1=0:GOTO810
2080 h=1699:FORy=0TO4:FORx=0TO8:d=PEEK(h-x):IFd=32THEN2100
2090 p=x:pq=(100-(y*6))/25:y=5:x=9
2100 NEXT:h=h+40:NEXT:h=1827
2110 a1=(ee*-1)+(((28-aa)-p)*pq)
2120 IFmm=1THENa1=a1-9
2130 IFn$="t"THENee=(ee/1.5)-5
2140 GOTO810
2150 FORx=1TO20:POKE54277,29:POKE54276,17:POKE54273,17:POKE54276,129
2160 POKE54273,125:POKE54276,0:POKE54277,0:NEXT
2170 POKE54277,8:POKE54283,17:POKE54280,92:POKE54279,169
2180 POKE54283,0:POKE54277,0:POKE54272,0:RETURN
2190 POKE54277,29:POKE54276,129:POKE54273,6:POKE54272,4
2200 FORv=1TO20:POKElf,1:POKE53272,22:POKE53272,21:POKElf,0:NEXT
2210 POKE54276,0:POKE54277,0:POKE54272,0:RETURN
2220 POKE54276,0:POKE54277,0:POKE54272,0
2230 POKE54277,29:POKE54276,17:POKE54273,17:POKE54272,37
2240 FORx=1TO700:NEXT:POKE54276,0:POKE54277,0:POKE54272,0:RETURN
2250 POKE54276,0:POKE54277,0:POKE54277,29:POKE54276,33:FORx=40TO140STEP6
2260 POKE54273,15+x:NEXT:POKE54276,0:POKE54277,0:RETURN
2270 POKE54276,0:POKE54277,0:POKE54273,0
2280 POKE54283,0:POKE54284,0:POKE54280,0
2290 READh:READl:READd
2300 IFh=-1THENRESTORE:RETURN
2310 POKE54277,29:POKE54273,h/1.3:POKE54272,l:POKE54276,67:POKE54278,15
2320 POKE54284,29:POKE54280,h/2:POKE54283,17
2330 FORt=1TOd/17:POKE54275,t:NEXT:GOTO2270
2340 DATA66,111,400:88,33,450,0,0,70,99,111,200,22,77,200,66,50,950,88,33,450
2350 DATA50,44,200,33,33,90,33,88,320,55,77,77,88,33,200
2360 DATA66,111,400:88,33,450,0,0,70,99,111,200,22,77,200,66,50,950,88,33,450
2370 DATA50,44,200,33,33,90,33,88,320,55,77,77,88,33,999
2380 DATA-1,-1,-1
2390 POKE54276,0:POKE54277,0:POKE54277,29:POKE54276,33:FORx=160TO1STEP-5
2400 POKE54273,66:POKE54273,33:NEXT:POKE54276,0:POKE54277,0:RETURN
2410 PRINT"{home}{cyan}{down*6} the current score's : {yellow}{up}"y$"="s
2420 PRINT"{home}{yellow}{down*7}"SPC(23)z$"="rr
2430 FORv=1TO5000:NEXT:PRINT"{home}{white}{down*3}":FORv=1TO7
2440 PRINT"{space*24}";
2450 NEXT:RETURN
2460 PRINT"{clear}{down}"TAB(11)"{yellow}{cm l}{reverse on}WEATHERWAR II{reverse off}{cm j}":PRINT"{down}{light gray}The COMPUTER ";
2470 PRINT"PLAYS, if you type in{space*7}'COMPUTER' for player 1 or player 2.
2480 PRINT"{down}Play continues until the ROUND is{space*8}completed, giving both";
2490 PRINT" players an equal{space*2}number of Wheather Strikes.
2500 PRINT"{down}Enter a 'S' as weapon selection to see{space*3}Current Scores. (1 point ";
2510 PRINT"per game){space*5}{down}Enter a 'Q' as weapon selection to QUIT{space*2}the game in";
2520 PRINT" progress.":PRINT"{down}Lightning is the most destructive weapon ";
2530 PRINT"and hail the most useful.
2540 PRINT"{down}The INSTRUCTIONS will be shown ONCE, so{space*2}if you don't under";
2550 PRINT"stand, then hit 'R'{space*5}to repeat them.
2560 PRINT"{yellow}{down}{space*6}{cm l}{reverse on}HIT{sh space}ANY{sh space}KEY{sh space}TO{sh space}START{sh space}PLAY{reverse off}{cm k}":FORv=1TO9:GETa$:NEXT
2570 GETa$:IFa$=""THEN2570
2580 IFa$="r"THEN1670
2590 PRINT"{clear}":POKE53272,21:GOTO150
2600 v=53248:POKEv+21,0:RESTORE:FORx=1TO39:READa:NEXT:FORx=0TO7:POKE2040+x,11
2610 NEXT:FORx=0TO62:READa:POKE704+x,a:NEXT:POKEv+23,199:POKEv+29,137
2620 POKEv+27,120:FORx=0TO16:READa:POKEv+x,a:NEXT:FORx=39TO46:READa
2630 POKEv+x,a:NEXT:RETURN
2640 DATA0,48,0,0,112,0
2650 DATA0,248,0,0,248,0
2660 DATA1,252,0,12,252,0
2670 DATA13,254,0,15,254,224
2680 DATA7,253,224,7,251,224
2690 DATA25,253,192,31,255,192
2700 DATA111,255,216,111,255,184
2710 DATA119,255,120,63,255,240
2720 DATA31,255,224,7,255,0
2730 DATA3,254,0,1,252,0
2740 DATA0,248,0
2750 DATA19,176,30,148,58,154,111,197,227,197,229,191,228,176,49,176,132
2760 DATA5,5,5,9,10,9,8,5
2770 END
stop tok64
(bastext 1.0)