start tok64 d64-Wwg54A
130 POKE53280,.:POKE53281,.:sc$="off"
140 PRINT"{yellow}{clear}{ct n}Label BASIC converter v2.0b
150 PRINT"{down}This is a {white}Share Ware {yellow}program.
160 PRINT"{down}(c)1991-92 Peter Karlsson
170 PRINT"{down}{light green} MAIN MENU
180 PRINT"{=*11}
190 PRINT"{down}{cyan}1. {light green}Display {white}Share Ware note
192 PRINT"{down}{cyan}2. {white}Convert a text file to Stage 2
193 PRINT"{down}{cyan}3. {cyan}Enable/disable special codes table
194 PRINT"{space*3}{light blue}Current setting is: {white}"sc$
195 PRINT"{down}{cyan}4. {light green}Quit program
200 POKE198,.:WAIT198,1:GETa$:IFa$<"1"ORa$>"4"THEN200
210 ONVAL(a$)GOTO2000,230,3000:PRINT"{clear}";:END
230 POKE53280,6:POKE53281,6:INPUT"{clear}{white}Input file name";ip$
240 op$=LEFT$("s2/"+ip$,16)
250 PRINT"{down}The result will be sent to the SEQ-file
260 PRINTop$
270 op$=LEFT$("s2/"+ip$,16)
280 OPEN15,8,15:PRINT"{down}Reading "ip$"{.*3}
290 OPEN2,8,2,ip$+",s,r":GOSUB1000
300 DIMrn$(1000),lb$(100)
310 rn=1
320 GET#2,a$:IFstTHEN345
330 IFa$<>CHR$(13)THENrn$(rn)=rn$(rn)+a$:GOTO320
340 GOSUB1000:rn=rn+1:GOTO320
345 IFrn$(rn)<>""THENrn=rn+1
350 CLOSE2:rn=rn-1
360 PRINT"Done."rn"lines were found.
370 PRINT"{down}Searching labels{.*3}":lb=.
380 FORi=1TOrn
390 IFLEFT$(rn$(i),2)=":;"THEN410
400 NEXT:GOTO430
410 lb=lb+1:lb$(lb)=RIGHT$(STR$(10000+i+1),4)+MID$(rn$(i),3)
420 rn$(i)="rem * "+MID$(lb$(lb),5)+" *"
425 PRINTCHR$(34)MID$(lb$(lb),5)CHR$(34)" at line #"i:GOTO400
430 PRINT"Done."lb"labels were found.
440 PRINT"{down}Converting jumps to line#s
450 FORi=1TOrn
460 FORj=1TOLEN(rn$(i))-3
470 IFMID$(rn$(i),j,2)="::"THENk=j+2:GOTO500
480 NEXT
490 NEXTi:GOTO570
500 lb$=""
510 lb$=lb$+MID$(rn$(i),k,1):k=k+1
520 IFk>LEN(rn$(i))ORMID$(rn$(i),k,1)=","ORMID$(rn$(i),k,1)=":"THEN540
530 GOTO510
540 FORz=1TOlb:IFMID$(lb$(z),5)<>lb$THENNEXT:GOTO560
550 rn$(i)=LEFT$(rn$(i),j-1)+STR$(VAL(LEFT$(lb$(z),4)))+MID$(rn$(i),k):GOTO460
560 PRINT"Unknown label in line #"i"{left}:"lb$:GOTO490
570 PRINT"Done.
575 IFsc$="on"THENGOSUB800
580 PRINT"{down}Press any key to save the result file{space*3}to disk.
590 POKE198,.:WAIT198,1:POKE198,.
600 OPEN2,8,2,"@0:"+op$+",s,w":GOSUB1000
610 PRINT#2,CHR$(34)"0 rem created with label basic v2.0b{space*4}(c)peter karlsson
620 FORi=1TOrn
625 PRINT#2,CHR$(34)MID$(STR$(i),2)rn$(i):GOSUB1000:PRINTi;rn$(i)
630 NEXT:PRINT#2,"{arrow left}":GOSUB1000
640 CLOSE2:GOSUB1000
650 PRINT"ready.
660 PRINT"{down}Load the stage 2-converter to convert
670 PRINTCHR$(34)op$CHR$(34)" to basic.
680 END
800 PRINT"{down}Converting special codes{.*3}
810 READs:DIMsc$(s,1):FORi=1TOs:READsc$(i,0),sc$(i,1):NEXT
820 FORi=1TOrn:tp$=rn$(i)
821 FORj=1TOLEN(tp$)
830 IFMID$(tp$,j,1)<>"{arrow left}"THENNEXT:rn$(i)=tp$:NEXT:PRINT"Done.":RETURN
840 FORk=1TOs:IFMID$(tp$,j+1,1)<>sc$(k,.)THENNEXT:j=j+1:GOTO830
850 tp$=LEFT$(tp$,j-1)+sc$(k,1)+MID$(tp$,j+2):GOTO821
900 DATA33,{arrow left},{arrow left},/,{^},?,"{pi}",g,"{clear}",h,"{home}",1,"{black}",2,"{white}",3,"{red}",4,"{cyan}",5,"{156}",6,"{green}",7,"{blue}"
901 DATA8,"{yellow}",9,"{reverse on}",0,"{reverse off}",q,"{orange}",w,"{brown}",e,"{pink}",r,"{dark gray}",t,"{gray}",y,"{light green}",u,"{light blue}",i,"{light gray}",z,]
902 DATAx,[,c,{pound},v,"{sh -}",b,"{sh +}",n,"{cm -}",",","{down}",o,"{up}",k,"{left}",l,"{right}"
1000 INPUT#15,a,a$,b,b:IFa<20THENRETURN
1010 PRINT"{down*2}Disk Error:"a;CHR$(34)a$CHR$(34)
1020 CLOSE2:CLOSE15:END
2000 PRINT"{clear}{light blue}Share Ware note"
2030 PRINT"{down}{green}This program is {white}NOT {green}public domain, and
2040 PRINT"is fully copyrighted. Due to the giant
2050 PRINT"costs of marketing, the {white}Share Ware{green} type
2060 PRINT"of marketing is used. If you find this
2070 PRINT"program useful, please send SEK 20 to:
2080 PRINT"{down}Detta program [r {white}INTE {green}public domain, och";
2090 PRINT"[r helt copyrightat. Pga de stora kost-
2100 PRINT"naderna f{pound}r marknadsf{pound}ring, s] anv[nds
2110 PRINT"{white}Share Ware{green}-metoden. Om du finner detta
2120 PRINT"program anv[ndbart, var god s[nd SEK 20
2130 PRINT"till:
2140 PRINT,"{yellow}{down}Peter Karlsson
2150 PRINT,"Vaernsta Ullersaeter
2160 PRINT,"{left}{orange}S{yellow}710 40{space*2}FROEVI
2170 PRINT,"{orange}Sweden
2180 PRINT"{down}{light blue}PRESS ANY KEY{space*3}TRYCK EN TANGENT"
2190 POKE198,.:WAIT198,1:GETa$:RUN
3000 IFsc$="on"THENRUN
3010 sc$="on"
3020 PRINT"{clear}{white}These codes are used in programs:
3030 PRINT"{down}{yellow}CODE GIVES{space*3}CODE GIVES
3040 PRINT"{light green}{arrow left*2}{space*3}{arrow left}{space*7}{arrow left}9{space*3}Reverse On
3050 PRINT"{arrow left}/{space*3}^{space*7}{arrow left}0{space*3}Reverse Off
3060 PRINT"{arrow left}g{space*3}Clear{space*3}{arrow left}z{space*3}]
3070 PRINT"{arrow left}h{space*3}Home{space*4}{arrow left}x{space*3}[
3080 PRINT"{arrow left}1{space*3}Black{space*3}{arrow left}c{space*3}{pound}
3090 PRINT"{arrow left}2{space*3}White{space*3}{arrow left}v{space*3}{sh -}
3100 PRINT"{arrow left}3{space*3}Red{space*5}{arrow left}b{space*3}{sh +}
3110 PRINT"{arrow left}4{space*3}Cyan{space*4}{arrow left}n{space*3}{cm -}
3120 PRINT"{arrow left}5{space*3}Purple{space*2}{arrow left}?{space*3}Pi-sign
3130 PRINT"{arrow left}6{space*3}Green{space*3}{arrow left},{space*3}Down
3140 PRINT"{arrow left}7{space*3}Blue{space*4}{arrow left}o{space*3}Up
3150 PRINT"{arrow left}8{space*3}Yellow{space*2}{arrow left}k{space*3}Left
3160 PRINT"{arrow left}q{space*3}Orange{space*2}{arrow left}l{space*3}Right
3170 PRINT"{arrow left}w{space*3}Brown
3180 PRINT"{arrow left}e{space*3}Light Red
3190 PRINT"{arrow left}r{space*3}Dark Grey
3200 PRINT"{arrow left}t{space*3}Medium Grey
3210 PRINT"{arrow left}y{space*3}Light Green
3220 PRINT"{arrow left}u{space*3}Light Blue
3230 PRINT"{arrow left}i{space*3}Light Grey
3240 PRINT"{down}{light blue}PRESS ANY KEY{space*3}TRYCK EN TANGENT";
3250 POKE198,.:WAIT198,1:GETa$:GOTO140
9000 REM updates:
9001 REM v1.1 - 1991.12.30
9002 REM v2.0 - 1992.07.21
9003 REM v2.0b- 1992.08.23
stop tok64
(bastext 1.0)