start tok64 d64-WjnJYl
0 REM"{delete*6}save"@0:link viewer v1.1",8
5 REM{reverse on} -----------------------------v1.1
6 REM{reverse on} link viewer(c)1992 peter karlsson
7 REM{reverse on} ---------------------------------
8 REM{reverse on} this program is public domain !!!
9 REM{reverse on} ---------------------------------
10 RUN11
11 DIMa$(144),t$(5),s$(5):s=1:z$="spurseq{space*2}prg{space*2}usr{space*2}rel":o$=CHR$(34)+CHR$(20)
12 OPEN15,8,15,"i0":OPEN2,8,2,"#"
13 PRINT#15,"u1 2 0 18 0"
14 GET#2,t$,s$:e$=CHR$(.)
15 a=ASC(s$+e$)
16 FORm=.TO1STEP.
17 PRINT#15,"u1 2 0 18"a
18 FORq=2TO226STEP32
19 PRINT#15,"b-p 2"q
20 FORi=.TO20
21 GET#2,x$:a$(s)=a$(s)+LEFT$(x$+e$,1)
22 NEXT:IFASC(a$(s))THENPRINTo$MID$(a$(s),4,16):s=s+1
23 a$(s)="":NEXT
24 PRINT#15,"b-p 2 0
25 GET#2,t$,s$:e$=CHR$(.)
26 IFASC(t$+e$)>.THENa=ASC(s$+e$):NEXTm
27 CLOSE2:CLOSE15:s=s-1
28 FORi=1TOs
29 m=ASC(a$(i))
30 IF(mAND7)>.AND(mAND7)<5AND(mAND128)=128THEN34
31 IFi=sTHENs=s-1:GOTO28
32 FORj=iTOs-1:a$(j)=a$(j+1):NEXT:s=s-1
33 GOTO28
34 NEXT
35 POKE53280,.:POKE53281,.
36 PRINT"{clear}{green}{reverse on} antal filer p] disken :"s"{left} ":IFs>48THENs=48
37 d$="{home}{down*24}
38 b$="0123456789abcdefghijklmnopqrstuvwxyz+-{pound}@*^:;=,./
39 FORi=1TOs
40 PRINTLEFT$(d$,1+i+24*(i>24));:IFi>24THENPRINTTAB(20)
41 PRINT"{white}{reverse on}"MID$(b$,i,1)"{green}{reverse off}>{yellow}"o$MID$(a$(i),4,16)o$"{light green}"MID$(z$,ASC(a$(i))AND7,1);
42 NEXT
43 PRINT"{home}{down}{left*5}{light gray}{reverse on}v[lj":POKE198,.:WAIT198,1:GETa$
44 FORf=1TOs:IFMID$(b$,f,1)<>a$THENNEXT:GOTO43
45 PRINT"{clear}{green} blocklista f{pound}r : {white}"o$MID$(a$(f),4,16)o$;
46 PRINT"{light green}("MID$(z$,(ASC(a$(f))AND7)*5,3)")"
47 PRINT"{light gray} sp]r -> {yellow}{1*10}{2*10}{3*6}{light gray} s{cm m}
48 PRINT"{yellow}12345678901234567890123456789012345{light gray} kMN
49 p$="{.*17}d{.*17}"
50 FORi=.TO20
51 PRINT"{156}"LEFT$(p$,35+5*(i=17)+11*(i=18)+18*(i>18))TAB(36)
52 PRINT"{yellow}"MID$(STR$(100+i),3)
53 NEXT
54 OPEN15,8,15:OPEN2,8,2,"#":b=.:by=.
55 t=ASC(MID$(a$(f),2)):a=ASC(MID$(a$(f),3))
56 PRINT#15,"u1 2 0"t;a
57 PRINTLEFT$(d$,4+a)TAB(t-1)"{green}V"LEFT$(d$,24)TAB(20)STR$(t)","STR$(a)"{space*2}"
58 GET#2,t$,s$:t=ASC(t$+e$):a=ASC(s$+e$)
59 b=b+1:by=by+254:IFtTHEN56
60 by=by+a-255:CLOSE2:CLOSE15:PRINTLEFT$(d$,24)TAB(20)"{space*7}"
61 PRINTd$"{green}"by"bytes"TAB(20)"antal block:{yellow}"b;
62 m=ASC(a$(f)):IF(mAND7)<4THEN73
63 OPEN15,8,15:OPEN2,8,2,"#":b=.
64 t=ASC(MID$(a$(f),20)):a=ASC(MID$(a$(f),21))
65 PRINT#15,"u1 2 0"t;a
66 PRINT#15,"b-p 2 4"
67 FORi=.TO5:GET#2,t$(i),s$(i):NEXT
68 CLOSE2:CLOSE15
69 FORi=.TO5:t=ASC(t$(i)+e$):a=ASC(s$(i)+e$):IFt=.THEN71
70 b=b+1:PRINTLEFT$(d$,4+a)TAB(t-1)"{light green}{sh +}{green}"LEFT$(d$,23)
71 NEXT
72 PRINTLEFT$(d$,23)TAB(20)"{green}antal side-"CHR$(13)TAB(20)"sectorblock:{yellow}"b
73 POKE198,.:WAIT198,1:GETa$
74 PRINT"{green}{clear}meny:
75 PRINT"{white}1.{green} samma disk
76 PRINT"{white}2.{green} ny disk
77 PRINT"{white}3.{green} sluta
78 POKE198,.:WAIT198,1:GETa$:IFa$<"1"ORa$>"3"THEN78
79 ONVAL(a$)GOTO35,10,80
80 POKE53280,14:POKE53281,6:PRINT"{light blue}{clear}";
stop tok64
(bastext 1.0)