start tok64 d64-Vtl9bD
0 PRINT"{clear}{reverse on}shift{reverse off} hoppar till fil-menyn
10 FORl=679TO730:READa:POKEl,a:NEXT
11 SYS679:POKE52,128:POKE56,128
12 POKE56578,PEEK(56578)OR3:POKE56576,(PEEK(56576)AND252)OR1
13 POKE648,136:POKE53272,32:PRINT"{142}{clear}";
14 DATA120,165,1,41,251,133,1,169,,133,251,169,208,133,252,169,,133,253,169
15 DATA128,133,254,160,,177,251,145,253,200,192,,208,247,230,252,230,254,165
16 DATA252,201,216,208,237,165,1,9,4,133,1,88,96
17 FORs=27*8TO29*8+7:READt:POKE32768+s,t:POKE33792+s,255-t:NEXT
18 DATA102,24,60,102,126,102,102,
19 DATA102,60,102,102,102,102,60,
20 DATA60,36,60,102,126,102,102,
21 FORi=.TO7:POKE33576+i,128:POKE33592+i,1:POKE34600+i,127:POKE34616+i,254:NEXT
30 IFPEEK(653)=1THEN1000
40 PRINT"{clear}{down*7}{green}
50 PRINT"{reverse on}{cm m}{cm g}{right}{up}{reverse off}{cm f}{cm d}{down}{left*2}{reverse on}{sh pound}{cm asterisk}{right}{cm d}{cm asterisk}{right} {right*2} {cm asterisk}{right} {sh asterisk}{right}{space*2}{right} {right} {cm asterisk}
51 PRINT"{cm asterisk}{sh pound}{right}{reverse on}{cm m}{cm g}{right}{cm d}{cm asterisk}{right}{space*2}{right} {reverse off}{sh pound}{right}{reverse on}{cm y} {right}{cm k}{reverse off}{cm k}{right}{reverse on} {right} {reverse off}{sh pound}
100 REM * v[rldstid *
110 POKE53280,.:POKE53281,.:POKE646,12
120 INPUT"{home}{down*2}{right*8}svensk normaltid (ej sommartid){right}hhmmss";sn$
130 IFLEN(sn$)<>6THEN120
140 ti$=sn$
142 DATA22:REM antal st[der
150 DATA"{yellow}stockholm {green}(cet)",+1
160 DATAlondon (gmt),+0
170 DATAmoskva,      +3
180 DATAwashington,  -5
190 DATAlos angeles, -8
200 DATAtokyo,       +9
210 DATAcanberra,    +10
220 DATAbuenos aires,-3
230 DATAhelsingfors, +2
240 DATApeking,      +8
242 DATAmexico city, -6
244 DATAphnom penh,  +7
246 DATAlas palmas,  -1
247 DATAwellington,  +12
248 DATAdenver,      -7
249 DATAfairbanks,   -10
250 DATAsantiago,    -4
251 DATAanadyr,      +13
252 DATAnome,        -11
253 DATAangmagssallk,-2
254 DATAdhaka,       +6
255 DATAdawson,      -9
260 DATAjan,31,feb,28,mar,31,apr,30,maj,31,jun,30,jul,31,aug,31,sep,30,okt,31
270 DATAnov,30,dec,31
300 READtw:DIMtw$(tw),tm(tw):FORi=1TOtw:READtw$(i),tm(i):NEXT
301 PRINT"{home}{down*2}{space*39}"
302 PRINT"{space*39}"
305 PRINT"{home}{down*2}{right*10}sorterar tider
310 FORi=2TOtw:tm(i)=tm(i)-tm(1):NEXT:tm(1)=.
311 FORi=1TOtw-1
312 FORj=i+1TOtw
313 IFtm(i)=>tm(j)THENx=tm(i):tm(i)=tm(j):tm(j)=x:x$=tw$(i):tw$(i)=tw$(j):tw$(j)=x$
314 NEXT:NEXT:PRINT"{home}{down*2}{right*10}{space*14}"
320 INPUT"{home}{down*2}{right*10}datum (i sverige){right*13}{]*4}mmdd";dt$
330 IFLEN(dt$)<>8THEN320
331 DIMmt$(12),dm(12,1)
332 FORi=1TO12:READmt$(i),dm(i,.):dm(i,1)=dm(i,.)-(i=2):NEXT
340 yr=VAL(LEFT$(dt$,4))
350 mt=VAL(MID$(dt$,5,2))
360 dt=VAL(MID$(dt$,7)):PRINT"{clear}{down}":FORi=1TOtw
361 PRINT"{green}"tw$(i):NEXT
365 FORi=.TO39:POKE34856+i,64:POKE55336+i,4:NEXT
370 PRINT"{home}{down}
380 hr=VAL(LEFT$(ti$,2)):mn=VAL(MID$(ti$,3,2))
385 sy=-((INT(yr/4)=yr/4)-(INT(yr/100)=yr/100)+(INT(yr/400)=yr/400))
390 FORi=1TOtw:h=hr+tm(i):d0=.:IFh<0THENd0=-1:h=h+24
400 IFh>23THENd0=1:h=h-24
410 PRINT"{yellow}"TAB(15)MID$(STR$(100+h),3)"{orange}:{yellow}"MID$(STR$(100+mn),3);
420 d=dt+d0:m=mt:y=yr:x9=.
430 IFd<1THENm=m-1:x9=-1:IFm<1THENy=y-1:m=m+12
440 IFd>dm(m,sy)THENm=m+1:x9=1:IFm>12THENy=y+1:m=m-12
450 IFx9=1THENd=1
460 IFx9=-1THENd=dm(m,sy)
470 PRINT"{light blue} "MID$(STR$(100+d),3)" "mt$(m)y;:sh=h+1+24*(h=23)
471 PRINTTAB(34)"{dark gray}"MID$(STR$(sh+100),3)":"MID$(STR$(mn+100),3):NEXT
480 PRINT"{home}{down*24}{white}obs! {dark gray}gr]a {gray}tider anger sommartid!{home}";
490 hs=hr+1+24*(hr=23):PRINT"{home}{cyan}cet: {yellow}"ti$dt"{left}/"MID$(STR$(mt),2)yr,
495 PRINT"{dark gray}"MID$(STR$(hs+100),3)MID$(ti$,3)
500 IFRIGHT$(ti$,2)>"00"THEN490
501 h$=MID$(STR$(101+hr+24*(hr=23)),3)+MID$(ti$,3,2)
502 PRINT"{home}{right*5}{yellow}"LEFT$(ti$,4)"{dark gray}VV{space*19}{dark gray}"h$"VV"
510 IFLEFT$(ti$,4)<>"{0*4}"THEN370
520 dt=dt+1
530 IFdt=<dm(mt,sy)THEN370
540 mt=mt+1:dt=1
550 IFmt=<12THEN370
560 yr=yr+1:mt=1:GOTO370
1000 POKE53280,.:POKE53281,.:PRINT"{clear}
1005 sv$="save":dv$="tape":sv=1:dv=1
1010 PRINT"{green}{home}file menu:
1020 PRINT"{light green}1) {green}save/load/verify:{space*8}{left*6}"sv$
1030 PRINT"{light green}2) {green}tape/disk:{space*15}{left*6}"dv$
1050 PRINT"{down*4}{light green}9) {green}execute
1060 GETa$:IFa$<"1"ORa$>"9"THEN1060
1070 IFa$="9"THEN1210
1080 IFa$="1"THENsv=sv+1+3*(sv=3)
1090 IFa$="2"THENdv=dv+1+3*(dv=3)
1100 IFa$>"3"ANDa$<"9"THEN1060
1120 IFsv=1THENsv$="save
1130 IFdv=1THENdv$="tape
1150 IFsv=2THENsv$="verify
1160 IFdv=2THENdv$="disk#8
1170 IFsv=3THENsv$="load
1180 IFdv=3THENdv$="disk#9
1200 GOTO1010
1210 PRINT"{clear}{down*2}";:nm$=CHR$(34)+"v[rldstid"+CHR$(34):n$="save"+nm$:v$="verify"+nm$
1220 ct$=CHR$(34):IFtr=1ANDdv<3THEN1380
1230 IFsv>1THEN1280
1240 IFdv=1THENPRINTn$
1250 IFdv=2THENPRINTn$",8
1260 IFdv=3THENPRINTn$",9
1270 GOTO1490
1280 IFsv>2THEN1330
1290 IFdv=1THENPRINTv$
1300 IFdv=2THENPRINTv$",8
1310 IFdv=3THENPRINTv$",9
1320 GOTO1490
1330 INPUT"programnamn";p$
1340 IFdv=1THENPRINT"load"ct$p$
1350 IFdv=2THENPRINT"load"ct$p$ct$",8
1360 IFdv=3THENPRINT"load"ct$p$ct$",9
1370 GOTO1490
1380 IFsv>1THEN1420
1390 PRINTn$",7":GOTO1490
1420 IFsv>2THEN1460
1430 IFdv=1THENPRINTv$",7":GOTO1490
1460 INPUT"programnamn";p$
1470 IFdv=1THENPRINT"load"ct$p$ct$",7
1490 PRINT"{home}";:POKE198,5:POKE631,13:POKE632,82:POKE633,85:POKE634,78:POKE635,13
stop tok64
(bastext 1.0)