start tok64 d64-Tuc2Xf
2 REM{reverse on}   program information    
3 REM{reverse on}   programinformation     
4 REM{reverse on}   programm information   
5  
6 REM (c)1992 peter karlsson
7 REM this program is public domain
8  
9 REM v1.02  92.04.06
100  
102 POKE53280,.:POKE53281,.
104 PRINT"{ct n}{ct h}{clear}{down*2}{right}{white} 1.{space*2}English
106 PRINT"{down}{right}{yellow} 2.{space*2}Svenska
108 PRINT"{down}{right}{green} 3.{space*2}Deutsch
110 POKE198,.:WAIT198,1:GETl$:l=ASC(l$)-49:IFl<.ORl>2THEN110
112 DIMa$(14,2),t$(24,1):dn$="{home}{down*24}
114 FORi=.TO14:FORj=0TO2:READa$(i,j):NEXT:NEXT
116 PRINT"{clear}{down*2}{right}{white} "a$(.,l)
118 PRINT"{down}{right}{yellow} 1. "a$(1,l)
120 PRINT"{down}{right}{green} 2. "a$(2,l)
122 PRINT"{down}{right}{cyan} 3. "a$(13,l)
124 DATA"Menu","Meny","Menue","Read information","La{up}{left}{cm p}{down}s information"
126 DATA"Information lesen","Write informatin","Skriv information"
128 DATA"Information schreiben"
130 POKE198,.:WAIT198,1:GETm$:m=ASC(m$)-48:IFm<1ORm>3THEN130
132 IFm=3THENPOKE53280,14:POKE53281,6:PRINT"{clear}{light blue}{142}{ct i}";:END
134 ONmGOSUB136,218:GOTO116
136 PRINT"{clear}{yellow}{down}{right} "a$(3,l)
138 FORi=.TO24:t$(i,.)="":t$(i,1)="":NEXT
140 OPEN15,8,15
142 v=-1:OPEN2,8,0,"$0:i/*=s":GOSUB256
144 FORi=1TO32:GET#2,x$
146 NEXT
148 GET#2,x$,x$
150 GET#2,x$:IFx$="b"THEN162
152 IFx$<>CHR$(34)THEN150
154 v=v+1:IFv=25THENv=24:GOTO162
156 GET#2,x$:IFx$<>CHR$(34)THENt$(v,.)=t$(v,.)+x$:GOTO156
158 GET#2,x$:IFx$<>""THEN158
160 PRINTt$(v,.):GOTO148
162 CLOSE2:IFv>=.THEN166
164 PRINT"{clear}{down}{right}{green} "a$(4,l):POKE198,.:WAIT198,1:POKE198,.:CLOSE15:RETURN
166 FORi=.TOv
168 OPEN2,8,2,"0:"+t$(i,.)+",s,r":GOSUB256
170 INPUT#2,t$(i,1):GOSUB256
172 CLOSE2:GOSUB256:NEXT
174 PRINT"{clear}{yellow}";:FORi=.TOv
176 PRINTLEFT$(dn$,i+1)CHR$(48+i-7*(i>9))". "t$(i,1)"{home}"
178 NEXT
180 POKE198,.:WAIT198,1:GETa$
182 a=ASC(a$)-48:a=a+7*(a>9):IFa<.ORa>vTHEN180
184 PRINT"{clear}{down}{right} {yellow}Information:
186 OPEN2,8,2,"0:"+t$(a,.)+",s,r":GOSUB256
188 FORi=6TO10
190 PRINT"{down}{green} "a$(i,l)":
192 INPUT#2,i$:GOSUB256
194 PRINT"{yellow}"i$
196 NEXT
198 CLOSE2:GOSUB256:CLOSE15
200 POKE198,.:WAIT198,1:POKE198,.:RETURN
202 DATA"Please wait, reading titles","Var god va{up}{left}{cm p}{down}nta, la{up}{left}{cm p}{down}ser titlar"
204 DATA"Bitte warten, lesen die Titel","No information on this disk"
206 DATA"Ingen information pa{up}{left}.{down} disken","Kein Information auf Disk"
208 DATA"Reading program names","La{up}{left}{cm p}{down}ser programnamn"
210 DATA"Lesen die Programmnamen","Name of program","Programnamn"
212 DATA"Name des Programms","Verision no.","Verision","Verision","Author"
214 DATA"Skrivet av","Verfasser des Programms","Date","Datum","Datum"
216 DATA"Program type","Programtyp","Art des Programms"
218 PRINT"{clear}{down}{right}{yellow} "a$(11,l)
220 s$="":INPUTs$:IFs$=""THEN218
222 i$=LEFT$("i/"+s$,16)
224 PRINT"{clear}{green}{down}{right} "a$(12,l)":"
226 OPEN15,8,15
228 OPEN2,8,2,"@0:"+i$+",s,w":GOSUB256
230 FORi=6TO10
232 PRINT"{down} {green}"a$(i,l)":
234 i$="":INPUT"{yellow}";i$:IFi$=""THENPRINT"{up}";:GOTO234
236 PRINT#2,i$:GOSUB256
238 NEXT
240 CLOSE2:GOSUB256
242 CLOSE15
244 RETURN
246 DATA"Enter name used with SAVE","Ange namnet du gav vid SAVE"
248 DATA"Geben Sie bitte der SAVE-name an","Please enter these datas"
250 DATA"Var god mata in dessa data","Geben Sie bitte diese Datas an"
252 DATA"Quit program","Avsluta programmet","Programm beendet","Disk error"
254 DATA"Diskfel","Diskfehler"
256 INPUT#15,en$,em$,et$,es$
258 IFVAL(en$)<20THENRETURN
260 PRINT"{clear}{down}{right}{white}"LEFT$("{cm @*10}",LEN(a$(14,l)))
262 PRINT"{right}{reverse on}"a$(14,l)
264 PRINT"{down*2}"en$" - {yellow}"CHR$(ASC(em$)+32)MID$(em$,2)"."
266 PRINT"{right*5}{cyan}"et$"{green},{cyan}"es$
268 CLOSE2:CLOSE15
270 STOP
stop tok64
(bastext 1.0)