start tok64 d64-6ZsCCE
1 REM"{delete*6}save"@0:link viewer",8
5 REM{reverse on} ---------------------------------
6 REM{reverse on} link viewer(c)1992 peter karlsson
7 REM{reverse on} ---------------------------------
8 REM{reverse on} this program is public domain !!!
9 REM{reverse on} ---------------------------------
99 RUN100
100 DIMa$(144):s=1
101 OPEN15,8,15,"i0":OPEN2,8,2,"#"
102 PRINT#15,"u1 2 0 18 0"
103 GET#2,t$,s$:e$=CHR$(.)
104 a=ASC(s$+e$)
105 FORm=.TO1STEP.
106 PRINT#15,"u1 2 0 18"a
107 FORq=2TO226STEP32
108 PRINT#15,"b-p 2"q
109 FORi=.TO18
110 GET#2,x$:a$(s)=a$(s)+LEFT$(x$+e$,1)
111 NEXT:PRINTMID$(a$(s),4):s=s+1
112 NEXT
113 PRINT#15,"b-p 2 0
114 GET#2,t$,s$:e$=CHR$(.)
115 IFASC(t$+e$)>.THENa=ASC(s$+e$):NEXTm
116 CLOSE2:CLOSE15:s=s-1
117 FORi=1TOs
118 m=ASC(a$(i))
119 IF(mAND7)>.AND(mAND7)<4AND(mAND128)=128THEN123
120 IFi=sTHENs=s-1:GOTO117
121 FORj=iTOs-1:a$(j)=a$(j+1):NEXT:s=s-1
122 GOTO117
123 NEXT
124 POKE53280,.:POKE53281,.
125 PRINT"{clear}{green}{reverse on} antal filer p] disken :"s"{left} ":IFs>48THENs=48
126 d$="{home}{down*24}
127 b$="0123456789abcdefghijklmnopqrstuvwxyz+-{pound}@*^:;=,./
128 FORi=1TOs
129 PRINTLEFT$(d$,1+i+24*(i>24));:IFi>24THENPRINTTAB(20)
130 PRINT"{white}{reverse on}"MID$(b$,i,1)"{green}{reverse off}>{yellow}"MID$(a$(i),4);
131 NEXT
132 PRINT"{home}{down}{left*5}{light gray}{reverse on}v[lj":POKE198,.:WAIT198,1:GETa$
133 FORf=1TOs:IFMID$(b$,f,1)<>a$THENNEXT:GOTO132
134 PRINT"{clear}{green} blocklista f{pound}r : {white}"MID$(a$(f),4)
135 PRINT"{light gray} sp]r -> {yellow}{1*10}{2*10}{3*6}{light gray} s{cm m}
136 PRINT"{yellow}12345678901234567890123456789012345{light gray} kMN
137 p$="{.*17}d{.*17}"
138 FORi=.TO20
139 PRINT"{156}"LEFT$(p$,35+5*(i=17)+11*(i=18)+18*(i>18))TAB(36)
140 PRINT"{yellow}"MID$(STR$(100+i),3)
141 NEXT
142 OPEN15,8,15:OPEN2,8,2,"#":b=.:by=.
143 t=ASC(MID$(a$(f),2)):a=ASC(MID$(a$(f),3))
144 PRINT#15,"u1 2 0"t;a
145 PRINTLEFT$(d$,4+a)TAB(t-1)"{green}V"LEFT$(d$,24)TAB(20)STR$(t)","STR$(a)"{space*2}"
146 GET#2,t$,s$:t=ASC(t$+e$):a=ASC(s$+e$)
147 b=b+1:by=by+254:IFtTHEN144
148 by=by+a-255:CLOSE2:CLOSE15:PRINTLEFT$(d$,24)TAB(20)"{space*7}"
149 PRINTd$"{green}antal block:{yellow}"bLEFT$(d$,24)TAB(20)"{green}"by"bytes
150 POKE198,.:WAIT198,1:GETa$
151 PRINT"{green}{clear}meny:
152 PRINT"{white}1.{green} samma disk
153 PRINT"{white}2.{green} ny disk
154 PRINT"{white}3.{green} sluta
155 POKE198,.:WAIT198,1:GETa$:IFa$<"1"ORa$>"3"THEN155
156 ONVAL(a$)GOTO124,99,157
157 POKE53280,14:POKE53281,6:PRINT"{light blue}{clear}";
stop tok64
(bastext 1.0)