start tok64 d64-89rq0o
100 POKE53280,0:POKE53281,0:q$=CHR$(34)
110 PRINT"{clear}{white}{cm @*21}"
120 PRINT"{light gray}{reverse on}formatterings-idkoder"
130 PRINT"{light blue}{down}{pound}versatt av mr.p. of softwolves f{pound}r"
140 REM unders{pound}k formatterings-id - 154140 ?"sys pd 1992."
150 DIMt(35)
160 FOR i=1TO35
170 t(i)=1
180 NEXTi
190 PRINT"{yellow}{down*2}s[tt i disk som ska unders{pound}kas"
200 PRINT"{green}{down}tryck {light green}{reverse on}return{reverse off}{green} f{pound}r att forts[tta":IFqTHEN250
210 PRINT"{down*4}{white}obs! {yellow}detta program f{pound}rst{pound}r inte p]"
220 PRINT"{light gray}{cm t*4}{yellow} n]got s[tt din diskett, det enda"
230 PRINT"{space*5}det g{pound}r [r att leta fram den idkod"
240 PRINT"{space*5}disketten ursprungligen hade.":q=-1
250 GETc$:IFc$=""THEN250
260 IFc$<>CHR$(13)GOTO250
270 OPEN15,8,15
280 PRINT"{clear}"
290 REM s{pound}k
300 FORt=1TO35
310 IFd$=""THENd$=CHR$(0)
320 GOSUB640
330 IFe<>1GOTO470
340 PRINT#15,"m-r"CHR$(22)CHR$(0)
350 GET#15,i$
360 IFi$=""THENi$=CHR$(0)
370 i=ASC(i$)
380 i$=RIGHT$(STR$(i),LEN(STR$(i))-1)
390 PRINT#15,"m-r"CHR$(23)CHR$(0)
400 GET#15,d$
410 d=ASC(d$)
420 d$=RIGHT$(STR$(d),LEN(STR$(d))-1)
430 i$="chr$("+i$+")"
440 d$="chr$("+d$+")"
450 id$=i$+" {green}+{light blue} "+d$
460 GOTO510
470 IFe=3THENid$="?inget synk-m[rke":GOTO510
480 IFe=2THENid$="?header-block finns inte":GOTO510
490 IFe=9THENid$="?checksumfel i header-block":GOTO510
500 id$="?header ej funnen i tid"
510 t$=RIGHT$(STR$(t),LEN(STR$(t))-1)
520 IFt<10THENt$=" "+t$
530 PRINT"{green}sp]r {light blue}"t$" {green}: {light blue}"id$;:IFe=1THENPRINT" {cyan}("q$CHR$(i)CHR$(d)q$")";
540 REM paus
550 GETc$:IFc$=""GOTO570
560 GETc$:IFc$=""THEN560
570 PRINT:NEXTt
580 CLOSE15
590 PRINT"{green}{down}vill du kolla en disk till?"
600 GETa$:IFa$="j"THEN190
610 IFa$<>"n"THEN600
620 END
630 REM jobk{pound}n
640 try=0
650 PRINT#15,"m-w"CHR$(8)CHR$(0)CHR$(2)CHR$(t)CHR$(0)
660 PRINT#15,"m-w"CHR$(1)CHR$(0)CHR$(1)CHR$(176)
670 try=try+1
680 PRINT#15,"m-r"CHR$(1)CHR$(0)
690 GET#15,e$
700 IFe$=""THENe$=CHR$(0)
710 e=ASC(e$)
720 IFtry=500GOTO740
730 IFe>127GOTO670
740 RETURN
stop tok64
(bastext 1.0)