start tok64 d64-f6rmEG
0 REM programl[s v2.0 ( 1992-02-02 )
1 REM 1990:mar04,aug03,04,dec11
2 REM 1991:feb20,apr23,jun07,19,aug11
3 REM      dec04
4 REM 1992:jan29,feb02
7 REM kopiera/sprid/anv[nd fritt
8 REM s[lj/modifiera/{pound}vers[tt inte
9 REM (c)peter karlsson alias mr.p/sw   ----------------------------------------
20 POKE56,64:CLR:POKE53280,6:POKE53281,6:PRINT"{white}{clear}{down}{right}programl[s v2.0{space*2}v[nta{.*3}
30 DIMb$(255),k$(255):FORi=1TO255:b$(i)=CHR$(i):k$(i)=CHR$(i):NEXT
40 FORi=128TO232:READb$(i):NEXT
50 READz,k$:IFz>.THENk$(z)=k$:GOTO50
60 FORi=49152TO49193:READa:POKEi,a:NEXT
70 PRINT"{clear}{down}{right}programl[s v2.0 (c)peter karlsson 1992
71 INPUT"{down}{right*2}programnamn";a$:q=LEN(a$):IFq<1ORq>16THEN71
80 POKE52992,q:FORi=1TOq:POKE52992+i,ASC(MID$(a$,i)):NEXT:PRINT"laddar":SYS49152
100 PRINT"{clear}{down}{right}utmatning till: {reverse on}s{reverse off}k[rm,{reverse on}p{reverse off}rinter el.
101 PRINT"{reverse on}d{reverse off}iskett";:INPUTd$:IFd$="s"THEN109
102 IFd$="p"THENd$="j":OPEN2,4:GOTO108
103 d$="j":u$=LEFT$(a$,14)+".p":PRINT"utmatning till filen "u$
104 dv=8:IFPEEK(49153)<8THENdv=8
105 PRINT"s[tt i r[tt diskett i enhet"dv"{left}.tryck":POKE198,.:WAIT198,1:GETw$
106 OPEN2,8,2,"0:"+u$+",s,w"
108 PRINT"{clear}{light blue}{white}{.*5}{light blue}{reverse on} var god v[nta {reverse off}":CMD2
109 POKE53280,.:POKE53281,.:POKE646,11:PRINT"programnamn: "a$:PRINT
110 ad=16386:sl=PEEK(16384)+PEEK(16385)*256
120 ad=ad+2
130 REM **radnummer********************
140 r=PEEK(ad)+256*PEEK(ad+1):ad=ad+2
150 IFad<=slTHEN190
155 PRINT"sh=shift cm=commodore ct=control
156 PRINT"{space*2}vid dubbla tangenth[nvisningar g[ller ";
157 PRINT"den v[nstra engelskt och h{pound}gra svenskt
158 PRINT"tangentbord.
160 IFd$="j"THENPRINT"listningen [r gjord med programl[s 2.0 (c)peter karlsson 19920202":PRINT#2:CLOSE2
170 POKE198,.:INPUT"{down}{right}fler program? n{left*3}";a$:IFa$="j"THEN70
180 POKE53280,14:POKE53281,6:POKE646,14:PRINT"{clear}";:END
190 r$=RIGHT$("{space*3}"+STR$(r),5):PRINTr$;:IFd$="s"THEN210
200 FORi=1TO5:POKE1023+i,ASC(MID$(r$,i,1)):NEXT
210 x=PEEK(ad):y=PEEK(ad+1):ad=ad+1:s$=b$(x):IFx=34THEN290
230 ON-(x=.)GOTO250:PRINTs$;:GOTO210
250 REM **radslut**********************
260 PRINT:IFd$<>"j"THENPRINT"{light gray}tryck";:POKE198,.:WAIT198,1:PRINT"{left*5}{space*5}{left*5}{dark gray}{up}
270 GOTO120
290 REM **citat-tecken*****************
300 PRINTCHR$(34);
310 x=PEEK(ad):y=PEEK(ad+1):z=PEEK(ad+2):ad=ad+1:s$=k$(x)
320 ON-(x=.)GOTO250:IF(x=yAND(LEN(s$)>1ORx=32))OR(x=yANDx=z)GOTO380
340 IFLEN(s$)>1THENPRINT"<"s$">";:GOTO360
350 PRINTs$;
360 ON2+(x=34)GOTO210,310
380 c=.:IFx>47ANDx<58THEN350
390 c=c+1:y=PEEK(ad+c):IFx=yTHEN390
400 IFx=32THENs$="space"
405 IFLEN(s$)=1THENPRINT"<"MID$(STR$(c+1),2)" "s$">";:ad=ad+c:GOTO360
410 PRINT"<"MID$(STR$(c+1),2)"x("s$")>";:ad=ad+c:GOTO360
420 REM basic-kommandon
430 DATAend,for,next,data,input#,input,dim,read,let,goto,run,if,restore,gosub,return,rem,stop,on,wait,load,save,verify,def,poke,print#,print,cont,list,clr,cmd,sys,open,close,get,new,tab(,to,fn,spc(,then,not,step,+,-,*,/,{^},and,or,>,=,<,sgn,int,abs,usr
460 DATAfre,pos,sqr,rnd,log,exp,cos,sin,tan,atn,peek,len,str$,val,asc,chr$,left$,right$,mid$,go
470 REM kommandon tfc3
471 DATAoff,auto,del,renum,help,find,old,dload,dverify,dsave,append,dappend,dos,kill,mon,pdir,plist,bar,desktop,dump,array,mem,trace,replace,order,pack,unpack,mread,mwrite
480 REM specialtecken
490 DATA5,white,8,ct h,9,ct i,14,ct n,17,down,18,rvs on,19,home,20,delete
500 DATA28,red,29,right,30,green,31,blue,129,orange,133,f1,134,f3,135,f5
510 DATA136,f7,137,f2,138,f4,139,f6,140,f8,142,uppercase,144,black,145,up
520 DATA146,rvs off,147,clear,148,insert,149,brown,150,lt red,151,grey 1
530 DATA152,grey 2,153,lt green,154,lt blue,155,grey 3,156,purple,157,left
540 DATA158,yellow,159,cyan,160,sh space,13,return,141,sh return
550 DATA161,cm k,162,cm i,163,cm t,165,cm g,167,cm m,170,cm m,171,cm q,172,cm d
560 DATA173,cm z,174,cm s,175,cm p,176,cm a,177,cm e,178,cm r,179,cm w,180,cm h
570 DATA181,cm j,182,cm l,183,cm y,184,cm u,185,cm o,187,cm f,188,cm c,189,cm x
580 DATA190,cm v,191,cm b,255,pi,164,cm @
590 DATA193,sh a,194,sh b,195,sh c,196,sh d,197,sh e,198,sh f,199,sh g,200,sh h
600 DATA201,sh i,202,sh j,203,sh k,204,sh l,205,sh m,206,sh n,207,sh o,208,sh p
610 DATA209,sh q,210,sh r,211,sh s,212,sh t,213,sh u,214,sh v,215,sh w,216,sh x
620 DATA217,sh y,218,sh z,186,sh @
630 DATA126,pi,255,pi
640 DATA94,up arrow,95,left arrow,60,less than,62,greater than,64,at
650 DATA1,ct a,2,ct b,3,ct c,4,ct d,6,ct f,7,ct g,10,ct j,11,ct k,12,ct l
660 DATA15,ct o,16,ct p,21,ct u,22,ct v,23,ct w,24,ct x,25,ct y,26,ct z
670 DATA27,"ct :/[",219,"sh +/[",220,"cm -/sh {pound}",221,"sh -/]"
680 DATA223,"cm */-",166,"cm +/]",168,"cm pound/[",169,"sh pound/cm {pound}"
690 DATA192,"sh */-"
998 DATA,
999 REM laddrutin
1000 DATA169
1001 DATA8   :REM  enhetsnummer
1002 DATA170,160,,32,186,255,173,,207,162,1,160,207,32,189,255,169,,162,2,160
1003 DATA64,32,213,255,176,5,32,183,255,208,1,,142,,64,140,1,64,96
stop tok64
(bastext 1.0)