start tok64 d64-QvVLtW
10 REM *** seq writter ***
20 REM *** by ron martin ***
30 REM *** 7/7/84 ***
40 POKE53280,0:POKE53281,6:PRINT"{clear}{light green}"
50 PRINTCHR$(14):GOTO660
60 PRINT"{clear}{white}Write{.*4}":CLR
70 l=1:DIMa$(500),b$(81)
80 a=1:PRINT"{white}Line #"l:PRINT
90 GETy$:IFy$=""THEN90
100 x=ASC(y$)
110 IFx=145ORx=17ORx=157ORx=29THEN90
120 IFx=147ORx=19THEN90
130 IFx=20ANDa>1THENa=a-1:PRINTy$;:GOTO90
140 IFx=20THEN90
150 IFx=13THENPRINT:GOTO190
160 PRINTy$;:b$(a)=y$
170 a=a+1:IFa>80THENPRINTCHR$(20);:a=a-1:GOTO90
180 GOTO90
190 IFb$(1)=""THEN240
200 FORt=1TOa:a$(l)=a$(l)+b$(t):b$(t)="":NEXT
210 l=l+1:GOTO80
220 GETy$:IFy$=""THEN220
230 PRINTASC(y$):GOTO220
240 REM what do you want to do with it
250 PRINT"{clear}{light green}":INPUT"(V)iew, (S)ave or (E)xit";q$
260 q$=LEFT$(q$,1):IFq$<>"v"ANDq$<>"s"ANDq$<>"e"THEN250
270 IFq$="s"THEN550
280 IFq$="e"THENRUN
290 PRINT"{clear}{cyan}View (Press Space Bar to Pause)"
300 FORt=1TOl
310 PRINTa$(t):NEXT
320 GOSUB340
330 GOTO250
340 POKE198,0
350 PRINT:INPUT"{white}Press Return to Continue";q$
360 RETURN
370 REM read file
380 PRINT"{clear}{white}Read File{.*4}"
390 PRINT"Want a Hard Copy (Y) or (N)"
400 POKE198,0:hc=0
410 GETy$:IFy$=""THEN410
420 IFy$="y"ORy$="Y"THENhc=1:OPEN4,4,7:PRINT#4," ";
430 INPUT"Filename";f$:PRINT
440 OPEN15,8,15
450 OPEN2,8,2,"0:"+f$+",s,r"
460 INPUT#15,er,er$
470 IFerTHENGOSUB640:GOTO430
480 GET#2,a$
490 IFst<>0THEN530
500 GETy$:IFy$=" "THENGOSUB350
510 PRINTa$;:IFhc=1THENPRINT#4,a$;
520 GOTO480
530 CLOSE2:CLOSE15:CLOSE4:GOSUB350
540 GOTO660
550 REM out to disk
560 INPUT"Filename > ";f$
570 OPEN15,8,15
580 OPEN2,8,2,"0:"+f$+",s,w"
590 INPUT#15,er,er$
600 IFerTHENGOSUB640:GOTO550
610 FORt=1TOl:PRINT#2,a$(t):NEXT
620 CLOSE2:CLOSE15
630 PRINT"Done":GOTO660
640 PRINT"{clear}{white}{reverse on} Disk Error {reverse off}";er;er$
650 CLOSE15:CLOSE2:RETURN
660 PRINT"{clear}{light green}{space*2}**** Menu *****":CLR
670 PRINT:PRINT"(1) Write Seq. File.":PRINT"(2) Read Seq. File."
680 PRINT"(3) Quit"
690 POKE198,0:PRINT:PRINT"Choice >"
700 GETy$:IFy$=""THEN700
710 x=VAL(y$):IFx<1ORx>3THEN660
720 ONxGOTO60,370,730
730 END
stop tok64
(bastext 1.0)