start tok64 d64-ZFJzDo
10 REM"{141}{ct n}{up}{cm a}{sh asterisk*37}{cm s}
11 REM"{141}{up}{sh -}{space*5}{cm @*27}{space*5}{sh -}
12 REM"{141}{up}{sh -}{space*5}{reverse on}MINI SEQUENTIAL FILE READER{reverse off}{space*5}{sh -}
13 REM"{141}{up}{sh -}{space*37}{sh -}
14 REM"{141}{up}{sh -} (c)1992 Peter Karlsson alias Mr.P.{space*2}{sh -}
15 REM"{141}{up}{sh -} for Softwolves Software and Sys PD{space*2}{sh -}
16 REM"{141}{up}{cm q}{sh asterisk*37}{cm w}
17 REM"{141}{up}{sh -} OK to copy, translate and modify,{space*3}{sh -}
18 REM"{141}{up}{sh -} but not to sell or to erase my name {sh -}
19 REM"{141}{up}{cm z}{sh asterisk*37}{cm x}
20 REM"{delete*7}save"mini seq reader",8
21 REM"{delete*7}{141*3}run
22 POKE53280,14:POKE53281,14
23 PRINT"{white}{ct h}{142}{clear}{down}{cm a}{cm r}{cm s}{cm r}{cm a}{sh asterisk}{cm s}{cm r} {cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s} {cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}I{cm a}{sh asterisk}{cm s}{cm a}{sh asterisk}{cm s}
24 PRINT"{sh -*5} {sh -*2} {sh -}{space*2}{sh -}{space*2}{sh -} {sh -} {sh -} {sh -*2}{space*2}{sh -} {sh -*2} {sh -*2}{space*2}{sh -} {sh -}ver";
25 PRINT"{sh -*5} {sh -*2} {cm z}{sh asterisk}{cm s}{cm q}{sh asterisk}{cm w}{sh -} {sh -} {cm q}{cm r}{cm x}{cm q}{sh asterisk}{cm w}{cm q}{sh asterisk}{cm w}{sh -} {sh -}{cm q}{sh asterisk}{cm w}{cm q}{cm r}{cm x}1.1";
26 PRINT"{sh -} {sh -*3} {sh -*2}{space*3}{sh -*2}{space*2}{sh -}M{sh -} {sh -}{cm z}{cm s}{sh -}{space*2}{sh -} {sh -*2} {sh -*2}{space*2}{sh -}{cm z}{cm s}
27 PRINT"{cm x} {cm z}{cm e}{cm x} {cm z}{cm e} {cm z}{sh asterisk}{cm x}{cm z}{sh asterisk}{cm x}{cm z}{sh asterisk}M {cm e} {cm e}{cm z}{sh asterisk}{cm x}{cm e} {cm e}{cm z}{sh asterisk}K{cm z}{sh asterisk}{cm x}{cm e} {cm e}
28 PRINT"{blue}{sh asterisk*8} improved on 1992-01-10 {sh asterisk*8}
29 PRINT"{white}which seq-file do you want to read?
30 POKE198,.:a$="":INPUT"$=dir @=dos {arrow left}=quit? ${left*3}";a$
31 IFa$="{arrow left}"THENPRINT"{clear}{light blue}";:POKE53281,6:END
32 IFa$="@"THENGOSUB58:GOTO23
33 IFa$="$"THENGOSUB50:GOTO30
34 OPEN15,8,15
35 PRINT"{clear}{ct n}";
36 OPEN8,8,8,"0:"+a$+",s,r"
37 GOSUB48:PRINT:PRINT"{reverse on}SHIFT{reverse off} pauses and {reverse on}Q{reverse off} quits
38 GET#8,b$:IFstTHEN45
39 PRINTb$;:IFPEEK(653)AND3=.THENGOSUB48:GOTO38
40 IFPEEK(653)AND1=1THEN40
41 IFPEEK(197)=62THEN43
42 GOTO38
43 PRINT:PRINT"{reverse on}Reading aborted by user.":CLOSE8:CLOSE15
44 PRINT:PRINT"Press {reverse on}CONTROL{reverse off} to restart":WAIT653,4:RUN23
45 PRINT:PRINT"{reverse on}End of file":CLOSE8:CLOSE15:GOTO44
46 PRINT"{reverse on}Reading aborted due to disk error:
47 PRINT"{reverse on}"CHR$(ASC(em$)+32)MID$(em$,2)".":CLOSE8:CLOSE15:GOTO44
48 INPUT#15,en,em$,et,es:IFen<20THENRETURN
49 GOTO46
50 PRINT"{142}{down}{clear}pause the directory with {reverse on}shift{reverse off}.
51 a$="$0:*=s":IFz=1THENa$="$0":z=.
52 OPEN1,8,0,a$:POKE781,1:SYS65478:GETa$,a$:e$=CHR$(.)
53 GETa$,a$,h$,l$:IFstTHENSYS65484:CLOSE1:RETURN
54 IFPEEK(653)AND1=1THEN54
55 b=ASC(h$+e$)+256*ASC(l$+e$):PRINTTAB(5+(b>9)+(b>99))bTAB(8-(b>9)-(b>99))
56 GETa$,b$:IFa$THENPRINTa$b$;:GOTO56
57 PRINTa$:GOTO53
58 PRINT"{clear}{ct n}{down}Enter DOS command: $ for dir.
59 PRINT"RETURN to quit.
60 a$="":POKE631,34:POKE198,1:INPUTa$
61 IFa$="$"THENz=1:GOSUB50:PRINT"press {reverse on}any key":POKE198,.:WAIT198,1:GOTO58
62 IFa$=""THENRETURN
63 IFLEFT$(a$,1)="n"THEN69
64 IFLEFT$(a$,1)="v"THEN70
65 IFLEFT$(a$,1)="s"THEN71
66 PRINT"Sending:":PRINTa$:OPEN15,8,15,a$
67 INPUT#15,en,em$,et$,es$:PRINTCHR$(34)em$CHR$(34)"{space*2}"et$" "es$
68 CLOSE15:GOTO60
69 g$="format":GOTO72
70 g$="validate":GOTO72
71 g$="scratch
72 PRINT"WARNING: By using the "g$" command
73 PRINT"{space*9}you can lose important datas.
74 PRINT"{space*9}To "g$": press {reverse on} y {reverse off}.
75 GETa$:IFa$=""THEN75
76 IFa$<>"y"THEN60
77 GOTO66
stop tok64
(bastext 1.0)