start tok64 d64-Zdgjf7
0 REM"@0:db print 1.0",8:rem (c)1991 mr.p.
1 GOTO10
2 INPUT#15,z1$,z2$,z3$,z4$:IFVAL(z1$)<20THENRETURN
3 PRINT"diskfel #"z1$" "CHR$(34)z2$CHR$(34):PRINTz3$","z4$
4 CLOSE15:END
10 OPEN15,8,15,"i0:
20 OPEN2,8,2,"0:databudget.fil,s,r":GOSUB2
30 INPUT#2,dd$:GOSUB2:CLOSE2:GOSUB2
40 PRINT"dagens datum: "dd$:d$=dd$
50 INPUT"nytt/return ";dd$:IFd$=dd$THEN80
60 OPEN2,8,2,"@0:databudget.fil,s,w":GOSUB2
70 PRINT#2,dd$:GOSUB2:CLOSE2:GOSUB2:PRINT#15,"i0:":GOSUB2
80 OPEN2,8,2,"0:db print.fil,s,r":GOSUB2
90 INPUT#2,dv,sk:GOSUB2:CLOSE2:GOSUB2
100 POKE53280,.:POKE53281,.
110 PRINT"{gray}{clear}{reverse on}databudget print v1.0 (c)1991 mr.p.{space*4}"
120 PRINT"{down}aktuellt datum: "dd$
130 PRINT"{down}aktuell printer:"dv"sek:"sk
140 PRINT"{down}huvudmeny:
150 PRINT" -1- utskrift 40tkn/rad enkelrad
160 PRINT" -2- utskrift 40tkn/rad dubbelrad
170 PRINT" -3- utskrift 80tkn/rad
180 PRINT" -4- uppdatera printerkonfiguration
190 PRINT" -5- avsluta
200 POKE198,.:WAIT198,1:GETa$:IFa$<"1"ORa$>"5"THEN200
210 IFa$="5"THENCLOSE15:END
220 ONVAL(a$)GOSUB1000,2000,3000,500:GOTO100
500 PRINT"{down}aktuell printerkonfiguration:
510 PRINT"enhets#:"dv
520 PRINT"sek. ad:"sk
530 INPUT"nytt enhets# el return";dv
540 INPUT"ny sek.-adr. el return";sk
550 OPEN2,8,2,"@0:db print.fil,s,w":GOSUB2
560 PRINT#2,MID$(STR$(dv),2)CHR$(13)MID$(STR$(sk),2)CHR$(13):GOSUB2
570 CLOSE2:GOSUB2:RETURN
700 w=SGN(x):x=x*w:x$=MID$(STR$(INT(x)),2):tz$=STR$(x):tq$="
701 IFLEFT$(x$,1)="."THENx$="0"+x$
710 IFx<1e9THENtq$="."+MID$(tz$,LEN(x$)+3):IFtq$="."THENtq$=".00
720 IFx<1e9ANDLEN(tq$)=2THENtq$=tq$+"0
730 IFx=>1e9THENx=INT(x)
740 x$=RIGHT$("{0*12}"+x$+tq$,12):IFx>VAL(x$)THENx$="************
742 IFw=-1THENx$="-"+MID$(x$,2):IFx*w<>VAL(x$)THENx$="-***********
744 RETURN
751 IFLEFT$(x$,1)="."THENx$="0"+x$
800 w=SGN(x):x=x*w:x$=MID$(STR$(INT(x)),2):tz$=STR$(x):tq$="
801 IFLEFT$(x$,1)="."THENx$="0"+x$
810 IFx<1e5THENtq$="."+MID$(tz$,LEN(x$)+3):IFtq$="."THENtq$=".00
820 IFx<1e5ANDLEN(tq$)=2THENtq$=tq$+"0
830 IFx=>1e5THENx=INT(x)
840 x$=RIGHT$("{0*8}"+x$+tq$,8):IFx>VAL(x$)THENx$="********
850 IFw=-1THENx$="-"+MID$(x$,2):IFx*w<>VAL(x$)THENx$="-*******
860 RETURN
900 IFpTHENPRINT#1,s$:PRINTs$:RETURN
910 PRINTs$:RETURN
1000 PRINT"{clear}utskrift 40tkn/rad enkelrad
1010 INPUT"{down}ange kontonummer";nn$
1020 OPEN2,8,2,"0:"+nn$+",s,r":GOSUB2
1030 INPUT#2,kn$,ki$,kf$,ba$,ko$,kt$,z:GOSUB2
1035 PRINT"starta:return{space*2}ingen printerutskrift:@
1036 p=-1:POKE198,.:WAIT198,1:GETa$:IFa$="@"THENp=.:GOTO1050
1040 OPEN1,dv,sk
1050 s$="kontonummer: "+kn$:GOSUB900
1060 s$="innehavare:{space*2}"+ki$:GOSUB900
1070 s$="kontoform:{space*3}"+kf$:GOSUB900
1080 s$="bank:{space*8}"+ba$:GOSUB900
1090 s$="bankkontor:{space*2}"+ko$:GOSUB900
1100 s$="telefon:{space*5}"+kt$:GOSUB900
1110 s$="{-*39}":GOSUB900
1120 s$="datum{space*6}text{space*7}belopp{space*3}saldo":GOSUB900
1130 s$="{-*39}":GOSUB900
1140 s$="{space*31}{0*5}.00":GOSUB900
1150 FORq=1TOz
1160 INPUT#2,sl,t$,tr,y,m,d:GOSUB2
1170 d$=MID$(STR$(10000+y),3)+"-"+MID$(STR$(100+m),3)+"-"+MID$(STR$(100+d),3)
1180 x=tr:GOSUB800:tr$=x$:x=sl:GOSUB800
1190 s$=d$+" "+LEFT$(t$+" {.*9}",10)+" "+tr$+" "+x$:GOSUB900
1200 NEXT
1210 s$="{-*39}":GOSUB900
1220 s$="utskriftsdatum: "+dd$:GOSUB900
1230 s$="{-*39}":GOSUB900
1240 s$="db print (c) 1991: mr.p. and softwolves":GOSUB900
1250 s$="{-*39}":GOSUB900
1260 CLOSE1:CLOSE2
1270 PRINT"{reverse on}tryck":POKE198,.:WAIT198,1:GETa$
1280 RETURN
2000 PRINT"{clear}utskrift 40tkn/rad dubbelrad
2010 INPUT"{down}ange kontonummer";nn$
2020 OPEN2,8,2,"0:"+nn$+",s,r":GOSUB2
2030 INPUT#2,kn$,ki$,kf$,ba$,ko$,kt$,z:GOSUB2
2035 PRINT"starta:return{space*2}ingen printerutskrift:@
2036 p=-1:POKE198,.:WAIT198,1:GETa$:IFa$="@"THENp=.:GOTO2050
2040 OPEN1,dv,sk
2050 s$="kontonummer: "+kn$:GOSUB900
2060 s$="innehavare:{space*2}"+ki$:GOSUB900
2070 s$="kontoform:{space*3}"+kf$:GOSUB900
2080 s$="bank:{space*8}"+ba$:GOSUB900
2090 s$="bankkontor:{space*2}"+ko$:GOSUB900
2100 s$="telefon:{space*5}"+kt$:GOSUB900
2110 s$="{-*39}":GOSUB900
2120 s$="datum{space*6}text{space*7}nummer":GOSUB900
2130 s$="ins[ttning{space*3}uttag{space*8}saldo":GOSUB900
2140 s$="{-*39}":GOSUB900
2150 s$="{space*26}{0*9}.00":GOSUB900
2160 FORq=1TOz
2170 INPUT#2,sl,t$,tr,y,m,d:GOSUB2
2180 d$=MID$(STR$(10000+y),3)+"-"+MID$(STR$(100+m),3)+"-"+MID$(STR$(100+d),3)
2190 x=tr:GOSUB700:tr$=x$:x=sl:GOSUB700
2191 s$=d$+" "+LEFT$(t$+"{space*10}",10)+" ("+MID$(STR$(q),2)+")":GOSUB900
2200 IFtr>.THENs$=tr$+"{space*14}"+x$:GOSUB900:GOTO2210
2201 s$="{space*13}"+tr$+" "+x$:GOSUB900
2210 NEXT
2220 GOTO1210
3000 PRINT"{clear}utskrift 80tkn/rad dubbelrad
3001 ss$="{-*40}
3002 ss$=ss$+"{-*39}
3010 INPUT"{down}ange kontonummer";nn$
3020 OPEN2,8,2,"0:"+nn$+",s,r":GOSUB2
3030 INPUT#2,kn$,ki$,kf$,ba$,ko$,kt$,z:GOSUB2
3040 OPEN1,dv,sk
3050 PRINT#1,"kontonummer: "+kn$
3060 PRINT#1,"innehavare:{space*2}"+ki$
3070 PRINT#1,"kontoform:{space*3}"+kf$
3080 PRINT#1,"bank:{space*8}"+ba$
3090 PRINT#1,"bankkontor:{space*2}"+ko$
3100 PRINT#1,"telefon:{space*5}"+kt$
3110 PRINT#1,ss$
3120 PRINT#1,"datum{space*6}text{space*7}nummer{space*12}";
3130 PRINT#1,"ins[ttning{space*3}uttag{space*9}saldo
3140 PRINT#1,ss$
3145 PRINT#1,"{space*40}";
3150 PRINT#1,"{space*27}{0*9}.00
3160 FORq=1TOz
3170 INPUT#2,sl,t$,tr,y,m,d:GOSUB2
3180 d$=MID$(STR$(10000+y),3)+"-"+MID$(STR$(100+m),3)+"-"+MID$(STR$(100+d),3)
3190 x=tr:GOSUB700:tr$=x$:x=sl:GOSUB700
3191 PRINT#1,d$+" "+LEFT$(t$+"{space*10}",10)+" ("+MID$(STR$(q),2)+")"TAB(40)
3200 IFtr>.THENPRINT#1,tr$+"{space*14}"+x$:GOTO3205
3201 PRINT#1,"{space*13}"+tr$+" "+x$
3210 NEXT
3220 PRINT#1,ss$
3230 PRINT#1,"utskriftsdatum: "+dd$TAB(40)"db print (c) 1991: mr.p. and softwolves
3240 PRINT#1,ss$
3250 GOSUB1260
stop tok64
(bastext 1.0)