start tok64 d64-EjOmk0
1 REM"@0:databudget 1.8",8
2 DIMs(1000),t(1000),t$(1000),y(1000),d(1000),m(1000):GOSUB60000
3 POKE650,128
10 CLOSE15:CLOSE2:OPEN15,8,15:OPEN2,8,2,"0:databudget.fil,s,r":GOSUB9999
20 IFq>1THENGOSUB3300:END
30 INPUT#2,dd$:GOSUB9999:IFq>1THENGOSUB3300:END
40 CLOSE2:CLOSE15
50 PRINT"{clear}datum: "dd$
60 PRINT"mata in nytt. f{pound}r gamla-tryck return.
70 INPUT"nytt";dd$
80 IFLEN(dd$)<>10ORMID$(dd$,5,1)<>"-"ORMID$(dd$,8,1)<>"-"THENPRINT"fel.":GOTO70
100 POKE53280,.:POKE53281,12:PRINT"{gray}";:POKE53281,.
110 PRINT"{clear}{reverse on}databudget 1.8 (c)1989-91 mr.p.{space*8}"
115 PRINT"{home}{down*24}{reverse on}datum: "dd$" {home}
120 GOSUB1000:REMmeny
130 ONaGOSUB3000,4000,5000,6000,7000,8000,9000:REMval
140 GOTO120
1000 PRINT"{home}{down*3}{right*4}O{cm y*19}P
1010 PRINT"{right*4}{cm h}**** huvudmeny ****{cm n}
1020 PRINT"{right*4}{cm h}1.h[mta in konto{space*3}{cm n}
1030 PRINT"{right*4}{cm h}2.spara undan konto{cm n}
1040 PRINT"{right*4}{cm h}3.nya transaktioner{cm n}
1050 PRINT"{right*4}{cm h}4.starta nytt konto{cm n}
1051 PRINT"{right*4}{cm h}5.visa alla trans. {cm n}
1052 PRINT"{right*4}{cm h}6.f{pound}rkorta konto{space*3}{cm n}
1053 PRINT"{right*4}{cm h}7.avsluta{space*10}{cm n}
1060 PRINT"{right*4}L{cm p*19}{sh @}":IFz=.THEN1155
1080 PRINT"{home}{down*13}{right}{cm p*34}
1090 PRINT"{right}{cm h}nuvarande uppgifter:{space*12}{cm n}
1100 PRINT"{right}{cm h}kontonummer:{space*20}{cm n}{left*21}"kn$
1110 PRINT"{right}{cm h}innehavare:{space*21}{cm n}{left*22}"ki$
1120 PRINT"{right}{cm h}kontoform:{space*22}{cm n}{left*23}"kf$
1130 PRINT"{right}{cm h}bank:{space*27}{cm n}{left*28}"ba$
1140 PRINT"{right}{cm h}kontor:{space*25}{cm n}{left*26}"ko$;
1141 PRINT","kt$
1142 PRINT"{right}{cm h}saldo:{space*26}{cm n}{left*27}"s(z)
1150 PRINT"{right}{cm y*2}O{cm y*16}P{cm y*14}
1152 PRINT"{right*3}{cm h}fyllt minne:{space*3}%{cm n}{left*5}";MID$(STR$(1000+INT(z/10)),3)
1153 PRINT"{right*3}L{cm p*16}{sh @}
1155 SYS49408
1160 PRINT"{home}"TAB(33)"O{cm y*4}P"
1170 PRINTTAB(33)"{cm h}v[lj{cm n}":PRINTTAB(33)"L{cm p*4}{sh @}"
1180 GETa$:IFa$<"1"ORa$>"7"THEN1180
1190 a=VAL(a$)
1200 SYS49440
1210 PRINT"{home}{down*3}{right*4}{down}{right}";:FORi=1TOa:PRINT"{down}";:NEXT:PRINT"{light gray}"a$"{gray}
1220 RETURN
3000 SYS49408:PRINT"{home}{down*2}O{cm y*3}namn=kontonummer{cm y*3}P
3010 PRINT"{cm h}namn?{space*17}{cm n}
3020 PRINT"L{cm p*22}{sh @}
3030 INPUT"{home}{down*3}{right}namn";a$:a$=LEFT$(a$,16)
3031 PRINT"{home}{down*4}{right*3}O{cm y*10}P":PRINT"{right*3}{cm h}band/disk?{cm n}":PRINT"{right*3}L{cm p*10}{sh @}
3032 POKE198,.:WAIT198,1:GETq$:IFq$<>"b"ANDq$<>"d"THEN3031
3033 IFq$="d"THEN3140
3040 PRINT"{home}{down*2}O{cm y*22}P
3050 PRINT"{cm h}l[ser data{.*8}{space*4}{cm n}
3060 PRINT"L{cm p*22}{sh @}
3065 PRINT"{cm p*19}
3066 PRINT"{space*18}{cm n}
3067 PRINT"{space*18}{cm n}
3068 PRINT"{cm y*19}{home}{down*4}
3070 OPEN1,1,0,a$
3080 INPUT#1,kn$,ki$,kf$,ba$,ko$,kt$
3090 INPUT#1,z
3100 FORi=1TOz
3110 : INPUT#1,s(i),t$(i),t(i),y(i),m(i),d(i)
3120 NEXT:PRINT"{home}{down*3}{right}{space*18}":SYS49440
3130 CLOSE1:RETURN
3140 PRINT"{home}{down*2}O{cm y*22}P
3150 PRINT"{cm h}stoppa i disk, {reverse on}space{reverse off}{space*2}{cm n}
3160 PRINT"L{cm p*22}{sh @}":POKE198,.:WAIT198,1:POKE198,.
3170 PRINT"{home}{down*2}O{cm y*22}P
3180 PRINT"{cm h}l[ser data{.*8}{space*4}{cm n}
3190 PRINT"L{cm p*22}{sh @}
3200 IFRIGHT$(a$,1)=" "THENa$=LEFT$(a$,LEN(a$)-1):GOTO3200
3210 OPEN15,8,15:OPEN1,8,2,a$+",s,r":GOSUB9999:IFq>.THENCLOSE1:GOTO3300
3220 INPUT#1,kn$,ki$,kf$,ba$,ko$,kt$
3230 INPUT#1,z
3240 FORi=1TOz
3250 : INPUT#1,s(i),t$(i),t(i),y(i),m(i),d(i)
3260 NEXT:PRINT"{home}{down*3}{right}{space*18}":SYS49440
3270 CLOSE1:GOSUB9999:IFa<20THENCLOSE15:RETURN
3300 SYS49440:PRINT"{home}{down*7}"TAB(20)"O{cm y*15}P
3310 PRINTTAB(20)"{cm h}{space*2}diskfel #{space*4}{cm n}{left*5}"MID$(STR$(q),2)
3340 PRINTTAB(20)"{cm h}{space*15}{cm n}{left*16}"LEFT$(q$,15)
3350 PRINTTAB(20)"L{cm p*15}{sh @}
3360 CLOSE15:POKE198,.:WAIT198,1:POKE198,.:RETURN
4000 SYS49408:a$=kn$
4031 PRINT"{home}{down*4}{right*3}O{cm y*10}P":PRINT"{right*3}{cm h}band/disk?{cm n}":PRINT"{right*3}L{cm p*10}{sh @}
4032 POKE198,.:WAIT198,1:GETq$:IFq$<>"b"ANDq$<>"d"THEN4031
4033 IFq$="d"THEN4140
4040 PRINT"{home}{down*2}{cm a}{sh asterisk*22}{cm s}
4050 PRINT"{sh -}skriver data{.*6}{space*4}{sh -}
4060 PRINT"{cm z}{sh asterisk*22}{cm x}
4065 PRINT"{cm a}{sh asterisk*27}{cm s}
4066 PRINT"{sh -}{space*27}{sh -}
4067 PRINT"{sh -}{space*27}{sh -}
4068 PRINT"{cm z}{sh asterisk*27}{cm x}{home}{down*6}{right}";
4070 OPEN1,1,1,a$:PRINT"{home}{down*7}{cm h}ok":b$=CHR$(13)
4080 PRINT#1,kn$b$ki$b$kf$b$ba$b$ko$b$kt$
4090 PRINT#1,z
4100 FORi=1TOz
4110 : PRINT#1,s(i)b$t$(i)b$t(i)b$y(i)b$m(i)b$d(i)
4120 NEXT:PRINT"{home}{down*3}{right}{space*18}"
4130 CLOSE1:SYS49440:RETURN
4140 PRINT"{home}{down*2}O{cm y*22}P
4150 PRINT"{cm h}stoppa i disk, {reverse on}space{reverse off}{space*2}{cm n}
4160 PRINT"L{cm p*22}{sh @}":POKE198,.:WAIT198,1:POKE198,.
4170 PRINT"{home}{down*2}O{cm y*22}P
4180 PRINT"{cm h}skriver data{.*7}{space*3}{cm n}
4190 PRINT"L{cm p*22}{sh @}
4210 OPEN15,8,15:OPEN1,8,2,"@0:"+a$+",s,w":GOSUB9999:IFq>.THENCLOSE1:GOTO3300
4220 b$=CHR$(13):PRINT#1,kn$b$ki$b$kf$b$ba$b$ko$b$kt$
4230 PRINT#1,z
4240 FORi=1TOz
4250 : PRINT#1,s(i)b$t$(i)b$t(i)b$y(i)b$m(i)b$d(i)
4260 NEXT:PRINT"{home}{down*3}{right}{space*18}":SYS49440
4270 CLOSE1:GOSUB9999:CLOSE15:IFa<20THENRETURN
4280 GOTO3300
5000 SYS49408:PRINT"{clear}{down*2}O{cm y*18}P
5010 PRINT"{cm h}saldo:{space*12}{cm n}{left*12}"s(z)
5020 PRINT"L{cm p*18}{sh @}{home}databudget. nya transaktioner.sluta:0
5030 PRINT"{home}{down*7}{right}datum:"TAB(11)"text:"TAB(22)"trans:"TAB(32)"saldo:"
5035 IFz=0THENPRINTTAB(32)"0":GOTO5050
5040 FORi=1TOz:PRINTMID$(STR$(10000+y(i)),3)"-"MID$(STR$(100+m(i)),3)"-";
5045 PRINTMID$(STR$(100+d(i)),3)TAB(11)t$(i)TAB(21)t(i)TAB(31)s(i):NEXT
5050 PRINT"komma mellan ]r,m]n,dat:":z=z+1
5055 IFz>1000THENz=1000:GOTO5140
5060 INPUTy(z),m(z),d(z):IFy(z)=0THENz=z-1:GOTO5130
5062 PRINT"{up*2}text? (max 10 tecken):{space*2}"
5064 INPUT"{space*13}{left*4}";t$(z):t$(z)=LEFT$(t$(z),10)
5070 PRINT"{up*2}ange transaktionens storlek:
5080 INPUT"(naturligtvis i kr){space*3}{left*2}";t(z)
5090 PRINT"{up*2}{space*28}"
5091 PRINT"{space*39}"
5100 s(z)=s(z-1)+t(z)
5105 PRINT"{up*2}"MID$(STR$(10000+y(z)),3)"-"MID$(STR$(100+m(z)),3)"-";
5106 PRINTMID$(STR$(100+d(z)),3)TAB(11)t$(z)TAB(21)t(z)TAB(31)s(z)
5110 IFs(z)<0THENPRINT"*** varning *** {pound}verbelastat konto ***
5115 IFz=1000THEN5140
5120 PRINT"st[mmer det?":POKE198,0:WAIT198,1:GETa$
5122 PRINT"{up}{space*12}{up}":IFa$="n"THENz=z-1
5124 GOTO5050
5130 PRINT"{home}";:SYS49440:RETURN
5140 PRINT"{home}{down}O{cm y*34}P
5150 PRINT"{cm h}minnet slut. jag f{pound}resl]r att du{space*2}{cm n}
5160 PRINT"{cm h}sparar undan kontot och f{pound}rkortar {cm n}
5170 PRINT"{cm h}det. tryck p] return f{pound}r ]terg]ng {cm n}
5180 PRINT"{cm h}till huvudmenyn.{space*18}{cm n}
5190 PRINT"L{cm p*34}{sh @}
5200 GETa$:IFa$<>CHR$(13)THEN5200
5210 SYS49440:RETURN
6000 PRINT"{home}{down}O{cm y*10}P
6010 PRINT"{cm h}nytt konto{cm n}
6020 PRINT"L{cm p*10}{sh @}{cm p*19}
6030 PRINT"{home}{down*4}{cm h}{space*29}{cm n}
6040 PRINT"{cm h}{space*29}{cm n}
6050 PRINT"{cm h}{space*29}{cm n}
6060 PRINT"L{cm p*29}{sh @}
6070 RESTORE:z=.:s(.)=.
6080 READa$:IFa$<>"nykont"THEN6080
6105 READa$,a,x$:IFa$="slut"THENRETURN
6110 PRINT"{home}{down*5}{cm h}mata in{space*22}{cm n}
6120 PRINT"{up}{right*9}";a$":
6130 PRINT"{cm h}?{space*28}{cm n}{up}
6140 PRINT"{right*3}{reverse on}";:FORi=1TOa:PRINT" ";:NEXT:PRINT
6150 PRINT"{up}{right}";:INPUTy$
6160 FORi=aTO1STEP-1:IFMID$(y$,i,1)=" "THENNEXT
6165 y$=LEFT$(y$,i)
6170 IFx$="kn"THENkn$=y$
6180 IFx$="ki"THENki$=y$
6190 IFx$="kf"THENkf$=y$
6200 IFx$="ba"THENba$=y$
6210 IFx$="ko"THENko$=y$
6220 IFx$="kt"THENkt$=y$
6230 GOTO6105
7000 SYS49408:PRINT"{clear} tryck space f{pound}r forts. return stoppar.
7010 PRINT"datum:{space*5}text:{space*6}trans:{space*3}saldo:
7026 IFz=.THENPRINT"{-*10} {-*10} {-*8} {0*5}.00":GOTO7120
7030 FORi=1TOz:PRINTMID$(STR$(1e4+y(i)),3)"-"MID$(STR$(100+m(i)),3)"-";
7040 PRINTMID$(STR$(100+d(i)),3)" "t$(i)TAB(22):t=t(i):GOSUB10000
7045 PRINTt$" ";:t=s(i):GOSUB10000:PRINTt$
7050 IFi<zTHEN7080
7060 PRINT"tryck p] return f{pound}r menyn.
7080 GETa$:IFa$=CHR$(13)THENPRINT"{clear}":SYS49440:RETURN
7100 IFa$<>" "THEN7080
7110 NEXT:PRINT"{clear}":SYS49440:RETURN
7120 PRINT"tryck p] return f{pound}r menyn.
7140 GETa$:IFa$=CHR$(13)THENPRINT"{clear}":SYS49440:RETURN
7150 GOTO7140
8000 PRINT"{home}{down}{right*3}O{cm y*14}P
8010 PRINT"{right*3}{cm h}f{pound}rkorta konto{cm n}
8020 PRINT"{right*3}{cm h}[r du s[ker{?*3}{cm n}
8030 PRINT"{right*3}{cm h}{space*14}{cm n}
8040 PRINT"{right*3}{cm h}{space*14}{cm n}
8045 PRINT"{right*3}{cm h}{space*14}{cm n}
8050 PRINT"{right*3}L{cm p*14}{sh @}
8060 GETa$:IFa$<>"j"ANDa$<>"n"THEN8060
8070 IFa$="n"THENPRINT"{home}{down*4}{right*4}nej{space*11}":RETURN
8080 PRINT"{home}{down*4}{right*4}ja
8090 PRINT"{right*4}f{pound}rkortar{.*5}
8100 PRINT"{right*4}var god v[nta.
8110 y(1)=y(z):m(1)=m(z):d(1)=d(z):s(1)=s(z):t(1)=t(z):t$(1)=t$(z)
8120 FORi=2TOz:y(i)=.:m(i)=.:d(i)=.:s(i)=.:t(i)=.:t$(i)="":NEXT:z=1
8130 RETURN
9000 PRINT"{home}{down*2}{right}O{cm y*33}P
9005 PRINT"{right}{cm h}[r du s[ker p] att du vill sluta?{cm n}
9010 PRINT"{right}{cm h}har du inte sparat undan data sen{cm n}
9015 PRINT"{right}{cm h}senaste inmatning f{pound}rloras dessa!{cm n}
9020 PRINT"{right}L{cm p*33}{sh @}
9030 GETa$:IFa$="j"THENPRINT"{clear}";:CLOSE1:GOTO9060
9040 IFa$="n"THENRETURN
9050 GOTO9030
9060 OPEN15,8,15,"i0":OPEN2,8,2,"@0:databudget.fil,s,w":GOSUB9999:IFq>1THEN3300
9070 PRINT#2,dd$:GOSUB9999:IFq>1THEN3300
9080 CLOSE2:GOSUB9999:IFq>1THEN3300
9090 PRINT"{clear}":CLOSE15:END
9999 INPUT#15,q,q$,qq,qq:RETURN
10000 w=SGN(t):t=t*w:t$=MID$(STR$(INT(t)),2):tz$=STR$(t):tq$="
10010 IFt<1e5THENtq$="."+MID$(tz$,LEN(t$)+3):IFtq$="."THENtq$=".00
10020 IFt<1e5ANDLEN(tq$)=2THENtq$=tq$+"0
10030 t$=RIGHT$("{0*8}"+t$+tq$,8):IFt>VAL(t$)THENt$="{=*8}
10040 IFw=-1THENt$="-"+MID$(t$,2):IFt*w<>VAL(t$)THENt$="-{=*7}
10050 RETURN
60000 ON(PEEK(49408)=162)+1GOSUB60040:IFPEEK(49152)=120THENSYS49152:RETURN
60001 PRINT"{clear}{ct n}{white}PLEASE WAIT. Reading swedish characters."
60002 READy:IFy=>0THENPOKE49152+a,y:s=s-y*(a<178):a=a+1:GOTO60002
60003 IFs-23434THENPRINT"fel i data!":STOP
60004 SYS49152:RETURN
60005 DATA120,169,51,133,1,160,0,185
60006 DATA0,208,153,0,240,200,208,247
60007 DATA238,9,192,238,12,192,208,239
60008 DATA169,208,141,9,192,169,240,141
60009 DATA12,192,169,55,133,1,32,45
60010 DATA192,88,76,68,229,173,2,221
60011 DATA9,3,141,2,221,173,0,221
60012 DATA41,252,141,0,221,169,200,141
60013 DATA136,2,169,45,141,24,208,169
60014 DATA8,133,44,32,139,192,169,89
60015 DATA141,24,3,169,192,141,25,3
60016 DATA96,72,138,72,152,72,169,127
60017 DATA141,13,221,32,188,246,32,225
60018 DATA255,32,163,253,32,24,229,160
60019 DATA3,185,48,253,153,20,3,136
60020 DATA16,247,160,25,185,54,253,153
60021 DATA26,3,136,16,247,32,45,192
60022 DATA108,2,160,160,23,185,178,192
60023 DATA153,216,240,153,216,250,73,255
60024 DATA153,216,244,153,216,254,136,16
60025 DATA236,160,23,185,202,192,153,216
60026 DATA248,73,255,153,216,252,136,16
60027 DATA242,96
60028 DATA102,24,60,102,126,102,102,0
60029 DATA102,60,102,102,102,102,60,0
60030 DATA60,102,60,102,126,102,102,0
60031 DATA102,0,60,6,62,102,62,0
60032 DATA102,0,60,102,102,102,60,0
60033 DATA60,102,60,6,62,102,62,0,-1
60040 READa$:IFa$<>"scopy"THEN60040:DATAscopy
60041 FORi=49408TO49471:READa:POKEi,a:NEXT:RESTORE:a=0:RETURN
60042 DATA162,0,189,0,200,157,0,4,189,0,201,157,0,5,189,0,202,157,0,6,189,0
60043 DATA203,157,0,7,232,224,0,208,227,96
60044 DATA162,0,189,0,4,157,0,200,189,0,5,157,0,201,189,0,6,157,0,202,189,0
60045 DATA7,157,0,203,232,224,0,208,227,96
60100 DATAnykont
60101 DATAkontonummer,20,kn,innehavare,21,ki,kontoform,22,kf,bank(ej kontor),27
60102 DATAba,kontor(ort),15,ko,kontor(tele),10,kt,slut,,
stop tok64
(bastext 1.0)