start tok64 d64-UcPe2S
0 REM {ct n}{ct h}
1 REM {097}uthor: {109}r.{112}.
2 REM {100}ate:   890504
3 REM {110}ame:   '{100}en hemliga skatten'
10 REM initering
20 GOSUB 9100:GOSUB 10000
30 GOSUB 9000
100 REM rumsbeskrivningar
110 GOSUB 8000
200 REM .
400 REM huvudslinga
410 in$="":PRINT:INPUT "{light gray}Och nu";in$
420 IF in$="" THEN PRINT "F'l]t, va' sa' du?":GOTO 400
425 IF in$="spara" OR in$="ladda" THEN 4000
426 IF in$="sluta" THEN END
430 GOSUB 600
440 o1=0:o2=0:GOSUB 800
450 IF o1=-1 OR o2=-1 THEN 400
460 IF o1<7 THEN 1000
470 ON o1-6 GOTO 2100,2300,3400,3500,3200,3600,3700,3800,3100,2700,2000,2600
480 PRINT "?? {cm -*3}{H*3} ??":STOP
490 GOTO 400
600 REM ordsplittringsrutin
610 j=0:FOR i=1 TO at:k=0
620 j=j+1:IF j>LEN(in$) THEN 660
630 IF MID$(in$,j,1)=" "THEN 660
640 IF k=0 THEN k=j
650 GOTO 620
660 IF k=0 THEN 620
670 te$=MID$(in$,k,j-k):in$(i)=LEFT$(te$,ab)
680 IF j>LEN(in$) THEN 700
690 NEXT i:i=i-1
700 ao=i
710 RETURN
800 REM {pound}vers[ttningsrutin
805 IF in$(1)="l[gg" THEN in$(1)="sl[pp"
810 FOR i=1 TO ve
820 IF in$(1)=ve$(i) THEN o1=i:GOTO 840
830 NEXT i:PRINT "Vad menar du med "in$(1)"?":o1=-1
840 IF ao=1 THEN 880
850 FOR i=1 TO su
860 IF in$(2)=su$(i) THEN o2=i:GOTO 880
870 NEXT i:PRINT "Vad betyder "in$(2)"?":o2=-1
880 RETURN
1000 REM f{pound}rflyttningar
1010 n=VAL(MID$(ri$(ar),2*o1-1,2))
1020 IF n=0 THEN PRINT "Du kan inte g] d[r]t!":GOTO 400
1030 IF n>0 THEN 1100
1040 ON n+tr+1 GOTO 1060,1070,1080
1050 PRINT "{?*3}":GOTO 400
1060 PRINT "Du har inga badkl[der, s] hoppa inte i{space*2}och simma nu{.*3}":GOTO 400
1070 PRINT "Du ser en skylt d[r det st]r:{space*11}F{cm -}RBJUDEN G{sh -}NGTRAFIK"
1071 GOTO 400
1080 PRINT "V[gen [r avsp[rrad":GOTO 400
1100 REM kolla "hinder"
1110 IF ar=21ANDn=22ANDf3=0 THENn=23
1120 IF ar=23ANDn=22ANDf3=0 THENn=21
1130 IF ar=4ANDn=5ANDsa(3)<>-1 THEN 1150
1135 IFar=9ANDn=10ANDf2<>1 THEN PRINT"Du ser inget i h]let s] ";:GOTO 1160
1140 ar=n:GOTO 100
1150 ar=n:GOSUB 8000:PRINT"Det [r kallt ute. Du fryser ihj[l.":END
1160 PRINT"du g]r upp.":GOTO 100
2000 REM inventera
2010 IF sh=0 THEN PRINT "Du [r tomh[nt {!*4}":GOTO 400
2020 PRINT "Du knallar omkring med: "
2030 FOR i=1 TO tg
2040 IF sa(i)=-1 THEN PRINT sa$(i)
2050 NEXT i:GOTO 400
2100 REM ta
2105 IF o2=4 AND sa(5)=ar THEN o2=5
2110 IF o2=7 AND sa(7)=ar THEN 3300
2115 IF o2=15 OR o2=16 THEN o1=10:GOTO 470
2120 IF o2=22 THEN PRINT"Du f]r v[l gr[va efter den..":GOTO 400
2130 IF o2=21 THEN PRINT"Vilka pengar?":GOTO 400
2140 IF o2=18 THEN o1=12:GOTO 470
2150 IF o2=11 AND sa(11)=ar THEN PRINT"Mattor [r tunga!":GOTO 400
2170 IF sa(o2)=-1 THEN PRINT"Du b[r p] den redan.":GOTO 400
2180 IF sa(o2)<>ar THEN PRINT"Den finns ej h[r.":GOTO 400
2190 IF o2>tg THEN PRINT"Du kan inte b[ra s]dana saker.":GOTO 400
2200 i=o2:GOSUB 2250
2205 IF i=3 AND f6=1 THEN 2220
2210 GOTO 200
2220 z=INT(RND(1)*9+1):PRINT"Du hittar pengar i ena fickan. Det [r{space*2}"z*10"kr."
2230 f1=f1+z*10:f6=0:GOTO 200
2250 PRINT sa$(i)": ";
2260 IF sh=mh THEN PRINT:PRINT"Du kan inte b[ra mera.":GOTO 2290
2270 sa(i)=-1:sh=sh+1:PRINT"tagen."
2280 IF sa(4)=-1 AND sa(5)=-1 THEN sa(4)=0:sa(5)=0:f3=1:sh=sh-1:sa(8)=-1
2285 IF sa(1)=-1 AND sa(2)=-1 THEN f2=1
2290 RETURN
2300 REM sl[pp
2310 IF o2<>3 OR ar<5 THEN 2370
2320 PRINT"Det ska du v[l inte g{pound}ra{!*3} Det [r ju{space*3}kallt{!*3}":GOTO 200
2370 IF sa(o2)<>-1 THEN PRINT"Den saken b[r du inte p].":GOTO 400
2380 i=o2:GOSUB 2450
2385 IF i=1 AND f2=1 THEN o2=2:f2=0:GOTO 2380
2390 GOTO 200
2450 PRINT sa$(i)": lagd"
2460 sa(i)=ar:sh=sh-1
2470 RETURN
2600 REM anv[nd
2610 IF o2<>1 THEN PRINT"Hur d]?":GOTO 400
2620 IF f2<>1 THEN PRINT"Funkar inte. Har inga batterier.":GOTO 200
2625 IF ar=7 AND sa(4)=-1 OR sa(8)=-1 THEN 2640
2630 IFar=7THENPRINT"Du ser en papperslapp. Du tar upp den.":GOTO2670
2635 IF ar>9 AND ar<14 THEN PRINT"Du anv[nder den redan";:GOTO 200
2640 PRINT"Du ser inget s[rskilt";
2650 IF ar=8 THEN PRINT" f{pound}rutom en sten p]stranden";
2660 PRINT".":GOTO 200
2670 sa(4)=ar:o2=4:GOTO 2100
2700 REM kolla
2710 IF o2<>21 THEN PRINT"Hur d]?":GOTO 400
2720 PRINT"Du r[knar pengarna{.*4}":FORi=1TO1000:NEXTi
2730 PRINT"Du har";f1;"kr.":GOTO200
3100 REM knacka
3110 IF o2<>19 THEN PRINT"Knacka p] vad ?":GOTO 400
3120 IF ar<>12 THEN PRINT"Vilken d{pound}rr ?":GOTO 400
3130 PRINT"Uj uj uj.. Det skulle du inte ha gjort.."
3140 PRINT"Chefen s[tter fast dig f{pound}r industri-"
3150 PRINT"spionage och du f]r sitta i f[ngelse i{space*2}10 ]r{.*5}":END
3200 REM {pound}ppna
3210 IF o2<12 OR o2>14 THEN PRINT"Hur ??":GOTO 400
3220 IF ar<>sa(o2) THEN PRINT"Finns ej h[r{.*3}":GOTO 400
3230 IF o2=14 THEN 3130
3240 IF o2=13 THEN PRINT"Du hittar inget i spisen.":GOTO 200
3250 IF sa(2)=-1 THEN PRINT"Du ser bara mat i kylsk]pet":GOTO 200
3260 PRINT"Du ser ett par batterier."
3270 IF sa(1)<>-1 THEN 200
3280 PRINT"Du tar dem och s[tter dem i ficklampan":i=2:GOSUB2250:GOTO3295
3290 PRINT"VAD NU{sh space}D{sh -}?":STOP
3295 IF sa(2)=-1 THEN f2=1
3296 GOTO 200
3300 REM ta guldmynt
3310 f4=f4+1
3320 IF RND(1)<.3 THEN PRINT"Du fick dem.":GOTO 3340
3330 PRINT"Du n]r dem inte":GOTO 200
3340 z=700-(f4*10):PRINT"De var v[rda";z;"kr":f1=f1+z:sa(7)=0:GOTO 400
3400 REM gr[v
3405 IF sa(6)<>-1 THEN PRINT"Med vad?":GOTO 400
3410 IF o2<>0 THEN PRINT"Det r[cker med:gr[v":GOTO 400
3420 IF ar<>22 THEN PRINT"Gr[va efter vad?":GOTO 400
3430 f5=f5+1
3440 IF RND(1)<.2 THEN 3460
3450 PRINT"Du hittade inte skatten. Otur.":GOTO 200
3460 z=350000-(f5*100):PRINT"Du hittade den och fick";z;"kr."
3470 f1=f1+z:PRINT"GRATTIS. DU FICK";f1;"KR."
3480 END
3500 REM lyft
3505 IF o2=15 AND(ar=14 OR ar=24) THEN 3520
3506 IF sa(5)=ar AND o2=4 THEN o2=5
3510 IF sa(o2)<>ar THEN PRINT"Jag ser den inte.":GOTO 400
3520 IF o2=12 OR o2=13 OR o2=18 THEN PRINT"Det orkar du inte!":GOTO 400
3530 IF o2=14 OR o2=19 THEN PRINT"Den sitter fast.":GOTO 400
3540 IF o2=17 THEN PRINT"Det sitter fast.":GOTO 400
3550 IF o2>20 THEN PRINT"Hur?":GOTO 400
3560 IF o2<11 THEN PRINT"Skriv ta.":GOTO 400
3570 IFo2=15THENPRINT"Det [r en vanlig sten, du l[gger till-":GOTO3595
3580 IFo2=16THENPRINT"Det [r en vanlig badboll,du l[gger till-";:GOTO 3595
3590 o1=7:GOTO 470
3595 PRINT"baka den.":GOTO 400
3600 REM stj[l
3610 IF o2<>18 THEN PRINT"Varf{pound}r det?":GOTO 400
3620 IF sa(o2)<>ar THEN PRINT"Det finns ingen Volvo h[r!!":GOTO 400
3630 PRINT"Oj oj{.*3} {sh +}garen till bilen kommer och du";
3640 PRINT"blir tagen p] bar g[rning och f]r sitta"
3650 PRINT"8 ]r i f[ngelse {!*3}":END
3700 REM f{pound}rst{pound}r
3710 IF o2<>17 AND o2<>18 THEN PRINT"Hur d]?":GOTO 400
3720 IF sa(o2)<>ar THEN PRINT"Det finns inte h[r.":GOTO 400
3730 IF o2=18 THEN 3630
3740 PRINT"Det kommer en vakt fram{.*3} Synd att du"
3750 PRINT"inte s]g honom tidigare{!*3}":END
3800 REM hoppa
3810 IF ar<>17 AND ar<>18 THEN PRINT"Hoppa vart d]?":GOTO 400
3820 PRINT"Arg{h*3}{.*4} Det skulle du inte ha gjort!!";
3830 PRINT"Du sl]r ihj[l dig genom att hoppa ner..":END
4000 PRINT"{clear}SPARA och LADDA."
4010 g=1:IF in$="ladda" THEN g=0
4020 PRINT"Diskett eller kasett (D/K)";:INPUT de$
4030 de=76-ASC(de$):IF de<>1 AND de<>8 THEN 4000
4040 OPEN 1,de,g,"speldata"
4050 IF in$="spara" THEN 4100
4060 INPUT#1,ar,f1,f2,f3,f4,f5,f6,sh
4070 FOR i=1 TO sy:INPUT#1,sa(i):NEXT
4080 CLOSE 1:PRINT"KLAR.":GOTO 100
4100 c$=CHR$(13)
4110 PRINT#1,ar;c$;f1;c$;f2;c$;f3;c$;f4;c$;f5;c$;f6;c$;sh
4120 FOR i=1 TO sy:PRINT#1,sa(i):NEXT
4130 GOTO 4080
8000 REM rumsbeskrivningar
8005 ONarGOSUB8020,8030,8040,8050,8060,8070,8080,8090,8100,8110,8120,8130,8140
8006 IFar>13THENONar-13GOSUB8150,8160,8170,8180,8190,8200,8210,8220,8230,8240
8007 IFar>23THENONar-23GOSUB8250,8260
8010 te=0:FORi=1TOtg
8011 IF sa(i)<>ar THEN 8016
8012 IF te=1 THEN PRINT",";:GOTO 8014
8013 te=1:PRINT "Du ser ";
8014 IF POS(.)+LEN(sa$(i))>36 THEN PRINT
8015 PRINT sa$(i);
8016 NEXT i:IF te=1 THEN PRINT"."
8017 RETURN
8020 PRINT"Du [r i ditt rum. P] golvet ligger en"
8021 PRINT"matta.":RETURN
8030 PRINT"Du [r i sovrummet.":RETURN
8040 PRINT"Du [r i k{pound}ket. H[r finns en spis och ettkylsk]p.":RETURN
8050 PRINT"Du st]r i hallen.":RETURN
8060 PRINT"Du st]r nu i norra delen av er tr[dg]rd.":RETURN
8070 PRINT"Du befinner dig p] en v[g som g]r i{space*5}nord&sydlig riktning.":RETURN
8080 PRINT"Du st]r nu i s{pound}dra delen av tr[dg]rden. H[r [r m{pound}rkt.":RETURN
8090 PRINT"Du st]r p] v[gen.":RETURN
8100 PRINT"Du st]r p] v[gen. Du ser ett h]l i{space*6}marken.":RETURN
8110 PRINT"Du [r nere i h]let. Tur att du har fick-";
8111 PRINT"lampan, f{pound}r det [r m{pound}rkt h[r nere.":RETURN
8120 PRINT"Du befinner dig vid en underjordisk fa-"
8121 PRINT"brik. du ser ett kontor mot {pound}ster och"
8122 PRINT"ett gult sken i s{pound}der.":RETURN
8130 PRINT"Du befinner dig vid ett kontor. Du ser "
8131 PRINT"en gubbe inuti. D{pound}rren [r l]st.":RETURN
8140 PRINT"Du ser en gul,bl[nkande l]da.":RETURN
8150 PRINT"Du [r p] stranden. V[sterut ligger havet";
8151 PRINT"och skogen ligger {pound}sterut. Det ligger{space*3}en sten p] marken.":RETURN
8160 PRINT"Du [r p] stranden.":RETURN
8170 PRINT"Du [r i skogen. Du ser en stor ek fram- f{pound}r dig.":RETURN
8180 PRINT"Du befinner dig nu i tr[dkronan. Du ser"
8181 PRINT"ditt hus i nordv[st.":RETURN
8190 PRINT"P] v[gen ner s] ser du att det [r ett"
8191 PRINT"h]l i tr[det. D[r bor en ekorre.":RETURN
8200 PRINT"Du [r p] stranden. Det ligger en badboll";
8201 PRINT"h[r. Havet syns i nord,syd och v[st":RETURN
8210 PRINT"Du befinner dig vid banken. Den [r"
8211 PRINT"st[ngd och l]st. Det [r ett stort h[ng-"
8212 PRINT"l]s vid porten.":RETURN
8220 PRINT"Du befinner dig i skogen.":RETURN
8230 PRINT"Du ser p] kartan att skatten ska vara{space*3}h[r.":RETURN
8240 PRINT"Du [r i skogen.":RETURN
8250 PRINT"Du [r p] stranden. Du ser en sten.":RETURN
8260 PRINT"Du [r p] en parkering. Det st]r bara en"
8261 PRINT"bil parkerad. Det [r en vit Volvo.":RETURN
9000 REM instruktioner
9010 POKE 53280,0:POKE53281,0:PRINT"{light gray}{clear}{ct n}{ct h}DEN HEMLIGA SKATTEN"
9012 PRINT"{yellow}(c) 1989 Mr.P.{light gray}"
9015 PRINT"{down*2}Hej skattletare!!"
9020 PRINT"{down}Du har f]tt reda p] att en skatt ska "
9030 PRINT"finnas n]gonstans i n[rheten och du ska"
9040 PRINT"leta upp den. G{pound}r dig klar{.*4}{down*2}"
9050 RETURN
9100 REM {pound}vrig initering
9110 ve=18:su=22:ru=25:tg=8:sy=19:at=2:ab=7:mh=5:tr=3
9120 DIM ve$(ve),su$(su),ri$(ru),sa(sy),sa$(tg)
9130 FOR i=1 TO ve:READ ve$(i):NEXT i
9140 FOR i=1 TO su:READ su$(i):NEXT i
9150 FOR i=1 TO ru:READ ri$(i):NEXT i
9160 FOR i=1 TO sy:READ sa (i):NEXT i
9170 FOR i=1 TO tg:READ sa$(i):NEXT i
9180 ar=1:sh=0:f1=0:f2=0:f3=0:f4=0:f5=0:f6=1
9190 RETURN
9230 REM verb
9231 DATA "n","{pound}","s","v","upp","ner","ta","sl[pp","gr[v","lyft","{pound}ppna"
9232 DATA "stj[l","f{pound}rst{pound}r","hoppa","knacka","kolla","invente","anv[nd"
9240 REM substantiv
9241 DATA "ficklam","batteri","ytterkl","lappen","lappen","spaden","guldmyn"
9242 DATA "kartan","",""
9243 DATA "mattan","kylsk]p","spisen","l]dan","stenen","badboll","l]set"
9244 DATA "volvon","d{pound}rren",""
9245 DATA "pengarn","skatten"
9250 REM karta
9251 DATA"{0*3}402{0*6}","0103{0*8}","04{0*5}2{0*4}","{0*3}50301{0*4}"
9252 DATA"{0*3}60704{0*4}","-1{0*3}805{0*4}","0508{0*8}","06091407{0*4}"
9253 DATA"00-2{0*3}80010","0011{0*5}900","0012131{0*5}","{0*6}11{0*4}"
9254 DATA"11{0*10}","081615-3{0*4}","142124-3{0*4}","{0*4}20141700"
9255 DATA"{0*10}18","{0*8}1716","-325-3-3{0*4}","16{0*10}"
9256 DATA"{0*4}2215{0*4}","210023{0*6}","22{0*4}24{0*4}","152325-3{0*4}"
9257 DATA"24{0*4}19{0*4}"
9260 REM sakernas placering
9261 DATA 1,0,4,0,10,15,18,0,0,0
9262 DATA 1,3,3,13,0,19,20,25,12
9270 REM beskrivningar
9271 DATA "en liten ficklampa"
9272 DATA "2 stycken stora batterier"
9273 DATA "dina ytterkl[der"
9274 DATA "en papperslapp"
9275 DATA "en papperslapp"
9276 DATA "en spade"
9277 DATA "n]gra guldmynt"
9278 DATA "en skattkarta"
9999 END
10000 PRINTCHR$(142)"reading swedish characters"
10004 GOTO 10006: av harald fragner 26/10-87
10006 IF PEEK(49152)=120 AND PEEK(49180)=192 AND PEEK(49190)=32 THEN 10020
10008 READy:IF y<0 THEN 10016
10012 POKE49152+a,y:s=s-y*(a<178):a=a+1:GOTO 10008
10016 IF s-23434 THEN PRINT"fel i data!":STOP
10020 SYS 49152:REM aktivera svenska tecken
10024 RETURN
10028 REM **** maskinkod ****
10032 DATA120,169,51,133,1,160,0,185
10036 DATA0,208,153,0,240,200,208,247
10040 DATA238,9,192,238,12,192,208,239
10044 DATA169,208,141,9,192,169,240,141
10048 DATA12,192,169,55,133,1,32,45
10052 DATA192,88,76,68,229,173,2,221
10056 DATA9,3,141,2,221,173,0,221
10060 DATA41,252,141,0,221,169,200,141
10064 DATA136,2,169,45,141,24,208,169
10068 DATA8,133,44,32,139,192,169,89
10072 DATA141,24,3,169,192,141,25,3
10076 DATA96,72,138,72,152,72,169,127
10080 DATA141,13,221,32,188,246,32,225
10084 DATA255,32,163,253,32,24,229,160
10088 DATA3,185,48,253,153,20,3,136
10092 DATA16,247,160,25,185,54,253,153
10096 DATA26,3,136,16,247,32,45,192
10100 DATA108,2,160,160,23,185,178,192
10104 DATA153,216,240,153,216,250,73,255
10108 DATA153,216,244,153,216,254,136,16
10112 DATA236,160,23,185,202,192,153,216
10116 DATA248,73,255,153,216,252,136,16
10120 DATA242,96
10124 REM **** nya tecken ****
10128 DATA 66,24,60,102,126,102,102,0
10132 DATA 66,60,102,102,102,102,60,0
10136 DATA 24,36,60,102,126,102,102,0
10140 DATA 36,0,60,6,62,102,62,0
10144 DATA 36,0,60,102,102,102,60,0
10148 DATA 60,36,60,6,62,102,62,0,-1
10200 REM"<< slut >>
stop tok64
(bastext 1.0)