start tok64 d64-LkeL1u
5 INPUT"rensa sprites? j{left*3}";a$:IFa$="n"THEN15
10 GOSUB700
15 PRINT"{clear}"
20 POKE53280,11:POKE53281,12:POKE53269,0
30 PRINT"{blue}{reverse on} sprite editor {reverse off}
35 INPUT"{black}{down}vilken sprite ska editeras(0-7)? 0{left*3}";n:IFn<0ORn>7THEN35
36 z=15872+(n*64):c=0
40 INPUT"{black}{down}expanderad i x-led (j/n)? n{left*3}";a$:IFa$<>"j"THENPOKE53277,0:GOTO55
50 POKE53277,(2^n)
55 INPUT"{black}{down}expanderad i y-led (j/n)? n{left*3}";a$:IFa$<>"j"THENPOKE53271,0:GOTO61
60 POKE53271,(2^n)
61 INPUT"{black}{down}kopiera existerande data? j{left*3}";k$:IFk$="n"THEN69
65 INPUT"{black}{down}fr]n {green}a{black}nnan eller {green}s{black}amma sprite? s{left*3}";a$
66 IFa$="s"THEN70
67 INPUT"{black}{down}fr]n vilken sprite (0-7)";q:q=15872+(q*64)
68 FORi=0TO63:POKEi+z,PEEK(i+q):NEXT
69 POKE646,PEEK(53287+n):IFk$="n"THENFORi=0TO63:POKEi+z,0:NEXT
70 PRINT"{clear}{black}{down}"TAB(26)"{arrow left}=]ter":PRINTTAB(26)"x=expand x":PRINTTAB(26)"y=expand y
71 PRINTTAB(26)"c=f[rg":PRINTTAB(26)"spc=rita":PRINTTAB(26)"del=sudda dot
72 PRINTTAB(26)"home=sudda{down}{left*5}hela
73 PRINTTAB(26)"n=v[rden"
81 c=PEEK(53287+n)
82 POKE646,c
83 PRINT"{home}U{sh asterisk*24}I
84 FORi=1TO21:PRINT"{sh -}{space*24}{sh -}":NEXT
85 PRINT"J{sh asterisk*24}K{black}
90 GOSUB500:IFk$="j"THENGOSUB600
100 p=1065:s=1065
110 a=PEEK(p):IFa<>32THENk=81:GOTO120
115 k=87
120 POKEp,k:GETt$:IFt$=""THEN120
125 IFt$="{arrow left}"THEN15
126 IFt$="n"THENGOSUB1000:k$="j":GOTO69
130 IFt$="{down}"THENs=p+40
135 IFt$="{up}"THENs=p-40
140 IFt$="{left}"THENs=p-1
145 IFt$="{right}"THENs=p+1
150 IFt$="c"THENGOSUB800
155 IFt$="x"ANDPEEK(53277)=0THENPOKE53277,(2^n):GOTO180
156 IFt$="x"THENPOKE53277,0
157 IFt$="y"ANDPEEK(53271)=0THENPOKE53271,(2^n):GOTO180
158 IFt$="y"THENPOKE53271,0
160 IFt$=" "THENa=42:k=87:GOSUB200
170 IFt$="{home}"THENGOSUB400
175 IFt$=CHR$(20)THENa=32:k=81:GOSUB250
180 IFPEEK(s)=64ORPEEK(s)=93THEN120
185 POKEp,a:p=s
190 GOTO110
200 REM s[tt bit
210 GOSUB300
220 POKE(z+x),PEEK(z+x)OR(2^bi)
230 GOSUB500:RETURN
250 REM rensa bit
260 GOSUB300
270 POKE(z+x),PEEK(z+x)AND(255-(2^bi))
280 GOSUB500:a=32:RETURN
300 REM finn bit
310 li=(INT((p-1065)/40))
320 by=INT((p-(1065+(li*40)))/8)
330 x=((3*li)+by)
340 bi=(7-(p-(1065+40*li+8*by)))
350 RETURN
400 REM rensa
410 FORi=1065TO1865STEP40:FORj=iTOi+23:POKEj,32:NEXTj,i
420 FORi=zTOz+63:POKEi,0:NEXT
430 p=1065:s=1065:RETURN
500 REM visa sprite
510 POKE(2040+n),(248+n)
530 POKE(53248+(2*n)),255:POKE(53249+(2*n)),207
540 POKE53269,(2^n)
550 RETURN
600 REM kopiera
610 FORr=0TO20:FORk=0TO2:sp=z+(r*3)+k:bc=PEEK(sp):IFbc=0THEN670
620 FORby=7TO0STEP-1
630 sc=1065+(r*40)+(k*8)+(7-by)
640 IFbcAND(2^by)THENPOKEsc,42:GOTO660
650 POKEsc,32
660 NEXT
670 NEXT:NEXT
690 RETURN
700 REM rensa sprites
710 FORi=15872TO16384:POKEi,0:NEXT
730 RETURN
800 REM [ndra f[rg
805 PRINT"{down}";
810 INPUT"{up}{black}f[rg (0-15)";c:IFc<0ORc>15THEN810
820 FORi=55296TO56176STEP40:FORj=0TO25:POKE(i+j),c:NEXT:NEXT
830 POKE(53287+n),c
840 PRINT"{up}{space*16}{up}":RETURN
1000 REM v[rden
1010 PRINT"{clear}v[rden f{pound}r din sprite [r:"
1020 FORi=0TO62:PRINTMID$(STR$(PEEK(i+z)),2)",";
1030 IFi=62THENPRINTCHR$(20)
1040 IFPOS(.)>35THENPRINT
1050 NEXT
1060 PRINT"tryck {white}space{black} f{pound}r forts[tta rita"
1070 PRINT"tryck {white}p{black} f{pound}r print"
1080 GETa$:IFa$=" "THENRETURN
1090 IFa$<>"p"THEN1080
1100 OPEN1,4:CMD1,"spritedata:":FORi=0TO63STEP3:FORj=0TO2
1110 a=i+j+z:PRINTMID$(STR$(PEEK(a)),2);
1120 IFa-z<>63THENPRINT",";
1130 NEXT:m=m+1:PRINTTAB(m*10);
1140 IFm=9THENm=0:PRINT
1150 NEXT:PRINT
1160 PRINT"sprite #"MID$(STR$(n),2)
1170 PRINT#1:CLOSE1:RETURN
stop tok64
(bastext 1.0)