start tok64 d64-NP17eY
0 REM"{141}{up}charfile convert v1.02 (c) mr.p.
10 REM konverterar fil fr]n char master
11 REM v 3.10 till v 3.20 / 3.21
19 i=8:o=8
20 POKE53280,6:POKE53281,6:PRINT"{white}{clear} charfile convert v 1.02
21 PRINT"{yellow}{cm y*25}
30 PRINT"{light blue}{cm @*3}{down}{left*3}{reverse on} 1 {reverse off} v 3.10-fil fr]n
31 PRINT"{cm @*3}{down}{left*3}{reverse on} 2 {reverse off} v 3.20/3.21-fil till disk #
32 PRINT"{cm @*3}{down}{left*3}{reverse on} 3 {reverse off} b{pound}rja konvertering
33 PRINT"{cm @*3}{down}{left*3}{reverse on} 4 {reverse off} avsluta
40 PRINT"{home}{down*3}"TAB(20)"disk #"i:IFi=1THENPRINTTAB(20)"{up}band{space*4}"
50 PRINT"{down}"TAB(31)o
90 PRINT"{home}{down*22}{white}(c) {light blue}softwolves software public domain
91 PRINT"{space*4}och mr.p. 1991-08-04
92 PRINT"f{pound}r sys public domain biblioteket{home}
100 GETa$:IFa$<"1"ORa$>"4"THEN100
110 IFa$="2"THENo=o+1+4*(o=11):GOTO20
120 IFa$="3"THENGOSUB1000:GOTO20
130 IFa$="4"THENPOKE53280,14:PRINT"{light blue}{clear}";:END
140 i=i+1:IFi=2THENi=8
150 IFi=12THENi=1
160 GOTO20
1000 PRINT"{white}{clear} konvertering
1010 PRINT"{yellow}{cm y*14}
1020 PRINT"{light blue}filnamn (ladda):";:OPEN1,0:INPUT#1,fl$:CLOSE1
1021 fl$=LEFT$(fl$,12)+".fnt
1030 PRINT:PRINT"{light blue}filnamn (spara):";:OPEN1,0:INPUT#1,fs$:CLOSE1
1031 fs$=LEFT$(fs$+"{space*12}",12)+".cmf
1040 PRINT:IFi=1THENPRINT"{down}stoppa i band i bandspelaren":GOTO1060
1050 PRINT"stoppa i r[tt diskett i enhet"i
1060 PRINT"tryck tangent - {reverse on}stop{reverse off} avslutar":POKE198,.:WAIT198,1:POKE198,.
1070 ad=49152:CLOSE1:IFi=1THENOPEN1,1,.,fl$:GOTO1085
1075 OPEN15,i,15,"i0:
1080 OPEN1,i,2,fl$+",s,r":INPUT#15,a,a$,b,b:IFa=62THENCLOSE1:CLOSE15:RUN
1085 PRINT"{down} {-*3} laddar {-*3}{up}
1090 INPUT#1,a$:IFa$="theend"THEN1130
1100 FORi=1TOLEN(a$)STEP2:l$=MID$(a$,i,1):h$=MID$(a$,i+1,1)
1110 s=ASC(h$)-64+16*(ASC(l$)-64):POKEad,s:ad=ad+1
1120 NEXT:GOTO1090
1130 CLOSE1:CLOSE15
1140 PRINT"stoppa i r[tt diskett i enhet"o
1150 PRINT"tryck tangent - {reverse on}stop{reverse off} avslutar":POKE198,.:WAIT198,1:POKE198,.
1160 OPEN15,o,15,"i0:":OPEN2,o,2,fs$+",p,w
1170 INPUT#15,a,a$,b,b:IFa=63THENPRINTfs$" finns redan!":GOTO1200
1180 IFa=72THENPRINT"disken full":GOTO1200
1190 IFa>19THENPRINT"diskfel:"a;a$
1200 IFa>19THENPOKE198,.:WAIT198,1:CLOSE2:CLOSE15:RUN
1205 PRINT"{down} {-*3} sparar {-*3}
1210 PRINT#2,CHR$(.)CHR$(128);:FORi=49152TO50175:PRINT#2,CHR$(PEEK(i));:NEXT
1220 FORi=49152TO50175:PRINT#2,CHR$(255-PEEK(i));:NEXT:CLOSE2:CLOSE15:RUN
stop tok64
(bastext 1.0)