start tok64 d64-gdUX2n
0 xx$="1.13":yy$="august 8th, 1991"
1 REM"{141}{cm @*17}{141}{reverse on} 64dos (c) mr.p. {reverse off} sys pd 1991{141}
2 d=PEEK(186):IFd<8ORd>15THENd=8
3 OPEN15,d,15:OPEN8,d,8,"setup.dat,s,r":GOSUB9990:IFs=62THEN10
4 INPUT#8,a$,b$,c$,d$:GOSUB9990:CLOSE8:GOSUB9990:CLOSE15
5 GOTO100
10 CLOSE8:CLOSE15
11 PRINT"setup-file does not exist!
12 PRINT"please input settings:
13 INPUT"colors: background? 6{left*3}";bk
14 INPUT"{space*8}border{space*4}? 14{left*4}";bo
15 INPUT"{space*8}character ? 14{left*4}";ch
16 INPUT"device 'a'{space*8}? 8{left*3}";da
17 INPUT"'b'can be the same? 9{left*3}";db
18 INPUT"'c'(hd) 0=not used? 16{left*4}";dc
19 da$="a":db$="a":dc$="a"
20 IFdb=daTHENdb$="b"
21 IFdc=0THENdc$="x"
22 OPEN15,da,15:OPEN8,8,8,"@0:setup.dat,s,w":GOSUB9990:IFs<>0THENCLOSE15:STOP
23 PRINT#8,"a;"da";"da$:GOSUB9990:IFs<>0THENCLOSE15:STOP
24 PRINT#8,"b;"db";"db$:GOSUB9990:IFs<>0THENCLOSE15:STOP
25 PRINT#8,"c;"dc";"dc$:GOSUB9990:IFs<>0THENCLOSE15:STOP
26 PRINT#8,bo";"bk";"ch:GOSUB9990:IFs<>0THENCLOSE15:STOP
27 CLOSE8:GOSUB9990:CLOSE15:RUN
100 m$="syntax error in setup.dat line":IFLEFT$(a$,1)<>"a"THENPRINTm$1:END
101 IFLEFT$(b$,1)<>"b"THENPRINTm$2:END
102 IFLEFT$(c$,1)<>"c"THENPRINTm$3:END
103 da=VAL(MID$(a$,3)):db=VAL(MID$(b$,3)):dc=VAL(MID$(c$,3))
104 q=0:FORi=1TOLEN(a$):IFMID$(a$,i,1)=";"THENq=q+1
105 NEXT:IFq<>2THENPRINTm$1:END
106 da$=RIGHT$(a$,t+1)
107 q=0:FORi=1TOLEN(b$):IFMID$(b$,i,1)=";"THENq=q+1
108 NEXT:IFq<>2THENPRINTm$2:END
109 db$=RIGHT$(b$,t+1)
110 q=0:FORi=1TOLEN(c$):IFMID$(c$,i,1)=";"THENq=q+1
111 NEXT:IFq<>2THENPRINTm$3:END
112 dc$=RIGHT$(c$,t+1)
113 q=0:FORi=1TOLEN(d$):IFMID$(d$,i,1)=";"THENq=q+1:t(q)=i
114 NEXT:IFq<>2THENPRINTm$4:END
115 POKE53280,VAL(d$):POKE53281,VAL(MID$(d$,t(1)+1))
116 POKE646,VAL(MID$(d$,t(2)+1))
200 PRINT"{142}{clear}64dos (c) mr.p. of softwolves
201 u$="a":u=da:PRINT"{down}type 'help' for help{down}
202 PRINT"settings:"
203 PRINT" a: device"da
204 PRINT" b: device"db
205 PRINT" c: ";:IFdcTHENPRINT"device"dc"(hd)":GOTO207
206 PRINT"not used
207 PRINT"{down}";:IFPOS(0)>0THENPRINT
208 PRINTu$">";:OPEN1,0:INPUT#1,a$:CLOSE1:PRINT"{down}":RESTORE:s=0:IFa$="quit"THENSYS64738
209 READb$:IFb$="@"THEN290
210 s=s+1:IFLEFT$(a$,LEN(b$))<>b$THEN209
211 IFRIGHT$(a$,1)="?"THENa$="help "+LEFT$(a$,LEN(a$)-1):s=1
212 ONsGOSUB1000,2000,3000,4000,5000,6000,7000,8000,9000:GOTO207
220 DATAhelp,dir,delete,rename,backup,type,run,disk,settings,@
290 PRINT"syntax error:illegal command":GOTO207
300 PRINT"syntax error:illegal parameters":RETURN
1000 qt$=CHR$(34):IFa$<>"help"THEN1020
1001 PRINT"syntax:{space*2}help (command)":PRINT"{space*6}or <command>?
1002 PRINT"{space*9}dir (wildcard)
1003 PRINT"{space*9}delete <name>
1004 PRINT"{space*9}rename <old name>;<new name>
1005 PRINT"{space*9}backup <name>
1006 PRINT"{space*9}type <name>
1007 PRINT"{space*9}run <name>
1008 PRINT"{space*9}disk <"qt$"a"qt$"/"qt$"b"qt$"/"qt$"c"qt$">
1009 PRINT"{space*9}settings <"qt$"wiew"qt$"/"qt$"change"qt$">
1010 PRINT"{space*9}quit
1011 PRINT"<>=essential parameter ()=not essential
1012 PRINTCHR$(34)CHR$(34)"=parameter as written
1013 RETURN
1020 RESTORE:s=0:a$=MID$(a$,6):IFa$="quit"THEN1050
1021 READb$:IFb$="@"THEN300
1022 s=s+1:IFLEFT$(a$,LEN(b$))<>b$THEN1021
1023 ONsGOSUB1100,1200,1300,1400,1500,1600,1700,1800,1900:RETURN
1050 PRINT"quit
1051 PRINT"resets the computer
1052 RETURN
1100 PRINT"help (command)
1101 PRINT"view command syntax or info on commands
1102 RETURN
1200 PRINT"dir (wildcard)
1201 PRINT"view disk directory
1202 RETURN
1300 PRINT"delete <name>
1301 PRINT"delete the file <name> from disk
1302 RETURN
1400 PRINT"rename <old name>;<new name>
1401 PRINT"renames files
1402 RETURN
1500 PRINT"backup <file>
1501 PRINT"makes a backup copy of <file> on {reverse on}the
1502 PRINT"{reverse on}same{reverse off} disk
1503 RETURN
1600 PRINT"type <file>
1601 PRINT"reads a sequential file from disk
1602 RETURN
1700 PRINT"run <file>
1701 PRINT"loads & runs the file <file>
1702 RETURN
1800 PRINT"disk <"qt$"a"qt$"/"qt$"b"qt$"/"qt$"c"qt$">
1801 PRINT"change disk device
1802 PRINT"n.b if device 'c'(hd) is not used, you
1803 PRINT"will get a syntax error
1804 RETURN
1900 PRINT"settings <"qt$"wiew"qt$"/"qt$"change"qt$">
1901 PRINT"view or change settings
1902 RETURN
2000 w$=":"+MID$(a$,5):PRINT"{space*6}directory of "u$w$:IFw$=":"THENw$=""
2001 t=0:OPEN1,u,0,"$0"+w$:POKE781,1:SYS65478:GETa$,a$:e$=CHR$(0)
2002 GETa$,a$,h$,l$:IFstTHENSYS65484:CLOSE1:RETURN
2003 t=t+1:IFt=1THENPRINT"{space*6}disk name: ";:GOTO2008
2004 PRINT"{space*5}"ASC(h$+e$)+256*ASC(l$+e$);
2006 GETa$,b$:IFa$THENPRINTa$b$;:GOTO2006
2007 PRINTa$:GOTO2002
2008 GETa$:IFa$<>CHR$(34)THEN2008
2009 FORi=1TO16:GETa$:PRINTa$;:NEXT
2010 GETa$,a$:PRINT:PRINT"{space*6}disk id: ";
2011 FORi=1TO5:GETa$:PRINTa$;:NEXT:GETa$:PRINTa$:GOTO2002
3000 a$=MID$(a$,8)
3001 IFLEN(a$)<1ORLEN(a$)>16THEN300
3002 PRINT"the file "CHR$(34)a$CHR$(34)" will be
3003 PRINT"removed. is that ok?
3004 POKE198,.:WAIT198,1:GETz$:IFz$<>"y"THENRETURN
3005 OPEN15,u,15,"s0:"+a$
3006 GOSUB9990:PRINT#15,"i0:
3007 CLOSE15:RETURN
4000 a$=MID$(a$,8)
4001 q=0:FORi=1TOLEN(a$):IFMID$(a$,i,1)=";"THENq=q+1:IFq=1THENw=i
4002 NEXT:IFq<>1THEN300
4003 f1$=LEFT$(a$,w-1):f2$=MID$(a$,w+1)
4004 IFLEN(f1$)<1ORLEN(f1$)>16ORLEN(f2$)<1ORLEN(f2$)>16THEN300
4005 OPEN15,u,15,"r0:"+f2$+"="+f1$
4006 GOSUB9990:PRINT#15,"i0:
4007 CLOSE15:RETURN
5000 a$=MID$(a$,8)
5001 IFLEN(a$)<1ORLEN(a$)>16THEN300
5002 b$=LEFT$(a$,12)+".bak":IFb$=a$THENb$=LEFT$(a$,13)+".bk"
5003 PRINT"are you sure that it is enough space
5004 PRINT"left on disk to make a backup copy?
5005 POKE198,.:WAIT198,1:GETq$:IFq$<>"y"THENRETURN
5006 OPEN15,u,15,"c0:"+b$+"="+a$
5007 GOSUB9990:PRINT#15,"i0:
5008 CLOSE15:RETURN
6000 a$=MID$(a$,6)
6001 IFLEN(a$)<1ORLEN(a$)>16THEN300
6002 OPEN15,u,15,"i0:":OPEN8,u,8,a$+",s,r"
6003 GOSUB9990:IFs>1THENCLOSE8:CLOSE15:RETURN
6005 GET#8,a$:IFstTHENCLOSE8:CLOSE15:RETURN
6006 PRINTa$;:GOTO6005
7000 a$=MID$(a$,5)
7001 IFLEN(a$)<1ORLEN(a$)>16THEN300
7002 PRINT"{clear}{down*2}load"CHR$(34)a$CHR$(34)","u"{home}";
7003 POKE198,4:POKE631,13:POKE632,82:POKE633,213:POKE634,13:END
8000 a$=MID$(a$,6)
8001 IFa$<>"a"ANDa$<>"b"ANDa$<>"c"THEN300
8002 IFa$="c"ANDdc$="x"THEN300
8003 IFu$=a$THENRETURN
8004 u$=a$:IFa$="b"THEN8010
8005 IFa$="c"THEN8020
8006 IFu=daTHENPRINT"insert disk for drive a":POKE198,.:WAIT198,1:POKE198,.
8007 u=da:GOTO8100
8010 IFu=dbTHENPRINT"insert disk for drive b":POKE198,.:WAIT198,1:POKE198,.
8011 u=db:GOTO8100
8020 u=dc:GOTO8100
8100 w$="$0:$":PRINT:GOTO2001
9000 a$=MID$(a$,10)
9001 IFa$="view"THEN9010
9002 IFa$<>"change"THEN300
9003 GOTO12
9010 PRINT"current settings are:
9011 PRINT" a: device"da
9012 PRINT" b: device"db
9013 PRINT" c: ";:IFdcTHENPRINT"device"dc"(hd)":GOTO9015
9014 PRINT"not used
9015 a$="black{space*2}white{space*2}red{space*4}cyan{space*3}purple green{space*2}blue{space*3}yellow "
9016 a$=a$+"orange brown{space*2}lt.red dk.greymd.greyl.greenlt.bluelt.grey
9017 PRINT" {down}background color: "MID$(a$,(PEEK(53280)AND15)*7+1,7)
9018 PRINT" border color{space*4}: "MID$(a$,(PEEK(53281)AND15)*7+1,7)
9019 PRINT" character color : "MID$(a$,(PEEK(646)AND15)*7+1,7)
9020 PRINT"{down}this is 64dos version "xx$:PRINT"(c) "yy$" mr.p.
9021 RETURN
9990 INPUT#15,s,em$,et$,es$:IFs>1THEN9993
9991 IFs=.THENPRINTCHR$(34)em$CHR$(34):RETURN
9992 IFs=1THENPRINTCHR$(34)em$": "et$CHR$(34):RETURN
9993 PRINTMID$(STR$(s+100),3)" "CHR$(34)em$CHR$(34)TAB(25)et$","es$:RETURN
10000 REM"{141}{down*3} save"64dos" ,8{down*2}
stop tok64
(bastext 1.0)