start tok64 d64-BjRMWg
40000 POKE53280,0:POKE53281,0:PRINT"{clear}{142}";
40001 PRINT"{space*40}";
40002 PRINT"{space*40}";
40003 PRINT"{space*40}";
40004 PRINT"{space*40}";
40005 PRINT"{space*40}";
40006 PRINT"{space*40}";
40007 PRINT"{space*7}{reverse on}{yellow}{space*13}{cm m}{green}{space*2}{yellow}{cm h}{cm n}{cyan}{space*7}{reverse off}{space*8}";
40008 PRINT"{space*7}{reverse on}{yellow}{space*2}{reverse off}{space*6}{reverse on}{green}{cm y*2}{reverse off}{space*4}{reverse on}{space*2}{reverse off}{space*2}{reverse on}{cyan}{space*2}{reverse off}{space*13}";
40009 PRINT"{space*7}{reverse on}{yellow}{space*2}{reverse off}{space*6}{reverse on}{green}{space*2}{reverse off}{space*4}{reverse on}{space*2}{reverse off}{space*2}{reverse on}{cyan}{space*2}{reverse off}{space*13}";
40010 PRINT"{space*7}{reverse on}{yellow}{space*7}{reverse off} {reverse on}{green}{space*8}{reverse off}{space*2}{reverse on}{cyan}{space*7}{reverse off}{space*8}";
40011 PRINT"{space*12}{reverse on}{yellow}{space*2}{reverse off}{space*4}{reverse on}{green}{space*2}{reverse off}{space*10}{reverse on}{cyan}{space*2}{reverse off}{space*8}";
40012 PRINT"{space*12}{reverse on}{yellow}{space*2}{reverse off}{space*4}{reverse on}{green}{space*2}{reverse off}{space*10}{reverse on}{cyan}{space*2}{reverse off}{space*8}";
40013 PRINT"{space*5}{reverse on}{yellow}{space*9}{cyan}{cm h}{space*2}{cm n}{green}{space*2}{cyan}{cm h}{space*11}{reverse off}{space*8}";
40014 PRINT"{space*7}{orange}{cm i}{space*3}{cm f} {cm f*2}{space*3}{cm i}{space*8}{cm f}{space*12}";
40015 PRINT"{space*7}{reverse on}{cm c}{reverse off}{cm v}{cm f*2}{reverse on}{cm c}{reverse off} {cm k}{cm f}{cm d}{cm f} {cm k*2}{cm d} {cm i}{cm d} {cm d}{cm f*2}{cm i}{space*11}";
40016 PRINT"{space*7}{cm k} {cm b}{cm k}{reverse on}{cm c}{reverse off}{cm v}{cm k*2}{cm b}{cm f} {reverse on}{cm c}{reverse off}{cm v}{cm b}{cm v}{cm k*3}{cm b}{cm k*4}{space*10}";
40017 PRINT"{space*5}{blue}{cm y*27}{space*8}";
40018 PRINT"{space*40}";
40019 PRINT" {white}sys pd biblioteket{space*21}";
40020 PRINT" peter karlsson{space*25}";
40021 PRINT" v[rnsta ullers[ter{space*21}";
40022 PRINT"s710 40 fr{pound}vi{space*27}";
40023 PRINT" sweden{space*33}";
40024 PRINT"{space*40}";
40025 PRINT"{gray}erase lines: 4{0*4}-40027 for this scree{home}";
40026 POKE2023,14:POKE56295,12
40027 POKE198,.:WAIT198,1
50000 POKE53280,12:POKE53281,15:PRINT"{142}{clear}";
50010 PRINT"{reverse on}{gray}{space*20}{reverse off} {white}:this screen is:{space*3}";
50020 PRINT"{reverse on}{gray}{space*20}{reverse off} {white}:converted using:{space*2}";
50030 PRINT"{reverse on}{gray}{space*20}{reverse off} {white}:the screen:{space*7}";
50040 PRINT"{space*21}:converter:{space*8}";
50050 PRINT"{reverse on}{yellow} {cm d}{cm i*10}{cm f}{space*20}{reverse off}{cm k}{black}{cm d}{reverse on}{cm i*2}{reverse off}{cm b}{space*2}";
50060 PRINT"{reverse on}{yellow} {reverse off}{cm k}{reverse on}{black}the screen{yellow}{cm k}{dark gray}{space*20}{reverse off}{yellow}{cm k}{reverse on}{black}{cm k*2}{sh asterisk}{cm k}{reverse off}{space*2}";
50070 PRINT"{reverse on}{yellow}{space*2}{reverse off}{black}{cm d}{cm i*4}{cm f}{reverse on}{yellow}{space*5}{dark gray} softwolves 1990 !! {reverse off}{yellow}{cm k}{black}{cm c}{cm i*2}{reverse on}{cm b}{reverse off}{space*2}";
50080 PRINT"{reverse on}{yellow}{space*2}{black}{cm k}{cm d}{cm i*3}{reverse off}{cm v}{reverse on}{yellow}{space*5}{dark gray}{space*20}{reverse off}{yellow}{cm k}{space*6}";
50090 PRINT"{reverse on}{space*2}{black}{cm k}{reverse off}{cm k}{reverse on}{yellow}{space*19}{cm i*2}{space*8}{reverse off}{cm k}{black}1990{space*2}";
50100 PRINT"{reverse on}{yellow}{space*2}{black}{cm k}{reverse off}{cm k}{reverse on}{yellow}{space*3}{cm d}{cm i*15}{black}{cm k}{reverse off}{cm k}{reverse on}{yellow}{cm f}{cm i*6} {reverse off}{cm k}{space*6}";
50110 PRINT"{reverse on}{space*2}{black}{cm k}{reverse off}{cm k}{reverse on}{yellow}{cm i*3}{reverse off}{cm v}{reverse on}{black} {cm f}{reverse off}{cm k}{reverse on}{cm c} {reverse off}{cm f}{reverse on} {cm k}{reverse off}{cm k}{reverse on}{cm v}{cm d}{reverse off}{cm k}{reverse on}{cm c}{cm f}{reverse off}{cm k}{reverse on}{cm f}{cm d}{reverse off} {reverse on}{cm v}{cm d}{reverse off}{cm k}{reverse on}{cm c}{cm f}{reverse off}{cm k}{reverse on}{yellow} {reverse off}{cm k}{black}mr.p. ";
50120 PRINT"{reverse on}{yellow}{space*2}{black}{cm k}{space*4}{reverse off}{cm k}{reverse on}{space*2}{reverse off}{cm k}{reverse on} {cm k}{reverse off}{cm k}{reverse on}{cm f} {reverse off}{cm v}{reverse on}{cm f}{reverse off}{cm i}{cm f}{reverse on} {reverse off}{yellow}{cm d}{cm i}{black}{cm c}{reverse on} {reverse off}{cm k}{reverse on}{cm f}{reverse off}{cm i}{cm f}{reverse on} {reverse off}{yellow}{cm d}{cm i}{reverse on} {reverse off}{cm k}{space*6}";
50130 PRINT"{reverse on}{space*2}{reverse off}{cm i*14}{reverse on}{cm v}{reverse off}{cm i*4}{reverse on}{cm v} {cm c}{reverse off}{cm i*6}{reverse on}{space*3}{reverse off}{cm k}{space*6}";
50140 PRINT"{reverse on}{space*33}{reverse off}{cm k}{space*6}";
50150 PRINT"{space*40}";
50160 PRINT"{black}instructions:{space*27}";
50170 PRINT"create your screen. type run6{0*4} and{space*3}";
50180 PRINT"press return. follow the instructions{space*3}";
50190 PRINT"on screen, and your screen will be print";
50200 PRINT"statements. to erase this screen- erase ";
50210 PRINT"the lines between 5{0*4} and 50250.{space*6}";
50220 PRINT"{space*40}";
50230 PRINT"{reverse on}{gray}{space*40}";
50235 PRINT"{space*40}";
50240 PRINT"{space*39}{home}";
50250 POKE2023,160:POKE56295,252:GOTO50250
60000 DATA162,,189,,4,157,,196,189,,5,157,,197,189,,6,157,,198,189,,7,157,,199
60005 DATA232,208,229,96 , 162,,189,,216,157,,200,189,,217,157,,201,189,,218
60010 FORi=49152TO49181:READa:POKEi,a:s=s+a:NEXT:IFs<>3123THENPRINT" error in data1":END
60015 SYS49152:DATA157,,202,189,,219,157,,203,232,208,229,96
60020 FORi=49152TO49181:READa:POKEi,a:s=s+a:NEXT:IFs<>7110THENPRINT" error in data2":END
60025 SYS49152:PRINT"{clear}{down*2}{ct h}":s=PEEK(53272):POKE53272,21
60030 INPUT" starting line #? ";sl
60035 IFsl=>50001ORsl<.THENPRINT" illegal line# (0-5{0*4}!)":GOTO60030
60040 INPUT" line# step?{space*6}";ls
60045 IFls<>1ANDls<>5ANDls<>10THENPRINT" illegal line# step (1/5/10!)":GOTO60040
60050 bc$=STR$(PEEK(53281)AND15):bo$=STR$(PEEK(53280)AND15):x$=CHR$(34):PRINT"{clear}{down*2}"sl;
60055 PRINT"poke53280,"MID$(bo$,2)":poke53281,";:s$="{142}":IFs=23THENs$="{ct n}"
60060 PRINTMID$(bc$,2)":?"x$"{clear}"s$x$";":PRINT"60070sl="sl+ls":ls="ls":rw=.:cl=-1
60065 PRINT"run60070{home}";:POKE198,3:POKE631,13:POKE632,13:POKE633,13:END
60075 a$=MID$(STR$(sl),2)+"?"+CHR$(34):cl$="{black}{white}{red}{cyan}{156}{green}{blue}{yellow}{orange}{brown}{pink}{dark gray}{gray}{light green}{light blue}{light gray}
60080 sc=50176+rw*40:cs=51200+rw*40:IFrw=24THEN60160
60085 FORx=.TO39
60090 s=PEEK(sc+x):c=PEEK(cs+x)AND15
60095 IFs>127ANDrv=.THENrv=1:a$=a$+"{reverse on}
60100 IFs<128ANDrv=1THENrv=.:a$=a$+"{reverse off}
60105 s=sAND127
60110 IFc<>clANDNOT(s=32ANDrv=.)THENcl=c:a$=a$+MID$(cl$,c+1,1)
60115 IFLEN(a$)>76ANDLEN(a$)<80THENsl=sl+ls:a$=a$+CHR$(34)+";"+CHR$(13)+STR$(sl)+"?"+CHR$(34)
60120 t=s:IFs<32THENt=t+64:GOTO60140
60125 IFs<64THENt=t-5*(t=34):GOTO60140
60130 IFs<96THENt=t+32:GOTO60140
60135 t=t+64
60140 a$=a$+CHR$(t):NEXTx
60145 PRINT"{clear}{down*2}"a$CHR$(34)";
60150 PRINT"60070sl="sl+ls":ls="ls":rw="rw+1":cl="cl":rv="rv
60155 PRINT"run60070{home}";:POKE198,5:FORi=.TO4:POKE631+i,13:NEXT:END
60160 FORx=.TO38
60165 s=PEEK(sc+x):c=PEEK(cs+x)AND15
60170 IFs>127ANDrv=.THENrv=1:a$=a$+"{reverse on}
60175 IFs<128ANDrv=1THENrv=.:a$=a$+"{reverse off}
60180 s=sAND127
60185 IFc<>clTHENcl=c:a$=a$+MID$(cl$,c+1,1)
60190 IFLEN(a$)>76ANDLEN(a$)<80THENsl=sl+ls:a$=a$+";"+CHR$(13)+STR$(sl)+"?"+CHR$(34)
60195 t=s:IFs<32THENt=t+64:GOTO60215
60200 IFs<64THEN60215
60205 IFs<96THENt=t+32:GOTO60215
60210 t=t+64
60215 a$=a$+CHR$(t):NEXTx
60220 PRINT"{clear}{down*2}"a$"{home}"CHR$(34)";
60225 PRINTsl+ls"pO2023,"MID$(STR$(PEEK(51175)),2)":pO56295,"MID$(STR$(PEEK(52199)),2)
60230 PRINT"run60235{home}";:POKE198,5:FORi=.TO4:POKE631+i,13:NEXT:END
60235 PRINT"{clear}{down*2}{right}your screen is now converted into basic
60240 PRINT" please choose :{down}
60245 PRINT" {reverse on}1{reverse off} exit to basic with converter intact{down}
60250 PRINT" {reverse on}2{reverse off} erase converter and exit to basic
60255 FORi=.TO250:NEXT:PRINT"{home}{down*4}{right*17}*";:GETa$:IFa$<>""THEN60270
60260 FORi=.TO250:NEXT:PRINT"{home}{down*4}{right*17}{reverse on}*{reverse off}";:GETa$:IFa$<>""THEN60270
60265 GOTO60255
60270 PRINTCHR$(20)a$:IFa$="1"THENPRINT"{clear}{down*2}{right}the converter is intact in memory!":END
60275 IFa$<>"2"THENbc=PEEK(53280):POKE53280,bc-1:POKE53280,bc:GOTO60235
60280 PRINT"{clear}{down*2}{right}are you really sure you want to destroy{down}{right}the converter ? ";
60285 PRINT"*{left}";:GETa$:IFa$=""THENFORi=.TO250:NEXT:PRINT"{reverse on}*{reverse off}{left}";:FORi=.TO250:NEXT:GOTO60285
60290 PRINT"{clear}{down}{right*6}okay. destroying the converter.{home}{down*2}";:dl=60000
60295 FORi=.TO40STEP5:PRINTdl+i:NEXT:PRINT"dl="dl+45":?"CHR$(34)"{clear}{down*2}"CHR$(34)";:gO60295{home}";
60300 POKE198,10:FORi=.TO9:POKE631+i,13:NEXT:PRINT"{home}";:END
stop tok64
(bastext 1.0)