start tok64 d64-KGG6eh
0 REM //basic dis-ass//
1 POKE53280,14:POKE53281,6
10 DIMa$(255):PRINT"{light blue}{clear}{-*3}:getting datas.
11 FORi=.TO255:a$(i)="{?*3}e":NEXT
20 READx$:PRINT"{home}"x$:IFx$=""THEN200
30 READc$:FORi=1TO13:IFLEFT$(c$,2)="--"THEN60
40 PRINT"{home}{down}"LEFT$(c$,2):h=ASC(c$)-48:l=ASC(MID$(c$,2))-48
50 b=(h+7*(h>9))*16+(l+7*(l>9)):a$(b)=x$+CHR$(64+i)
60 c$=MID$(c$,3):NEXT:GOTO20
100 DATAadc,696d65----6171757d79------
101 DATAand,292d25----2131353d39------
102 DATAasl,--0e060a------161e--------
103 DATAbcc,--------------------90----
104 DATAbcs,--------------------b0----
105 DATAbeq,--------------------f0----
106 DATAbit,--2c24--------------------
107 DATAbmi,--------------------30----
108 DATAbne,--------------------d0----
109 DATAbpl,--------------------10----
110 DATAbrk,--------00----------------
111 DATAbvc,--------------------50----
112 DATAbvs,--------------------70----
113 DATAclc,--------18----------------
114 DATAcld,--------d8----------------
115 DATAcli,--------58----------------
116 DATAclv,--------b8----------------
117 DATAcmp,c9cdc5----c1d1d5ddd9------
118 DATAcpx,e0ece4--------------------
119 DATAcpy,c0ccc4--------------------
120 DATAdec,--cec6--------d6de--------
121 DATAdex,--------ca----------------
122 DATAdey,--------88----------------
123 DATAeor,494d45----4151555d59------
124 DATAinc,--eee6--------f6fe--------
125 DATAinx,--------e8----------------
126 DATAiny,--------c8----------------
127 DATAjmp,--4c------------------6c--
128 DATAjsr,--20----------------------
129 DATAlda,a9ada5----a1b1b5bdb9------
130 DATAldx,a2aea6------------be----b6
131 DATAldy,a0aca4--------b4bc--------
132 DATAlsr,--4e464a------565e--------
133 DATAnop,--------ea----------------
134 DATAora,090d05----0111151d19------
135 DATApha,--------48----------------
136 DATAphp,--------08----------------
137 DATApla,--------68----------------
138 DATAplp,--------28----------------
139 DATArol,--2e262a------363e--------
140 DATArti,--------40----------------
141 DATArts,--------60----------------
142 DATAsbc,e9ede5----e1f1fdf9--------
143 DATAsec,--------38----------------
144 DATAsed,--------f8----------------
145 DATAsei,--------78----------------
146 DATAsta,--8d85----8191959d99------
147 DATAstx,--8e86------------------96
148 DATAsty,--8c84--------94----------
149 DATAtax,--------aa----------------
150 DATAtay,--------a8----------------
151 DATAtsx,--------ba----------------
152 DATAtxa,--------8a----------------
153 DATAtxs,--------9a----------------
154 DATAtya,--------98----------------
155 DATA
200 POKE53280,.:POKE53281,.
210 INPUT"{green}{clear}disassemble from (hex) ";ad$
211 PRINT"{clear}{light blue} hex{space*4}{cyan}dec{space*2}{light gray}byte {dark gray}mnemonic{space*5}{156}length
212 a$=LEFT$(ad$,2):d$=RIGHT$(ad$,2)
213 h=ASC(a$)-48:l=ASC(MID$(a$,2))-48:ad=(h+7*(h>9))*16+(l+7*(l>9))
214 h=ASC(d$)-48:l=ASC(MID$(d$,2))-48:ad=ad*256+(h+7*(h>9))*16+(l+7*(l>9))
220 IFad<>INT(ad)ORad<.ORad>65535THEN210
230 h$="0123456789abcdef
240 a1=INT(ad/4096):x=ad-a1*4096:a2=INT(x/256):x=x-a2*256:a3=INT(x/16)
250 a4=x-a3*16
260 ad$=MID$(h$,a1+1,1)+MID$(h$,a2+1,1)+MID$(h$,a3+1,1)+MID$(h$,a4+1,1)
270 PRINT"{light blue}$"ad$" {cyan}#"MID$(STR$(100000+ad),3)": {light gray}";
280 IFad<65534THENm1=PEEK(ad):m2=PEEK(ad+1):m3=PEEK(ad+2):GOTO290
281 IFad=65534THENm1=PEEK(ad):m2=PEEK(ad+1):m3=PEEK(.):GOTO290
282 m1=PEEK(ad):m2=PEEK(.):m3=PEEK(1)
290 m1$=MID$(h$,INT(m1/16)+1,1)+MID$(h$,(m1AND15)+1,1)
300 m2$=MID$(h$,INT(m2/16)+1,1)+MID$(h$,(m2AND15)+1,1)
310 m3$=MID$(h$,INT(m3/16)+1,1)+MID$(h$,(m3AND15)+1,1)
320 PRINTm1$" {dark gray}"LEFT$(a$(m1),3)" ";
330 ONASC(RIGHT$(a$(m1),1))-64GOTO340,350,360,370,380,390,400,410,420,430,440
331 ONASC(RIGHT$(a$(m1),1))-74GOTO450,460
340 PRINT"#$"m2$;:x=2:GOTO470
350 PRINT"$"m3$m2$;:x=3:GOTO470
360 PRINT"$"m2$;:x=2:GOTO470
370 PRINT"a";:x=1:GOTO470
380 x=1:GOTO470
390 PRINT"($"m2$",x)";:x=2:GOTO470
400 PRINT"($"m2$"),y";:x=2:GOTO470
410 PRINT"$"m2$",x";:x=2:GOTO470
420 PRINT"$"m3$m2$",x";:x=3:GOTO470
430 PRINT"$"m3$m2$",y";:x=3:GOTO470
440 IFm2>128THENm2=m2-256
441 m4=ad+m2+2
442 a1=INT(m4/4096):x=m4-a1*4096:a2=INT(x/256):x=x-a2*256:a3=INT(x/16)
443 a4=x-a3*16
444 m4$=MID$(h$,a1+1,1)+MID$(h$,a2+1,1)+MID$(h$,a3+1,1)+MID$(h$,a4+1,1)
445 PRINT"$"m4$" r"m2$;:x=2:GOTO470
450 PRINT"($"m3$m2$")";:x=3:GOTO470
460 PRINT"$"m2$",y";:x=2
470 PRINTTAB(30)"{156}"x"byte";:IFx>1THENPRINT"s";
475 PRINT:ad=ad+x:GOSUB500:IFm1=76THENGOSUB540
476 IFm1=64ORm1=96THENGOSUB580
477 PRINT"{space*39}{up}"
480 IFx>65535THENx=x-65536:GOTO240
490 GOTO240
500 IFPEEK(198)=.THENRETURN
510 POKE198,.:PRINT"{white}{reverse on}press a key{reverse off}{space*2}{green}q {156}quit{space*2}{green}a {156}new address{up}":WAIT198,1:GETa$
511 IFa$="a"THEN200
520 IFa$<>"q"THENRETURN
530 END
540 POKE198,.:PRINT"{green}continue disass at $"m3$m2$"? {156}y/n?{up}
550 WAIT198,1:GETa$:IFa$<>"y"ANDa$<>"n"THEN550
560 IFa$="y"THENad=m3*256+m2
570 RETURN
580 POKE198,.:PRINT"{green}continue disass after rts/rti? {156}y/n?{up}
590 WAIT198,1:GETa$:IFa$="y"THENRETURN
600 IFa$<>"n"THEN590
stop tok64
(bastext 1.0)