start tok64 d64-OIC0jP
0 REM********************************
1 REM****by daniel lundin 25.2.86****
2 REM********************************
100 REM********set up screen***********
101 POKE808,251:POKE774,226:POKE775,252
102 PRINT"{clear}":POKE53281,0:POKE53280,0
103 POKE53272,(PEEK(53272)AND240)OR14:POKE53270,PEEK(53270)OR16
104 POKE53283,1:POKE53282,5
105 DIMs$(10,12)
106 REM***********variables*************
107 FORi=1TO6:READo$(i),o(i):NEXT
108 FORi=1TO10:FORt=1TO11:READs$(i,t):NEXTt,i
109 m$(1)="{white}LN{down}{left*2}MO":m$(2)="{white}LN{down}{left*2}MP":u$="{home}{down*24}"
110 r$="{pink}>{sh asterisk}{down}{left*2}?A{up}"
111 w$="{pink}FF{down}{left*2}FF{up}"
112 g$="{pink}GG{down}{left*2}GG{up}"
113 d$="{pink}BD{down}{left*2}CE{up}"
114 GOTO324
115 POKE53282,5:GOSUB228
116 m$(1)="{white}LN{down}{left*2}MO":m$(2)="{white}LN{down}{left*2}MP":u$="{home}{down*24}"
117 r$="{pink}>{sh asterisk}{down}{left*2}?A{up}"
118 w$="{pink}FF{down}{left*2}FF{up}"
119 g$="{pink}GG{down}{left*2}GG{up}"
120 d$="{pink}BD{down}{left*2}CE{up}"
121 x=2:y=2:d=0
122 PRINTLEFT$(u$,y)SPC(x);m$(1)
123 FORi=54272TO54296:POKEi,0:NEXT
124 SYSmu
125 POKE54278,128:POKE54277,9:POKE54276,17
126 POKE53265,PEEK(53265)OR16
127 REM************move man************
128 SYS5e4:SYS5e4
129 a=PEEK(1024+x+y*40-80):IFa=63ANDm=2THEN153
130 pe=PEEK(56321):p=0
131 IFpe=251THENp=-2:GOTO141
132 IFpe=247THENp=2:GOTO141
133 IFpe=254THENp=-80:GOTO141
134 IFpe=253THENp=80:GOTO141
135 IFpe=95THEN156
136 IFpe=127THEN243
137 IFpe=75THEN250
138 IFpe=187THEN179
139 IFpe=207THENSTOP
140 IFp=0THEN149
141 a=PEEK(1024+x+y*40+p):IFa=32ORa=71ORa=67THEN143
142 GOTO149
143 PRINTLEFT$(u$,y)SPC(x)"{pink}{space*2}{down}{left*2}{space*2}":m=0:r=1
144 IFp=2ORp=-2THENx=x+p
145 IFp=80THENy=y+2
146 IFp=-80THENy=y-2
147 IFy<2THENy=2
148 IFa=67THENd=d+1:GOSUB162:IFd=16THENle=le+1:sc=sc+400:lo=lo+1:GOTO170
149 PRINTLEFT$(u$,y)SPC(x);m$(r):m=m+1
150 IFr=1ANDm>8THENr=2:GOTO152
151 r=1
152 GOTO127
153 REM*************dead man***********
154 PRINTLEFT$(u$,y)SPC(x)"{pink}{space*2}{down}{left*2}{space*2}":SYS5e4:SYS5e4:SYS49901
155 POKE54278,128:POKE54277,9:POKE54276,17
156 SYS49901
157 POKE54296,15:POKE54276,17:FORi=0TO255STEP20:POKE54273,i:NEXT
158 FORi=255TO0STEP-15:POKE54273,i:NEXT
159 POKE54276,0
160 li=li-1:IFli<=0THEN215:REM**title**
161 GOTO115
162 REM********sound for diamond*******
163 POKE54278,128:POKE54277,9:POKE54276,17
164 PRINTLEFT$(u$,y)SPC(x);m$(1)
165 POKE54276,17:POKE54296,15:FORi=230TO90STEP-35:POKE54273,i:NEXT:POKE54276,0
166 sc=sc+275:POKE54273,0
167 a$=MID$(STR$(sc),2,LEN(STR$(sc))):sc$=LEFT$("{0*6}",6-LEN(a$))+a$
168 PRINT"{home}{white}"SPC(19);sc$
169 RETURN
170 REM***********new level************
171 SYS49901
172 POKE54276,17:FORi=0TO51STEP.2:POKE53282,i*5:POKE54273,i:NEXT:POKE54276,0
173 IFlo=3THEN175
174 GOTO115
175 PRINT"{clear}{down*8}{156}{right*8}you have made three levels!"
176 PRINT"{down*2}{green}{right*10}you get a bonus life!"
177 FORi=1TO2000:NEXT
178 li=li+1:lo=0:GOTO174
179 REM**********title page************
180 PRINT"{clear}{pink}"
181 PRINT">{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}{space*4}>{sh asterisk}"
182 PRINT"?A?A?A{space*2}?A?A?A{space*2}?A?A?A{space*2}?A{space*4}?A"
183 PRINT">{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*6}>{sh asterisk}{space*2}>{sh asterisk}"
184 PRINT"?A{space*2}?A{space*2}?A{space*2}?A{space*2}?A{space*6}?A{space*2}?A"
185 PRINT">{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*6}>{sh asterisk}>{sh asterisk}{space*2}"
186 PRINT"?A?A?A{space*2}?A{space*2}?A{space*2}?A{space*6}?A?A{space*2}"
187 PRINT">{sh asterisk}>{sh asterisk}{space*4}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*6}>{sh asterisk}{space*2}>{sh asterisk}"
188 PRINT"?A?A{space*4}?A{space*2}?A{space*2}?A{space*6}?A{space*2}?A"
189 PRINT">{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}{space*4}>{sh asterisk}"
190 PRINT"?A{space*2}?A{space*2}?A?A?A{space*2}?A?A?A{space*2}?A{space*4}?A"
191 PRINT"{pink}{space*33}"
192 PRINT"{pink}{space*33}"
193 PRINT"{space*6}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}{space*6}>{sh asterisk}{space*3}"
194 PRINT"{space*6}?A?A?A{space*2}?A?A?A{space*2}?A{space*6}?A{space*3}"
195 PRINT"{space*6}>{sh asterisk}{space*6}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*6}>{sh asterisk}{space*3}"
196 PRINT"{space*6}?A{space*6}?A{space*2}?A{space*2}?A{space*6}?A{space*3}"
197 PRINT"{space*6}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}{space*6}>{sh asterisk}{space*3}"
198 PRINT"{space*6}?A?A?A{space*2}?A?A?A{space*2}?A{space*6}?A{space*3}"
199 PRINT"{space*6}>{sh asterisk}{space*6}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}{space*6}>{sh asterisk}{space*3}"
200 PRINT"{space*6}?A{space*6}?A{space*2}?A{space*2}?A{space*6}?A{space*3}""
201 PRINT"{space*6}>{sh asterisk}{space*6}>{sh asterisk}{space*2}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}{space*2}>{sh asterisk}>{sh asterisk}>{sh asterisk}"
202 PRINT"{space*6}?A{space*6}?A{space*2}?A{space*2}?A?A?A{space*2}?A?A?A"
203 PRINT"{black}{a*40}{home}":an$="yes":SYS49901
204 SYS49547
205 FORi=0TO500
206 PRINT"{home}{down*24}{white}{space*15}instructions "an$;
207 q=PEEK(56321):IFq=239THEN212
208 IFq=251THENan$="yes":i=1
209 IFq=247THENan$="no ":i=1
210 NEXT
211 SYS49901:SYS49547:GOTO304
212 FORi=0TO25:SYS5e4:FORt=0TO20:NEXT:NEXT
213 IFan$="yes"THEN252
214 GOTO270
215 REM********game over*************
216 SYS49901
217 PRINT"{home}{down*10}{right*14}{black}{reverse on}{space*11}{reverse off}"
218 PRINT"{home}{down*11}{right*14}{black}{reverse on} {reverse off}{cyan}game over{black}{reverse on} "
219 PRINT"{home}{down*12}{right*14}{black}{reverse on}{space*11}{reverse off}"
220 POKE54296,15:POKE54277,68:POKE54278,68:POKE54276,129
221 POKE54273,1:POKE54272,90
222 FORi=1TO20
223 PRINT"{home}{down*11}{right*14}{black}{reverse on} {reverse off}{cyan}{space*9}{black}{reverse on} "
224 FORc=1TO100:NEXT
225 PRINT"{home}{down*11}{right*14}{black}{reverse on} {reverse off}{cyan}game over{black}{reverse on} "
226 FORc=1TO100:NEXT:NEXT:POKE54296,0
227 GOSUB281:GOTO179
228 REM*********draw screen***********
229 IFle=11THENle=1:sc=sc+600
230 PRINT"{clear}";
231 PRINT:FORi=1TO11:PRINT"{down}":FORt=1TO19
232 a$=MID$(s$(le,i),t,1)
233 IFa$="r"THENPRINTr$;
234 IFa$="w"THENPRINTw$;
235 IFa$="g"THENPRINTg$;
236 IFa$="d"THENPRINTd$;
237 NEXTt,i
238 PRINT:PRINT"{down}{F*38}"
239 PRINT"{F*38}{home}";
240 a$=MID$(STR$(sc),2,LEN(STR$(sc))):sc$=LEFT$("{0*6}",6-LEN(a$))+a$
241 PRINT"{home}{green}"SPC(13)"{white}score ";sc$;TAB(32)"men";li;"{home} sheet";le
242 RETURN
243 q=PEEK(56321)
244 PRINT"{home}{cyan}{space*7}pause mode - press button{space*7}"
245 IFq=239THEN247
246 GOTO243
247 PRINT"{home}{cyan}{space*39}"
248 PRINT"{home}{green}"SPC(13)"{white}score ";sc$;TAB(32)"men";li;"{home} sheet";le
249 GOTO130
250 li=li+1:IFli>10THENli=1
251 PRINT"{home}"TAB(35)li"{left} ":GOTO130
252 PRINT"{clear}{156}";
253 PRINT"{space*4}you shall guide rockie "m$(1)
254 PRINT"{156}{down}{space*4}around the caves"
255 PRINT"{down*2}{cyan}{space*4}looking for the diamonds "d$
256 PRINT"{down*2}{yellow}{space*4}but look up for the rocks "r$
257 PRINT"{down*3}{green}{space*4}hitting{red} run/stop {green}pauses game"
258 PRINT"{down}{green}{space*4}pressing {red}button {green}starts game again"
259 PRINT"{down}{green}{space*4}pressing {red}c= {green}and {red}run/stop {green}will kill"
260 PRINT"{down}{space*4}you if you are stuck somewhere"
261 PRINT"{down}{green}{space*4}pressing{red} ctrl{green} and{red} q {green}quits game "
262 PRINT"{down}{blue}{space*11}press space"
263 POKE198,0
264 GETq$:IFq$=" "THEN270
265 FORx=1TO300:NEXT
266 PRINT"{home}{right*26} "m$(2)
267 FORx=1TO300:NEXT
268 PRINT"{home}{right*26} "m$(1)
269 GOTO264
270 PRINT"{clear}{down*8}":li=3:le=1:sc=0:sc$="{0*6}":b$="on ":mu=49547
271 PRINT"{cyan}{space*7}use joystick to select "
272 PRINT"{cyan}{down*3}{space*5}press button when finished"
273 PRINT"{home}{cyan}{down*11}{space*10}starting level{156}"le
274 PRINT"{home}{cyan}{down*15}{space*3}{right*3}{space*6}sound{space*2}{156}"b$
275 q=PEEK(56321):IFq=254THENle=le+1:IFle>9THENle=1
276 IFq=253THENle=le-1:IFle<1THENle=9
277 IFq=251THENb$="on ":mu=49547
278 IFq=247THENb$="off":mu=49901
279 IFq=239THENlo=0:SYS49901:GOTO115
280 GOTO273
281 PRINT"{clear}":SYS49547
282 PRINT"{cyan}{space*10}enter your initials.{down*2}":FORt=1TO11:GETa$:NEXT
283 PRINT"{space*16}{yellow}{.*6}{left*6}";:q=0:h$=""
284 GETa$:IFa$=""THEN284
285 IFa$=CHR$(20)THENIFq>0THENq=q-1:PRINT"{left}.{left}";:h$=h$+"{left} {left}"
286 IFa$=CHR$(13)THEN292
287 IFa$=CHR$(34)THEN284
288 IFa$=CHR$(63)ORa$=CHR$(62)THEN284
289 IFa$<CHR$(32)ORa$>CHR$(90)THEN284
290 IFq<6THENh$=h$+a$:q=q+1:PRINTa$;
291 GOTO284
292 FORt=6TO1STEP-1
293 IFsc<=o(t)THEN o(t+1)=sc:o$(t+1)=h$:GOTO296
294 o(t+1)=o(t):o$(t+1)=o$(t)
295 NEXT
296 IFsc>o(1)THENo(1)=sc:o$(1)=h$
297 PRINT"{clear}"
298 PRINT"{space*9}{156}rock fall hiscore list{down*3}"
299 FORt=1TO6:PRINTTAB(11);"{yellow}";o(t);TAB(23);"{cyan}";o$(t);"{down*2}"
300 NEXT:PRINT"{cyan}{right}{space*10}{right}last score:{yellow}";sc:PRINT"{home}";
301 FORi=1TO1000
302 IFPEEK(56321)=239THENi=1000:RETURN
303 NEXT:RETURN
304 FORle=1TO9
305 PRINT"{clear}";
306 PRINT:FORi=1TO11:PRINT"{down}":FORt=1TO19
307 a$=MID$(s$(le,i),t,1)
308 IFa$="r"THENPRINTr$;
309 IFa$="w"THENPRINTw$;
310 IFa$="g"THENPRINTg$;
311 IFa$="d"THENPRINTd$;
312 IFPEEK(56321)=239THENi=11:t=19:le=9:SYS49901:GOTO179
313 NEXTt,i
314 PRINT:PRINT"{down}{F*38}"
315 PRINT"{F*38}{home}";
316 a$=MID$(STR$(sc),2,LEN(STR$(sc))):sc$=LEFT$("{0*6}",6-LEN(a$))+a$
317 PRINT"{home}{green}{space*9}preview{space*2}of{space*2}sheet ";le
318 PRINTLEFT$(u$,2)SPC(2);m$(1)
319 FORi=1TO200:IFPEEK(56321)=239THENle=9:i=3000:SYS49901:GOTO179
320 NEXT
321 IFle=3ORle=6ORle=9THENSYS49547
322 NEXT
323 GOSUB297:GOTO179
324 REM*******
325 SYS49901
326 FORi=54272TO54296:POKEi,0:NEXT
327 PRINT"{clear}{down*6}{white}{right*14}daniel lundin"
328 PRINT"{down*2}{space*13}p r e s e n t s "
329 PRINT"{down*2}{white}{space*17}for you"
330 POKE54296,15:POKE54277,129:POKE54278,129:POKE54276,17
331 FORco=2TO7
332 FORl=55656+13TO55656+29STEP2
333 POKEl,co
334 FORi=0TO255STEP20:POKE54273,i:NEXT:FORi1=1TO10:NEXT
335 NEXT:NEXT:POKE54296,0
336 FORi=1TO500:NEXT
337 GOTO179
338 REM*******data for screens*******
339 DATA"a",7,"b",6,"c",5,"d",4,"e",3,"f",2
340 DATAwgggggggggggggggggw,wgggwrrrrgrrrrwgggw
341 DATAwggggwgggggggwrgggw,wwggggwgggggwgrgggw,wgggggwgggggwgrgggw
342 DATAwggrgrgwdddwggrgggw,wggdgrgdwwwdggrgrgw,wrgggrgwdddwggrgdgw
343 DATAwgrgggwgrdrgwgggggw,wggdgwgrrrrrgwggrgw
344 DATAwgrgggdggddggrggdgw
345 DATAwgggrgrggggrgggggrw,wgggggggrggrggrrggw,wgggggrwwwwddwwwwdw
346 DATAwggdgwdwrggggrgrwgw,wdgggwgwdgrgrggdwgw,wggggwgwdwwggwwdwgw
347 DATAwrrrgwgwgwrggrwgwrw,wrdrgwgwgwggggwgwgw,wrrrgwdwgwgddrwrwgw
348 DATAwgdgggrggwgwwgwgggw,wggggggggggdggggrgw
349 DATAwggggrrrrgrrdrggrdw
350 DATAwggggdrdrgrrggggrrw
351 DATAwrgwwwwwgwwwwwwgggw
352 DATAwrgwdrggggggrdwgggw
353 DATAwrgwrgggggggrrwggdw
354 DATAwdgwgggggggggrwgggw
355 DATAwggwgrgggggggdwgdgw
356 DATAwgrwggggggggggwrddw
357 DATAwgrwgggrdrgggggdgrw
358 DATAwggwggrrdrrggrwrggw
359 DATAwggggrrrrrrrrrwrgdw
360 :
361 DATAwggrrggggggggggggrw
362 DATAwggrggwwwwwwwwwwggw
363 DATAwgggrwdrgrrrrggdwdw
364 DATAwrwgwrgrggrrgrrrgww
365 DATAwdwgdggdggddgrdggww
366 DATAwrwgwgggggrrgdgggww
367 DATAwrgggwgdgrrrrgggwdw
368 DATAwggrggwwwwwwwwwwrrw
369 DATAwggrggggggdgrgggrgw
370 DATAwggggggggggddgggggw
371 DATAwgggggggggggggggdgw
372 :
373 DATAwgggggggrrggggggggw
374 DATAwgggrgggggdrggrggrw
375 DATAwgggrwwwwwwwwwrgrrw
376 DATAwgggrgggrrdgrgdggdw
377 DATAwggrggdgggdrggdrggw
378 DATAwggrwwwwwwwwwwwrggw
379 DATAwggggggrdddrgggrggw
380 DATAwggdggggrrrggggdggw
381 DATAwgrwwwwwwwwwwwwwrgw
382 DATAwgrgrgggrrggggggdgw
383 DATAwgdggwwwgdgwwwggdgw
384 :
385 DATAwggrrdwgggwwwgggrrw
386 DATAwggrrrwggwwgwrggrrw
387 DATAwggrrrwgwwdddrggggw
388 DATAwggrggwgwgdgdgggggw
389 DATAwgggrrwwwwwwwwwwggw
390 DATAwggggddddgggdddgggw
391 DATAwggggrwwwwwwwwwwggw
392 DATAwggrgrwrggggggrgrgw
393 DATAwrrdgrwgrggggrrgrgw
394 DATAwrdrgrwdrrrrrrggrgw
395 DATAwrrggrwgggggggggggw
396 :
397 DATAwggggggrggggrgggggw
398 DATAwgggggggrdrggrgggrw
399 DATAwgggrwwwwwwwwwgggrw
400 DATAwrrgrwrrggrrdwgggrw
401 DATAwdrgrwddggrrrwgggdw
402 DATAwwrgrwgggggggwggggw
403 DATAwdrgdwgwwwwwgwggrgw
404 DATAwdrgdggwwwwwgdgrrgw
405 DATAwdgwdwwwwwwwwwrwrgw
406 DATAwrggggrrwwwgrgrgdgw
407 DATAwggggggggdgggrgggdw
408 :
409 DATAwggggggggrggggggrdw
410 DATAwggggrrrrdrgggggrrw
411 DATAwgggrdgrrrrrgggggrw
412 DATAwgrgrrrrgrgrrrrgrrw
413 DATAwrdgggdgggggdggggrw
414 DATAwrgwwwwwwgwwwwwwggw
415 DATAwrrwggggggggrrdwrdw
416 DATAwrdgrgggggggrrrrddw
417 DATAwwwrrgwwwgggrrrrwww
418 DATAwdgrggwdgggggggggrw
419 DATAwgggggwdwggggdgggdw
420 :
421 DATAwggggrgrgrddrggrrrw
422 DATAwgggggrdgggrgggddgw
423 DATAwgwwwwwwwwwwwwwgwgw
424 DATAwgwrrrrgdrrwdrggwgw
425 DATAwgwddrgrgrrgrrgrwgw
426 DATAwgwggggggrrggggrwgw
427 DATAwgwgrrgggrrggggrwgw
428 DATAwgwgdrrdgrrgrrwgwgw
429 DATAwgwdrrrrwrrwdrddwgw
430 DATAwgwwwwwwwdgwwgwwwgw
431 DATAwgggggggggggggggggw
432 :
433 DATAwggggggggdrgggggrdw
434 DATAwggggggggwwgggggrrw
435 DATAwrrgggggwrgwggggggw
436 DATAwdrggggwgrgrwgggggw
437 DATAwrrgggwgrdgdrwrgggw
438 DATAwggrgwgggdggggrgrgw
439 DATAwrgrggwrgrrrrwrrdrw
440 DATAwggrgggwddddwdrrrrw
441 DATAwgwdggggwrrwggrrdrw
442 DATAwdgrgggggwwggggggdw
443 DATAwgwggrggggggggggggw
444 REM********************
stop tok64
(bastext 1.0)