start tok64 d64-8CZmvZ
0 REM"{delete*6}save "@0:tt/file maker",8{141*5}
1 REM tt/file maker
2 REM copyright 1988, m. h. westerweel
3 REM haaksbergen, the netherlands
5 :
9 POKE53280,11:POKE53281,.:PRINT"{light gray}
10 sq$="{home}{down*24}":y=1:l=1:DIMt%(1600),l$(40):POKE53272,23
15 h$="{clear}{down} {reverse on}Return{reverse off}:New line, {reverse on}Del{reverse off}:Delete, {reverse on}F2{reverse off}:Save {home}{down*3}":PRINTh$"{right*2}{reverse on} {reverse off}
20 et$=LEFT$(sq$,24)+" {reverse on} * {.*10}End of text{.*11} * "
25 GETgt$:IFgt$=""THEN25
30 gt=ASC(gt$):IFgt>31THENIFgt<94THENIFgt<>61THEN75
35 IFgt>192THENIFgt<219THEN75
40 IFgt<>13THEN55
45 GOSUB195:IFl=21THENy=1:l2=1:PRINTh$"{right*2}{reverse on} {reverse off}"et$
50 IFl=41THENl=40:GOTO130
55 IFgt=20THENGOSUB105:GOTO25
60 IFgt=137THEN130
65 IFgt=34THENgt=39
70 GOTO25
75 IFgt=34THENgt$=CHR$(34)+CHR$(34)+"{left} {left}
80 ln=LEN(l$(l)):IFln<36THEN95
85 GOSUB195:IFl=21THENy=1:l2=1:PRINTh$"{right*2}{reverse on} {reverse off}"et$
90 IFl=41THENl=40:GOTO130
95 l$(l)=l$(l)+CHR$(gt):ln=LEN(l$(l)):PRINTLEFT$(sq$,y+3)TAB(ln+1)gt$"{reverse on} "
100 GOTO25
105 nl=.:IFln<1THENl=l-1:y=y-1:nl=1:ln=LEN(l$(l)):IFl<1THENl=1:y=1:GOTO120
110 IFl=20THENIFl2=1THENy=20:PRINTh$;:FORz=1TO20:PRINT"{right*2}"l$(z):NEXT:l2=.
115 IFln>.THENl$(l)=LEFT$(l$(l),ln-1):ln=LEN(l$(l))
120 IFnl=1THENPRINTLEFT$(sq$,y+4)TAB(2)"{reverse off} "
125 PRINTLEFT$(sq$,y+3)TAB(ln+2)"{reverse on} {reverse off} ":RETURN
130 IFl$(l)=""THENl=l-1
135 INPUT"{clear}{down} file name{.*3}";f$:ff=LEN(f$):IFff<1ORff>16THEN135
140 OPEN8,8,8,"0:"+f$+",s,w
145 lb=l/5:la=INT(lb):IFla=lbTHENt%(1)=la:t%(2)=5:GOTO155
150 lc=l-(5*la):t%(1)=la+1:t%(2)=lc
155 PRINT#8,t%(1):PRINT#8,t%(2):tt=2:FORld=1TOl:le$=l$(ld):le=LEN(le$):tt=tt+1
160 t%(tt)=le:PRINT#8,t%(tt):FORlf=1TOle:tt=tt+1:t%(tt)=ASC(MID$(le$,lf,1))
165 PRINT#8,t%(tt):NEXT:NEXT:tt=tt+1:t%(tt)=999:PRINT#8,t%(tt):CLOSE8:yn=1
170 IFff>13THENf$=LEFT$(f$,13):ff=13
175 yn$="":INPUT"{clear}{down} make a copy{.*3}";yn$:IFyn$<>"y"THENIFyn$<>"n"THEN175
180 IFyn$="n"THENEND
185 yn=yn+1:PRINT"{clear}{down} copying{.*3}":f$=LEFT$(f$,ff)+STR$(yn)
190 OPEN8,8,8,"0:"+f$+",s,w":FORtf=1TOtt:PRINT#8,t%(tf):NEXT:CLOSE8:GOTO175
195 ll$=l$(l):ll=LEN(ll$):IFll=.THEN210
200 IFRIGHT$(ll$,1)=" "THENl$(l)=LEFT$(ll$,ll-1):GOTO195
205 PRINTLEFT$(sq$,y+3)TAB(ln+2)"{reverse off} "LEFT$(sq$,y+4)TAB(2)"{reverse on} ":l=l+1:y=y+1:ln=.
210 IFll=.THENPRINTLEFT$(sq$,y+3)TAB(ln+2)"{reverse off} "LEFT$(sq$,y+3)TAB(2)"{reverse on} "
215 RETURN
stop tok64
(bastext 1.0)