start tok64 d64-YpIVGe
0 IFPEEK(53088)<>120THENGOSUB210: REM 850411
1 SYS53088:IFl=0THENGOSUB182:GOSUB2:GOTO4
2 PRINTm$(0):GOSUB3:FORi=1TO8:PRINT,"{reverse on}{space*4}"m$(i);:FORh=1TO(13-LEN(m$(i))):PRINT"{reverse on} ";:NEXT:PRINT:PRINT:NEXT
3 PRINT"{home}",mr$:PRINTl$;:PRINTn$:PRINT,,,"{up}"d$:RETURN
4 a=0:GETa$:IFa$<>""THENa=ASC(a$)-132:IFa$="f"THEN203
5 IFa>0ANDa<8THENONaGOTO20,30,40,70,85,90,109
6 GOTO4
7 POKEl+4,34:POKEl+4,33:RETURN
8 OPEN9,0:INPUT#9,i$:CLOSE9:PRINT:RETURN
9 GOSUB7
10 GOSUB12:GOTO99
11 f=0:PRINT"{down}[r detta korrekt? n=nej"
12 GETa$:IFa$=""THEN12
13 IFa$="n"THENf=1
14 RETURN
15 GOSUB16:FORi=0TOk:PRINT"{reverse on}"k$(i)"{reverse off}",p$(i,a%(j));:GOSUB205:NEXT:RETURN
16 GOSUB3:PRINT"{reverse on}visar nr:{reverse off}"j"{left}{space*4}{reverse on}sista{reverse off}="n"{left}{space*3}{reverse on}max{reverse off}="mx"{left} ":PRINTl$:RETURN
17 PRINT"data saknas!":GOTO9
18 GOSUB7:PRINTm$(9):GOSUB3:FORi=0TOk:PRINTi+1,k$(i):NEXT:IFd=1THENRETURN
19 PRINT" *","del av rad":RETURN
20 IFny=0THENGOSUB190:n=0
21 PRINTm$(9):GOSUB7:j=n+1:g=0:IFa%(j)=0THENa%(j)=j
22 IFn+1=mxTHENPRINT"minnet fullt!":GOTO10
23 GOSUB16:FORi=0TOk:PRINTk$(i),:i$="":IFg>0THENINPUT"{left*2}";i$:GOTO25
24 GOSUB8:IFi$="m"ANDg=0THEN99
25 IFi$<>""THENp$(i,a%(j))=LEFT$(i$,a(i))
26 NEXT:PRINTm$(0):GOSUB15:GOSUB11:PRINT"{up}"sp$:IFf=1THEN23
27 ONg+1GOTO29,32,79
29 n=n+1:GOTO21
30 j=1:GOSUB7:PRINTm$(0):GOSUB3:IFn=0THEN17
31 PRINTm$(10):GOSUB15:GOSUB12:IFa$="^"THENGOSUB140
32 IFa$="*"THENg=1:PRINTm$(0):GOSUB15:GOTO23
33 IFa$="{down}"THENj=j+1
34 IFa$="{up}"THENj=j-1
35 IFa$="v"THENGOSUB144
36 IFa$="m"THEN99
37 IFj<1THENj=1
38 IFj>nTHENj=n
39 GOTO31
40 d=0:IFn=0THEN17
41 GOSUB18:PRINT"{down}sortera efter rad nr ";:GOSUB8:IFi$="m"THEN99
42 IFi$="*"THENd=1:GOTO41
43 t=VAL(i$)-1:IFt<0ORt>kTHEN40
44 IFd=1THEN51
45 GOSUB69:g=n:GOSUB50
46 f=0:FORj=1TOm:p=j+g:IFp$(t,a%(j))>p$(t,a%(p))THENGOSUB68
47 NEXT:IFf>0THEN46
48 GOSUB50:IFg>0THEN46
49 PRINT"{down}klar!":GOTO9
50 g=INT(g/2):m=n-g:RETURN
51 GOSUB69:PRINT"{reverse off} efter:{down}"
52 PRINT" n","n:te pos p] raden{down}":PRINT,:GOSUB8:IFi$="m"THEN99
53 GOSUB69:g=n:GOSUB50
55 v=VAL(i$):IFv<1THEN51
56 f=0:FORj=1TOm:p=j+g:IFMID$(p$(t,a%(j)),v,1)>MID$(p$(t,a%(p)),v,1)THENGOSUB68
57 NEXT:IFf>0THEN56
58 GOSUB50:IFg>0THEN56
59 GOTO49
68 a=a%(j):a%(j)=a%(p):a%(p)=a:f=1:RETURN
69 PRINTm$(0):GOSUB3:PRINT"sorterar {reverse on}";k$(t):RETURN
70 d=0:pr=0:IFn=0THEN17
71 GOSUB18:PRINT"{down}s{pound}ka efter rad nr ";:GOSUB8:IFi$="m"THEN99
72 IFi$="*"THENd=1:GOTO71
73 a=VAL(i$)-1:IFa<0ORa>kTHEN71
74 PRINT"ange s{pound}kt ord (del av ord)":GOSUB8:b$=i$:IFd=1THEN80
75 FORj=1TOn:IFp$(a,a%(j))=b$THENGOSUB77
76 NEXT:GOTO9
77 REM
78 PRINTm$(0):GOSUB15:GOSUB11:PRINT"{up}"sp$:IFf=1THENg=2:GOTO23
79 RETURN
80 FORj=1TOn:FORe=1TOLEN(p$(a,a%(j)))
81 IFMID$(p$(a,a%(j)),e,LEN(b$))=b$THENGOSUB77
82 NEXTe,j:GOTO9
83 INPUT#15,a,i$,i,j:IFa>19THENPRINTa,i$,i;j:CLOSE8:CLOSE15
84 RETURN
85 GOSUB7:IFn=0THEN17
86 OPEN15,8,15:OPEN8,8,8,"@0:"+n$+",s,w":GOSUB83:IFa>19THEN9
87 PRINT#8,d$;cr$;k;cr$;n;cr$;mx;cr$;
88 FORi=0TOk:PRINT#8,a(i);cr$;k$(i);cr$;:FORj=1TOn:PRINT#8,p$(i,a%(j));cr$;
89 NEXTj,i:CLOSE8:CLOSE15:GOSUB7:GOTO4
90 PRINTm$(0):GOSUB3:GOSUB7:PRINT"gammal fil raderas!"
91 PRINT"{down}ska fil laddas in? n=nej":f=0:GOSUB12:IFf=1THEN99
92 CLR:GOSUB182:ny=1:GOSUB7:PRINT"{down}ange fil-namn{down}":GOSUB8:n$=i$:IFi$="@"THEN102
93 OPEN15,8,15:OPEN8,8,8,n$+",s,r":GOSUB83:IFa>19THEN9
94 INPUT#8,d$:INPUT#8,k:INPUT#8,n:INPUT#8,mx:GOSUB200:FORj=1TOn:a%(j)=j:NEXT
95 FORi=0TOk:INPUT#8,a(i):INPUT#8,k$(i):FORj=1TOn:INPUT#8,p$(i,j)
96 NEXTj,i:CLOSE8:CLOSE15:GOSUB7:PRINTm$(0):GOSUB3
97 PRINT"ange ev. nytt fil-namn";:i$="":INPUTi$:IFi$<>""THENn$=LEFT$(i$,18)
98 PRINT"ange ev. nytt datum";:i$="":INPUTi$:IFi$<>""THENd$=LEFT$(i$,6)
99 GOSUB2:GOTO4
109 PRINTm$(0):GOSUB3:GOSUB7:IFn=0THEN17
110 PRINTm$(9):GOSUB3:PRINT"{down}f{pound}rh{pound}r:":PRINT"{down}f1 "k$(0);" - ";k$(1)
111 PRINT"{down}f3 "k$(1);" - ";k$(0):PRINT"{down}v[lj alternativ!"
112 GOSUB12:pr=ASC(a$)-132:IFpr<1ORpr>2THEN112
113 r=0:f1=0:f2=0:f3=0:a=0:b=1:IFpr=2THENa=1:b=0
115 FORj=1TOn:PRINTm$(9):GOSUB3:PRINT"{down}f{pound}rh{pound}r ";k$(a);" - ";k$(b);"{down}"
116 PRINT"{reverse on}"k$(a)"{reverse off}",LEFT$(p$(a,a%(j))+sp$,29):GOSUB150:IFi$="m"THEN99
117 IFi$=p$(b,a%(j))THENr=r+1:PRINT"{down}r[tt svar, bra!":GOTO131
118 f=1:GOSUB155:GOSUB150:IFi$="m"THEN99
119 IFi$=p$(b,a%(j))THENf1=f1+1:GOTO130
121 f=2:GOSUB155:GOSUB150:IFi$="m"THEN99
122 IFi$=p$(b,a%(j))THENf2=f2+1:GOTO130
124 PRINT"{down}r[tt svar [r:";p$(b,a%(j));sp$;sp$;sp$:f3=f3+1:GOTO131
130 PRINTLEFT$("r[tt!"+sp$,40);sp$
131 GOSUB12:NEXT:PRINTm$(9):GOSUB3:PRINT"{down}f{pound}rh{pound}r "k$(a)" - "k$(b)
132 PRINT"resultat:":PRINT"*********{down}":PRINT"av";n;"glosor hade du:";r;"r[tt"
133 IFr=nTHENPRINT"{down}! ! b r a v o ! !":GOTO9
134 IFf1>0THENPRINT"fel 1 g]ng:{space*2}";f1
135 IFf2>0THENPRINT"fel 2 g]nger:";f2
136 IFf3>0THENPRINT"helt fel{space*4}:";f3
137 IFf1+f2+f3>2THENPRINT"{down}illa! plugga b[ttre!"
138 GOTO9
140 PRINT"{down}radera ? n=nej":f=0:GOSUB12:PRINTm$(0):GOSUB3:IFf=1THENRETURN
142 tf=a%(j):n=n-1:FORh=jTOn:a%(h)=a%(h+1):NEXT:a%(n+1)=tf:RETURN
144 PRINT"{down}vilket nr ska visas? ";:GOSUB8:j=VAL(i$):PRINTm$(0):GOSUB3:RETURN
150 PRINT"{reverse on}"k$(b)"{reverse off}",LEFT$("{left}>"+sp$,30):PRINT"{up}",:GOSUB8:RETURN
155 PRINT"{down}ledsen - fel! det b{pound}rjar p]:"
156 PRINTLEFT$(p$(b,a%(j)),f);:IFf=1THENPRINT".";
157 FORc=3TOLEN(p$(b,a%(j))):PRINT".";:NEXT:PRINT:PRINT"{up*4}";:RETURN
182 l=54272:cr$=CHR$(13):ne$="{home}":nf$=ne$:FORi=lTOl+24:POKEi,0:NEXT
183 POKEl,200:POKEl+1,100:POKEl+5,10:POKEl+6,0:POKEl+24,15
184 FORi=1TO10:sp$=sp$+"{space*4}":ne$=ne$+"{down}":nf$=nf$+"{down*2}":l$=l$+"{-*4}":NEXT
185 m$(1)="f1{space*2}skriva":m$(2)="f3{space*2}visa":m$(3)="f5{space*2}sortera":m$(4)="f7{space*2}s{pound}k"
186 m$(5)="f2{space*2}spara":m$(6)="f4{space*2}ladda":m$(7)="f6{space*2}f{pound}rh{pound}r":m$(8)="f = fre(0)"
187 me$="m=meny":mf$="{clear}"+nf$+l$+sp$:m$(0)=mf$+sp$+sp$+"{up}"
188 m$(9)=mf$+LEFT$(me$+sp$,40)+sp$+"{up}":mr$="{down}{left}{reverse on} * g l o s - 6 4 * {reverse off}"
189 m$(10)=nf$+"{down*2}"+me$+" v=valfri post *=[ndra ^=radera{space*3}"+sp$+"{up}":RETURN
190 ny=1:GOSUB7:PRINT"{clear}":GOSUB3:PRINT"{down}vilket spr]k ";:GOSUB8:k$(1)=LEFT$(i$,9)
191 PRINT"dagens datum ";:GOSUB8:d$=LEFT$(i$,6)
192 PRINT"fil-namn? ";:GOSUB8:n$=LEFT$(i$,18)
193 k=1:c=30:a(0)=29:a(1)=29:k$(0)="svenska"
198 mx=1000
199 PRINT"{down}du rymmer ca 1{0*3} glosor.":GOSUB12
200 DIMp$(k,mx),a%(mx):RETURN
202 x=FRE(0)-(FRE(0)<0)*65536:RETURN
203 PRINTm$(0):GOSUB3:PRINT"st[dar i minnet{.*3}{down}":PRINT"fritt minne:";:GOSUB202
204 PRINTx;"tecken":GOTO9
205 PRINT LEFT$(sp$,29-LEN(p$(i,a%(j)))):RETURN
210 REM
217 DATA 78,a5,01,29,fb,85,01,a9
218 DATA 00,85,fb,85,fd,a9,d0,85
219 DATA fc,a9,c0,85,fe,a0,00,b1
220 DATA fb,91,fd,c8,d0,f9,e6,fc
221 DATA e6,fe,a5,fc,c9,d8,d0,ef
222 DATA a5,01,09,04,85,01,58,ea
223 DATA a2,00,bd,d0,cf,9d,d8,c0
224 DATA 49,ff,9d,d8,c4,e8,e0,18
225 DATA d0,f0,ea,a9,20,8d,18,d0
226 DATA ea,ad,02,dd,09,03,8d,02
227 DATA dd,ad,00,dd,29,fc,8d,00
228 DATA dd,a9,c8,8d,88,02,ea,a9
229 DATA 93,20,d2,ff,60,00,00,00
230 DATA 00,00,00,00,00,00,00,00
231 DATA 66,66,3c,66,66,7e,66,00
232 DATA 66,66,3c,66,66,66,3c,00
233 DATA 3c,66,3c,66,66,7e,66,00,-1
234 c=53088:su=0:i=0:PRINT"{clear}laddar maskinkod"
235 READ a$:IF a$="-1"THEN 240
236 a=ASC(a$)-48:IF a>16 THEN a=a-7
237 b=ASC(RIGHT$(a$,1))-48:IF b>16 THEN b=b-7
238 n=a*16+b
239 POKE c+i,n:su=su+n:i=i+1:GOTO235
240 RETURN
stop tok64
(bastext 1.0)