start tok64 d64-WuGvEg
0 POKE53280,0:POKE53281,0:GOTO2000
1 PRINT"{clear}{cyan}skjut f{pound}r att tr[ffa"
2 PRINT"(ide' fr]n spelet bombardera av creative computing)
5 PRINT"{down}{yellow} 12345{space*4}{green}du ska p] ett rutn[t med 5x5
6 PRINT"{yellow}1{O*5}{cm h}{space*3}{green}rutor (som det till v[nster)
7 PRINT"{yellow}2{O*5}{cm h}{space*3}{green}placera ut 5 posteringar.
8 PRINT"{yellow}3{O*5}{cm h}{space*3}{green}jag g{pound}r likadant. n[r vi [r
9 PRINT"{yellow}4{O*5}{cm h}{space*3}{green}klara s] b{pound}rjar vi skjuta mot
10 PRINT"{yellow}5{O*5}{cm h}{space*3}{green}varandras posteringar. den
11 PRINT"{yellow} {cm y*5}{space*4}{green}som f{pound}rst f{pound}rst{pound}rt den andres
12 PRINT"{space*10}5 posteringar vinner. ett
13 PRINT"{space*10}skott i taget. du ser hela
14 PRINT"{light blue}@ mr.p.{space*3}{green}tiden kartan med dina
15 PRINT"{light blue}{space*2}1990{space*4}{green}posteringar och kartan med
16 PRINT"{light green}lycka{space*5}{green}dina skott.
17 PRINT"{light green}till!":GOSUB500
18 PRINT"{up*6}{cyan}tryck":PRINT"tangent
20 POKE198,.:WAIT198,1:POKE198,.
21 FORi=.TO30:PRINT:NEXT
22 FORi=1TO5:FORj=1TO5:a(i,j)=.:b(i,j)=.:NEXT:NEXT
24 GOSUB1000:REM--kartorna
26 PRINT"{blue}placera ut dina posteringar:
28 FORi=1TO5
30 PRINT"{pink}postering{white}"i"{pink}{left}: (x,y)";:INPUT"{yellow}";x,y
32 IFx<1ORx>5ORy<1ORy>5THENPRINT"{156}ogiltig position!!":GOTO30
34 IFa(x,y)THENPRINT"{orange}du har redan en postering d[r!":GOTO30
36 a(x,y)=-1:NEXT
38 GOSUB1000:REM--kartorna
40 FORi=1TO5
42 PRINT"{pink}jag placerar ut postering{white}"i
44 x=INT(RND(.)*5)+1:y=INT(RND(.)*5)+1
46 IFb(x,y)THEN44
48 b(x,y)=-1:FORz=.TO1000:NEXT:NEXT
50 REM--huvudloop
52 GOSUB1000:REM--kartorna
54 INPUT"{yellow}skjut: {orange}";x,y
56 IFb(x,y)=-2ORb(x,y)=1THENPRINT"{green}d[r har du redan skjutit!":GOTO54
58 IFb(x,y)THENPRINT"{white}tr[ff{!*3}":b(x,y)=-2:GOSUB600:GOTO61
60 b(x,y)=1:PRINT"{green}bom{!*3}
61 FORi=1TO5:FORj=1TO5:IFb(i,j)=-1THEN63
62 NEXT:NEXT:GOTO90
63 FORi=.TO1000:NEXT :GOSUB1000
64 x=INT(RND(.)*5)+1:y=INT(RND(.)*5)+1:IFa(x,y)=-2ORa(x,y)=1THEN64
66 PRINT"{down}{yellow}jag skjuter mot {orange}"CHR$(48+x)","CHR$(48+y)".":FORi=.TO200:NEXT
68 IFa(x,y)THENPRINT"{white}tr[ff!":a(x,y)=-2:GOSUB600:GOTO72
70 a(x,y)=1:PRINT"{green}bom{!*3}
72 FORi=1TO5:FORj=1TO5:IFa(i,j)=-1THEN76
74 NEXT:NEXT:GOTO78
76 FORi=.TO1000:NEXT:GOTO50
78 GOSUB1000:REM--kartorna
80 PRINT"{yellow}{down*2}jag vann{!*3}":END
90 GOSUB1000:REM--kartorna
92 PRINT"{yellow}{down*2}du vann.":END
500 RESTORE:FORl=54272TO54296:POKEl,.:NEXT
501 READx$:IFx$<>"music"THEN501
502 l1=54272:h1=54273:l2=l1+7:h2=h1+7
503 w1=54276:w2=w1+7:vo=l1+24
504 a1=54277:s1=54278:a2=a1+7:s2=s1+7
510 POKEvo,15:POKEa1,0:POKEa2,0:POKEs1,255:POKEs2,255
520 READh,l,hh,ll
530 IFl<.THEN560
540 POKEl1,l:POKEl2,ll:POKEh1,h:POKEh2,hh:POKEw1,33:POKEw2,17
550 FORi=1TO200:NEXT:POKEw1,32:POKEw2,16:FORi=1TO50:NEXT:GOTO520
560 POKEvo,0:RETURN
600 s=54272:FORl=sTOs+27:POKEl,.:NEXT
610 POKEs+24,15:POKEs,5:POKEs+1,5:POKEs+5,145:POKEs+4,129:POKEs+6,245
620 FORi=.TO200:POKE53270,(PEEK(53270)AND248)OR(INT(RND(.)*8)):NEXT
630 POKE53270,200:FORi=15TO.STEP-.1:POKEs+24,i:NEXT:RETURN
1000 REM--kartorna
1005 PRINT"{clear}{green}mina skott:"TAB(20)"dina skott:
1010 PRINT"{yellow} 12345"TAB(21)"12345"
1015 FORj=1TO5:PRINTCHR$(48+j);:FORi=1TO5
1020 IFa(i,j)=.THENPRINT"O";:GOTO1040
1025 IFa(i,j)=-1THENPRINT"{reverse on}O{reverse off}";:GOTO1040
1030 IFa(i,j)=-2THENPRINT"{red}{reverse on}O{reverse off}{yellow}";:GOTO1040
1035 IFa(i,j)=1THENPRINT"{white}V{yellow}";
1040 NEXT:PRINT"{cm h}"TAB(20)CHR$(48+j);:FORi=1TO5
1045 IFb(i,j)=.ORb(i,j)=-1THENPRINT"O";:GOTO1060
1050 IFb(i,j)=-2THENPRINT"{red}{reverse on}O{reverse off}{yellow}";:GOTO1060
1055 IFb(i,j)=1THENPRINT"{white}V{yellow}";
1060 NEXT:PRINT"{cm h}":NEXT
1070 PRINT" {cm y*5}"TAB(21)"{cm y*5}
1075 PRINT"{red}{reverse on}O{reverse off}{yellow} = tr[ffad"TAB(20)"{white}V{yellow} = bom"TAB(40)"{reverse on}O{reverse off} = dina posteringar{down}
1080 RETURN
2000 REM--flytta tecken
2005 FORl=49152TO49203:READa:POKEl,a:NEXT:SYS49152:POKE52,128:POKE56,128
2010 POKE56578,PEEK(56578)OR3:POKE56576,(PEEK(56576)AND252)OR1
2015 POKE648,136:POKE53272,32:PRINT"{142}{clear}";
2020 DATA120,165,1,41,251,133,1,169,,133,251,169,208,133,252,169,,133,253,169
2025 DATA128,133,254,160,,177,251,145,253,200,192,,208,247,230,252,230,254,165
2030 DATA252,201,216,208,237,165,1,9,4,133,1,88,96
1963 REM--poka
2040 FORi=0TO7:READa:POKEi+32768,a:POKEi+33792,255-a:NEXT
2042 FORi=27*8TO29*8+7:READa:POKEi+32768,a:POKEi+33792,255-a:NEXT:RUN1
2045 REM--data
2050 DATA60,66,157,161,161,157,66,60
2060 DATA102,24,60,102,126,102,102,,102,60,102,102,102,102,60,
2061 DATA60,36,60,102,126,102,102,
3000 DATAmusic
3010 DATA021,031, 021,031
3011 DATA022,096, 022,096
3012 DATA021,031, 021,031
3013 DATA022,096, 022,096
3014 DATA033,135, 021,031
3015 DATA033,135, 022,096
3016 DATA033,135, 021,031
3017 DATA031,165, 022,096
3018 DATA028,049, 021,031
3019 DATA031,165, 022,096
3020 DATA028,049, 021,031
3021 DATA021,031, 021,031
3022 DATA021,031, 025,030
3023 DATA021,031, 021,031
3024 DATA021,031, 025,030
3025 DATA025,030, 021,031
3026 DATA028,049, 025,030
3027 DATA025,030, 021,031
3028 DATA028,049, 025,030
3029 DATA044,193, 021,031
3030 DATA044,193, 025,030
3031 DATA044,193, 021,031
3032 DATA050,060, 025,030
3033 DATA042,062, 021,031
3034 DATA033,135, 025,030
3035 DATA028,049, 021,031
3036 DATA022,096, 025,030
3037 DATA022,096, 021,031
3038 DATA022,096, 025,030
3039 DATA025,030, 021,031
3040 DATA025,030, 025,030
3041 DATA022,096, 022,096
3042 DATA022,096, 022,096
3999 DATA-1,-1,-1,-1
stop tok64
(bastext 1.0)