start tok64 d64-lxyqv1
0 REM
1 REM *********************************
2 REM *                               *
3 REM * - av conny & l.g johansson. - *
4 REM *                               *
5 REM * - - -  15/4-84 16/4-84  - - - *
6 REM *                               *
7 REM * - - - -  goalkeeper!  - - - - *
8 REM *                               *
9 REM ********************************* 0 rem
10 PRINTCHR$(147):sp=53248:POKE788,52
15 GOSUB800:GOSUB700:GOTO500
20 REM *****       huvudlop       *****
25 FORq=1TO3:FORw=1TOin(2):FORe=1TO5
30 pa=INT(20*RND(1))
35 hj=INT(20*RND(1)):aa=240:cc=128
40 ba=INT(90*RND(1)-45)/10
45 lo=lo+1
50 ta=PEEK(197)
55 IFta=12THENx=-6:y=10:al=200:GOTO80
60 IFta=23THENx=6 :y=10:al=200:GOTO80
65 IFta=47THENx=-j:y=h :al=202:GOTO80
70 IFta=44THENx=j :y=h :al=201:GOTO80
75 x=0:y=10:al=200
80 xx=xx+x:yy=yy+y
85 IFxx<-70THEN xx=-70
90 IFxx>70THEN  xx=70
95 IFyy>0THEN   yy=0  :h=-6:j=3
100 IFyy<-25THENyy=-25:h=7 :j=2
105 POKE2040,al
110 POKEsp,120+xx:POKEsp+1,85+yy
115 IFlo<paTHEN45
120 aa=aa-(10+in(3)*1.5)
125 cc=cc-(ba+(in(3)*.5))
130 IFaa<80-hjTHEN200
135 POKEsp+30,0
140 POKEsp+2,cc:POKEsp+3,aa
145 GOTO50
200 REM *****    om tagit boll    *****
205 IFPEEK(sp+30)THENpo(w,q)=po(w,q)+1
210 NEXTe:GOSUB300:
215 GOSUB250:NEXTw:GOSUB250:NEXTq
250 GETj$:IFj$<>"/"THEN250
255 xx=0:yy=0:RETURN
300 REM ***** skriver ut resultat *****
305 IFw=1THENPRINT"{home}{down*10}"
310 PRINT"{down}";TAB(28+q*2)po(w,q)
315 IFq=3ANDw=in(2)THEN350
320 RETURN
350 REM *****    total segrare    *****
355 FORw=1TOin(2):FORq=1TO3
360 sc(w)=sc(w)+po(w,q):NEXT:NEXT
365 PRINT"{home}{down*9}":FORq=1TOin(2)
370 PRINT"spelare nr"q"fick"sc(q)          "po[ng{down}":NEXT
375 PRINT"{down*2}vill du/ni spela igen ?"
380 GETj$:IFj$="j"THEN:POKEsp+21,0:         RUN400
385 IFj$<>"n"THEN380
390 POKE788,49:POKEsp+32,14
395 POKEsp+33,6:END
400 REM *****     andra intro     *****
405 sp=53248:i=1:GOTO700:i=0
410 POKEsp+32,12
415 PRINT"{clear}{down*2}{right*2}"a$(1)"{down*2}"
420 FORq=2TO4
425 PRINT"{down}{right*2}"a$(q)"{down*2}":GOSUB770
430 NEXTq
435 PRINT"{down}{right*2}"a$(5)
440 FORp=1TO1500:NEXT:GOTO500
500 REM ***** planen,m]let,tavlan *****
505 POKEsp+32,12:POKEsp+33,5:POKE646,1
510 PRINT"{clear}{down}{right*3}{reverse on}{cm d}{cm i*19}{cm f}"
515 FORq=0TO4
520 PRINT"{right*3}{cm k}{yellow}{cm +*19}{white}{reverse on}{cm k}"
525 NEXT
530 PRINT"{up}{cm p*3}{right*21}{cm p*3}{home}"
535 PRINTTAB(27)"U{sh asterisk*10}I"
540 FORq=0TO20
545 PRINTTAB(27)"B{space*10}B"
550 NEXT
555 PRINTTAB(27)"J{sh asterisk*10}K{home}{down}"
560 PRINTTAB(28)"goalkeeper{down}"
565 PRINTTAB(28)"antal{down}"
570 PRINTTAB(28)"spelare:"in(2)"{down}"
575 PRINTTAB(28)"niv]{space*3}:"in(3)"{down}"
580 PRINTTAB(28)"resultat !{down}"
585 PRINTTAB(28)"1:{down}"
590 PRINTTAB(28)"2:{down}"
595 PRINTTAB(28)"3:{down}"
600 PRINTTAB(28)"4:{down}"
605 PRINTTAB(28)"5:{down}"
610 POKEsp,120:POKEsp+1,85:POKEsp+21,3
615 POKEsp+2,125:POKEsp+3,240
620 PRINTTAB(28)"klar{space*3}(?)"
625 GETj$:IFj$<>"/"THEN625
630 GOTO20
700 REM *****    f{pound}rsta intro    ******
705 POKEsp+32,12:POKEsp+33,11:POKE646,7
710 a$(1)="goalkeeper av conny & l.g johansson.":a(1)=36
715 a$(2)="skriv in antal spelare{space*3}(1-5)"  :a(2)=30
720 a$(3)="skriv in sv]righetsgraden(1-5)"  :a(3)=30
725 a$(4)="vill du ha instruktioner (j/n)"  :a(4)=30
730 a$(5)="okey ha det s] trevligt!!":      a(5)=25
735 IFi=1THEN410
740 FORq=1TO5:FORw=1TOa(q)
745 b$=MID$(a$(q),w,1)+" {up}
750 FORe=38TO1+wSTEP-1
755 PRINTTAB(e)b$;" {up}":NEXT:NEXT
760 PRINT"{down*2}":IFq=2ORq=3ORq=4THENGOSUB      770:NEXT
765 NEXT:FORp=1TO1500:NEXT:RETURN
770 PRINT"{up*3}"TAB(a(q)+3);:INPUTin$(q):     in(q)=VAL(in$(q))
775 IFin(q)<1THENin(q)=1
780 IFin(q)>5THENin(q)=5
785 IFin$(q)="j"THENGOSUB900
790 RETURN
800 REM ******   fixar sprites   ******
805 POKEsp+32,11 :POKEsp+33,11
810 POKEsp+21,0  :POKE2040,200
815 FORq=200TO203:FORw=0TO62:READda
820 POKEq*64+w,da:NEXTw:NEXTq
825 POKE2041,203 :POKEsp+39,1:POKEsp+40,1
830 RETURN
900 REM ******   instruktioner   ******
905 PRINT"{down}{right*2}du styr m]lvakten med:"
910 PRINT"{down}{right*2}{reverse on}z{reverse off} v[nster och {reverse on}x{reverse off} h{pound}ger"
915 PRINT"{down}{right*2}{reverse on}<{reverse off} hoppar m]lvakten ]t v[nster"
920 PRINT"{down}{right*2}{reverse on}>{reverse off} hoppar m]lvakten ]t h{pound}ger"
925 FORp=1TO6000:NEXT:RETURN
1000 REM ****** data m]lis still ******
1001 DATA0,0,0,0,60,0,0
1002 DATA90,0,0,90,0,0,126
1003 DATA0,0,102,0,0,60,0
1004 DATA80,255,10,113,255,142,59
1005 DATA255,220,31,126,248,14,126
1006 DATA112,0,126,0,0,255,0
1007 DATA1,255,128,3,195,192,7
1008 DATA129,224,7,0,224,3,129
1009 DATA192,1,195,128,7,195,224
1010 REM ****** data m]lis h{pound}ger ******
1011 DATA0,0,0,0,60,10,0
1012 DATA90,14,0,90,28,0,126
1013 DATA56,0,102,112,0,60,224
1014 DATA0,255,192,1,255,128,3
1015 DATA255,0,7,126,0,14,126
1016 DATA0,28,126,0,120,254,0
1017 DATA81,255,0,3,199,128,7
1018 DATA1,192,14,3,128,28,7
1019 DATA0,56,14,0,248,31,0
1020 REM ***** data m]lis v[nster *****
1021 DATA0,0,0,80,60,0,112
1022 DATA90,0,56,90,0,28,126
1023 DATA0,14,102,0,7,60,0
1024 DATA3,255,0,1,255,128,0
1025 DATA255,192,0,126,224,0,126
1026 DATA112,0,126,56,0,127,30
1027 DATA0,255,138,1,227,192,3
1028 DATA128,224,1,192,112,0,224
1029 DATA56,0,112,28,0,248,31
1030 REM *****     data boll      *****
1031 DATA124,0,0,254,0,0,254
1032 DATA0,0,254,0,0,124,0
1033 DATA0,0,0,0,0,0,0
1034 DATA0,0,0,0,0,0,0
1035 DATA0,0,0,0,0,0,0
1036 DATA0,0,0,0,0,0,0
1037 DATA0,0,0,0,0,0,0
1038 DATA0,0,0,0,0,0,0
1039 DATA0,0,0,0,0,0,0
1040 REM *****    slut p] data    *****
stop tok64
(bastext 1.0)