start tok64 d64-PTz9Ry
5 POKE53280,14:POKE53281,6:s=54272
10 REM ljudeffekter . dmz 3 / 87 .
20 PRINT"{light blue}{clear}";:FORi=0TO39:POKE2023-i,160:NEXT
30 FORi=0TO23:POKE1024+i*40,160:POKE1063+i*40,160:NEXT
40 PRINT"{reverse on} ljudeffekter dmz 3/1987 sida 26. meny. "
50 PRINTTAB(5)"{down*2}{reverse on}01{reverse off} po[ng ljud"TAB(45)"{reverse on}02{reverse off} blast off"
60 PRINTTAB(5)"{reverse on}03{reverse off} highscore ljud"TAB(45)"{reverse on}04{reverse off} uppm[rksamhet
70 PRINTTAB(5)"{reverse on}05{reverse off} virveltrumma"TAB(45)"{reverse on}06{reverse off} teleportera
80 PRINTTAB(5)"{reverse on}07{reverse off} red alert"TAB(45)"{reverse on}08{reverse off} hi-score
90 PRINTTAB(5)"{reverse on}09{reverse off} distorted guitar"TAB(45)"{reverse on}10{reverse off} motorcykel
100 PRINTTAB(5)"{reverse on}11{reverse off} driv mamma till vansinne"TAB(45)"{reverse on}12{reverse off} plask
110 PRINT"{down*3}{right*10}{reverse on}v[lj: --{left*2}";
120 GETa$:IFa$<"0"ORa$>"1"THEN120
130 PRINTa$;
140 GETb$:IFb$<"0"ORb$>"9"THEN140
150 c$=a$+b$
160 IFc$>"12"THEN140
170 PRINTb$:PRINT"{down}{right*10}{reverse on}";
180 c=VAL(c$):IFc=0THEN220
190 FORl=sTOs+24:POKEl,0:NEXT
200 ONcGOSUB1000,2000,3000,4000,5000,6000,7000,8000,9000,10000,11000,12000
210 PRINT"{up}{right*10}{space*27}{home}";:GOTO40
220 PRINT"hej d]."
230 FORi=0TO1000:NEXT:PRINT"{clear}";:END
1000 PRINT"po[ng ljud
1030 POKEs+24,15:POKEs+1,20:POKEs,136:POKEs+3,4:POKEs+2,0:POKEs+5,8
1090 POKEs+6,248:POKEs+15,75:POKEs+4,67:FORi=1TO25:POKEs+15,120-4*i:NEXT
1150 POKEs+4,64:RETURN
2000 PRINT"blast off
2030 POKEs,0:POKEs+1,5:POKEs+5,145:POKEs+6,245:POKEs+24,15:POKEs+4,129
2090 FORi=1TO400:NEXT:POKEs+4,128:FORi=0TO200:NEXT:POKEs+1,0:RETURN
3000 PRINT"highscore ljud
3030 POKEs+24,15:POKEs+6,247:POKEs+15,5:POKEs,5:POKEs+4,35
3080 FORa=1TO100:POKEs+1,a:FORt=1TO30:NEXT:NEXT:POKEs+4,34:RETURN
4000 PRINT"p]kalla uppm[rksamhet
4030 POKEs+24,15:POKEs+5,8:POKEs+6,255:POKEs+4,23
4050 FORa=1TO2:lf=10:FORb=1TO6:hf=10:POKEs+1,lf
4120 FORc=1TO4:POKEs+15,hf:hf=hf*1.02:NEXT
4160 lf=lf*1.2:NEXT
4180 FORd=1TO8:hf=20:POKEs+1,hf
4210 FORe=1TO3:POKEs+15,hf:hf=hf*1.2:NEXT
4250 lf=lf/1.2:NEXT:NEXT:POKEs+4,0:RETURN
5000 PRINT"vispar p] virveltrumma
5030 POKEs+24,15:POKEs+5,66:POKEs+6,20:POKEs+4,129
5070 FORt=1TO5:POKEs,200:POKEs+1,100
5090 FORh=1TO50:NEXT:POKEs,0:POKEs+1,0
5110 NEXT:POKEs+4,128:RETURN
6000 PRINT"teleportera
6030 POKEs+24,15:POKEs+5,8:POKEs+6,255:POKEs+4,23:lf=10
6080 FORa=1TO24:hf=30:POKEs+1,lf:FORb=1TO10:POKEs+15,hf:hf=hf*1.01:NEXT
6150 lf=lf+8:NEXT:POKEs+4,0:RETURN
7000 PRINT"red alert
7030 POKEs+24,15:POKEs+5,8:POKEs+6,255:POKEs+4,21
7070 FORa=1TO4:lf=10:FORb=1TO5:hf=40:POKEs+1,lf:FORc=1TO5:POKEs+15,hf
7140 hf=hf*1.01:NEXT:lf=lf*1.5:NEXT:NEXT:POKEs+4,0:RETURN
8000 PRINT"hi-score
8030 POKEs+24,15:POKEs+5,8:POKEs+6,255:POKEs+4,23
8070 FORa=1TO3:lf=10:FORb=1TO6:hf=30:POKEs+1,lf:FORc=1TO3:POKEs+15,hf
8120 hf=hf/1.2:NEXT:lf=lf*1.5:NEXT
8140 FORd=1TO8:POKEs+1,lf:POKEs+15,hf:FORe=1TO5:NEXT:lf=lf/1.5:NEXT:NEXT
8210 POKEs+4,0:RETURN
9000 PRINT"distorted guitar
9030 POKEs+24,15:POKEs+5,8:POKEs+6,255:POKEs+4,23:POKEs+15,40
9080 FORa=1TO4:FORlf=255TO0STEP-6:POKEs+1,lf:NEXT
9120 FORlf=0TO255STEP20:POKEs+1,lf:NEXT:NEXT:POKEs+4,0:RETURN
10000 PRINT"motorcykel
10030 POKEs+24,15:POKEs+3,8:POKEs+6,248:POKEs+4,65
10070 FORa=0TO5:POKEs+1,a:FORb=0TO255:POKEs,b:FORt=1TO5:NEXT:NEXT:NEXT
10110 POKEs+4,64:RETURN
11000 PRINT"driv mamma till vansinne
11030 POKEs+24,15:POKEs+6,248:POKEs+20,248:POKEs+18,17:POKEs+4,21
11080 FORa=32TO48STEP4:POKEs+15,a:FORb=0TO255:POKEs+1,b:FORt=1TO100:NEXT
11130 NEXT:NEXT:POKEs+4,20:POKEs+18,16:RETURN
12000 PRINT"plask
12030 POKEs,0:POKEs+1,64:POKEs+5,17:POKEs+6,249:POKEs+24,15:POKEs+4,129
12090 FORa=1TO150:NEXT:POKEs+4,128:FORi=1TO500:NEXT
12120 POKEs+1,0:RETURN
stop tok64
(bastext 1.0)