start tok64 d64-6tkxu2
0 GOTO20
1 INPUT#15,en$,em$,et$,es$:IFen$="00"ORen$="01"THENRETURN
2 PRINT"disk error "en$","em$","et$","es$
3 IFen$="72"THENPRINT"closeing data file..":CLOSE8
4 IFen$="62"ANDq=1THENCLOSE8:CLOSE15:GOTO9000
5 INPUT"{reverse on}a{reverse off}bort or {reverse on}r{reverse off}etry";a$
6 IFLEFT$(a$,1)="a"THENCLOSE8:CLOSE15:END
7 IFLEFT$(a$,1)="r"THENRETURN
8 GOTO5
10 REM --spelregister--
20 POKE53280,12:POKE53281,.:PRINT"{clear}laddar fil":OPEN15,8,15,"i0:
30 DIMn$(1000)
40 OPEN8,8,8,"0:spelreg,s,r":q=1:GOSUB1:q=.
50 INPUT#8,n:GOSUB1
60 IFnTHENFORi=1TOn:INPUT#8,n$(i):GOSUB1:PRINT"{up}",n-i"{left} ":NEXT
70 CLOSE8:GOSUB1
100 POKE53280,.
110 PRINT"{green}{clear}{down}{space*2}{-*3} spelregister {-*3}
120 PRINT"{yellow}{down} (1) {gray}s{pound}ka p] spelets namn
130 PRINT"{yellow}{down} (2) {gray}s{pound}ka p] diskett/kassett
140 PRINT"{yellow}{down} (3) {gray}mata in namn
150 PRINT"{yellow}{down} (4) {gray}spara register p] disk
160 PRINT"{yellow}{down} (5) {gray}[ndra/ta bort
190 PRINT"{yellow}{down} (0) {gray}avsluta
198 PRINT"{home}{down*24}{white}spel i registret:"n"{home}
199 INPUT"{home}{down*22}{light gray} v[lj ";a
200 IFa<>INT(a)ORa<.ORa>5THEN100
210 PRINT"{green}{clear}{down}{space*2}{-*3} spelregister {-*3}
220 IFa=1THENGOSUB1000:GOTO100
221 IFa=2THENGOSUB2000:GOTO100
223 IFa=3THENGOSUB3000:GOTO100
224 IFa=4THENGOSUB4000:GOTO100
225 IFa=5THENGOSUB5000:GOTO100
230 PRINT"{down}{gray}vill du inte spara ?":POKE198,.
240 WAIT198,1:GETa$:IFa$<>"j"ANDa$<>"n"THEN240
250 IFa$="n"THENCLOSE15:END
260 GOSUB4000:CLOSE15:END
999 REM --s{pound}k spel--
1000 PRINT"{down}{white}* {green}avslutar
1010 INPUT"{down}{gray}spelets namn";n$:IFn$="*"THENRETURN
1020 p=1:q=LEN(n$)
1030 FORi=pTOn:IFMID$(n$(i),11,q)=n$THENp=i+1:GOTO1100
1040 NEXT:IFz=1THENx=1:RETURN
1050 GOTO1000
1100 q$=n$(i):k$=LEFT$(q$,3):c$=MID$(q$,4,3):d$=MID$(q$,7,4)
1110 IFk$<>"{space*3}"THENPRINT"{gray}kassett : "k$". counter : "c$".
1120 IFd$<>"{space*4}"THENPRINT"{gray}diskett : "d$".
1125 PRINT"{gray}programnamn : "MID$(q$,11)
1130 PRINT"{down}{white}*{gray} sluta s{pound}ka {white}space{gray} forts[tta
1140 POKE198,.:WAIT198,1:GETa$:IFa$="*"THEN1000
1145 IFzTHENRETURN
1150 IFa$=" "THEN1030
1160 GOTO1140
1999 REM --s{pound}k disk/kass--
2000 INPUT"{down}{gray}s{pound}ka {reverse on}d{reverse off}isk/{reverse on}k{reverse off}ass";s$:IFs$<>"d"ANDs$<>"k"THEN2010
2010 PRINT"{white}* {green}avslutar
2020 INPUT"{down}{gray}disk/kass namn";w$:IFw$="*"THENRETURN
2030 p=1:q=LEN(w$):s=1:IFs$="d"THENs=7
2040 FORi=pTOn:IFMID$(n$(i),s,w)=w$THENp=i+1:GOTO2100
2050 NEXT:GOTO2010
2100 q$=n$(i):k$=LEFT$(q$,3):c$=MID$(q$,4,3):d$=MID$(q$,7,4)
2110 IFk$<>"{space*3}"THENPRINT"{gray}kassett : "k$". counter : "c$".
2120 IFd$<>"{space*4}"THENPRINT"{gray}diskett : "d$".
2125 PRINT"{gray}programnamn : "MID$(q$,11)
2130 PRINT"{white}*{gray} sluta s{pound}ka {white}space{gray} forts[tta
2140 POKE198,.:WAIT198,1:GETa$:IFa$="*"THEN2010
2150 IFa$=" "THEN2040
2160 GOTO2150
2999 REM --mata in--
3000 PRINT"{down}{white}* {green}avslutar {gray}poster i minnet :{white}"n
3001 INPUT"{down}{gray}spelets namn";n$:IFn$="*"THENRETURN
3010 INPUT"{down}{gray}kassett nr{space*2}? {reverse on}{space*3}{reverse off}{left*5}";k$
3020 INPUT"{down}{gray}-'- r[knare ? {reverse on}{space*3}{reverse off}{left*5}";c$
3030 INPUT"{down}{gray}diskett nr{space*2}? {reverse on}{space*4}{reverse off}{left*6}";d$
3040 INPUT"{down}{gray}korrekt? n{left*3}";r$:IFLEFT$(r$,1)<>"j"THEN3000
3050 t$="{space*4}"
3060 n=n+1:n$(n)=LEFT$(k$+t$,3)+LEFT$(c$+t$,3)+LEFT$(d$+t$,4)+n$
3070 IFn=1000THENPRINT"{white} {reverse on}minnet fullt":FORi=.TO5000:NEXT:RETURN
3080 GOTO3000
3999 REM --spara--
4000 PRINT"stoppa i disk. tryck {reverse on}space{reverse off}.
4010 POKE198,.:WAIT198,1:POKE198,.:t$=CHR$(34):PRINT"{clear}{gray}sparar fil
4020 OPEN8,8,8,"@0:spelreg,s,w":GOSUB1
4030 PRINT#8,n:GOSUB1
4040 IFnTHENFORi=1TOn:PRINT#8,t$n$(i):GOSUB1:PRINT"{up}",n-i"{left} ":NEXT
4050 CLOSE8:GOSUB1:RETURN
4999 REM --[ndra/ta bort--
5000 z=1:GOSUB1010:IFx=1THEN5000
5010 IFn$="*"THENRETURN
5020 PRINT"{down}{yellow}(1) {gray}[ndra {yellow}(2) {gray}ta bort {yellow}(3) {gray}forts[tta
5030 POKE198,.:WAIT198,1:GETa$:IFa$="3"THEN5000
5040 IFa$="2"THEN5130
5060 INPUT"{down}{gray}spelets namn";n$
5070 INPUT"{down}{gray}kassett nr{space*2}? {reverse on}{space*3}{reverse off}{left*5}";k$
5080 INPUT"{down}{gray}-'- r[knare ? {reverse on}{space*3}{reverse off}{left*5}";c$
5090 INPUT"{down}{gray}diskett nr{space*2}? {reverse on}{space*4}{reverse off}{left*6}";d$
5100 INPUT"{down}{gray}korrekt? n{left*3}";r$:IFLEFT$(r$,1)<>"j"THEN5020
5110 t$="{space*4}"
5120 n$(i)=LEFT$(k$+t$,3)+LEFT$(c$+t$,3)+LEFT$(d$+t$,4)+n$:GOTO5000
5130 INPUT"{down}{gray}s[ker? n{left*3}";r$:IFLEFT$(r$,1)<>"j"THEN5020
5140 n=n-1:FORw=iTOn:n$(w)=n$(w+1):NEXT:GOTO5000
9000 REM --init register--
9005 PRINT"spelreg init";
9010 OPEN15,8,15,"i0:
9020 OPEN8,8,8,"@0:spelreg,s,w":GOSUB1
9030 PRINT#8,"0":GOSUB1:CLOSE8:GOSUB1
9040 PRINT" klar":CLOSE15
stop tok64
(bastext 1.0)