start tok64 d64-Xub902
4 POKE53280,.:POKE53281,.
10 PRINT"{gray}{clear}";
20 DIMt$(255),q$(255)
30 g$="ha! jag gissade r[tt! duktigt va?
40 OPEN15,8,15,"r0:animal data=animal data
50 GOSUB9999
60 IFen$="62"THEN200
70 IFen$<>"63"THENPRINT"disk error:"em$:CLOSE15:END
150 OPEN8,8,8,"0:animal data,s,r
160 INPUT#8,ns,n:GOSUB9999
170 FORi=.TOn:INPUT#8,t$(i),q$(i):GOSUB9999:NEXT
190 CLOSE8:GOTO330
200 READns,n:FORi=.TOn:READt$(i),q$(i):NEXT
330 PRINT"{down*2} {gray}t[nk p] ett djur, s] ska jag gissa vad
340 PRINT" det [r. tryck p] {reverse on}shift{reverse off} n[r du valt
350 PRINT" djur.
360 WAIT653,1:POKE198,.
380 qa$=""
390 FORzz=.TOns:GOSUB440:NEXT
400 FORi=ns+1TOn:IFt$(i)=qa$THEN420
410 NEXT:GOTO510
420 zz=i:i=n:NEXT
430 GOSUB440:GOTO400
440 PRINTq$(zz)" ";
450 GETa$:IFa$<>"j"ANDa$<>"n"THEN450
460 qa$=qa$+a$
490 PRINTa$:RETURN
510 IFa$="j"THENPRINTg$:GOTO720
520 PRINT"knepigt. jag ger upp
540 ch=-1:INPUT" vad t[nkte du p]";na$
541 IFLEFT$(na$,2)<>"en"ANDLEFT$(na$,3)<>"ett"THEN540
550 t$=q$(zz):tl=LEN(t$)
560 PRINT"om man definitivt vill skilja
570 PRINTna$" fr]n"RIGHT$(t$,tl-6)"{left},
580 INPUT"hur fr]gar man d]";nq$
590 IFRIGHT$(nq$,1)<>"?"THENnq$=nq$+"?
600 PRINT"{down}och om det [r "na$
620 PRINT"vad svarar man d]? ";
630 GETra$:IFra$<>"j"ANDra$<>"n"THEN630
650 PRINTra$:n=n+1:pa$=LEFT$(qa$,LEN(qa$)-1)
660 t$=q$(zz):q$(zz)=nq$
670 x$="n":z$="j
680 IFra$="n"THENx$="j":z$="n
690 t$(n)=pa$+x$:q$(n)=t$:n=n+1
700 t$(n)=pa$+z$:q$(n)="[r det "+na$+"?
720 PRINT"{down}ska vi f{pound}rs{pound}ka igen?":POKE198,.
730 GETa$:IFa$<>"j"ANDa$<>"n"THEN730
740 IFa$="j"THEN330
760 IFch=.THENEND
910 OPEN8,8,8,"@0:animal data,s,w":GOSUB9999
920 PRINT#8,ns","n:GOSUB9999
930 FORi=.TOn:PRINT#8,t$(i)","q$(i):GOSUB9999:NEXT:CLOSE8
950 GOSUB9999:CLOSE15:END
1000 DATA0,2
1010 DATAs,har den fyra ben?
1020 DATAj,[r det en katt?
1030 DATAn,[r det en gam?
9998 STOP
9999 INPUT#15,en$,em$,et$,es$:IFen$<"02"OR(en$>"61"ANDen$<"64")THENRETURN
10000 IFen$="72"THENPRINT"warning: disk soon full!!":RETURN
10001 PRINT"disk error:"em$:CLOSE8:CLOSE15
stop tok64
(bastext 1.0)