start tok64 d64-5ZEy6o
0 REM"@0:directory
100 POKE53280,.:POKE53281,.:GOTO440
110 GET#8,a$:IFa$=""THENa$=CHR$(.)
120 RETURN
130 INPUT#15,e,e$,t,s
140 IFe>.THENPRINT"{pink}"e;e$t","s:CLOSE15:END
150 RETURN
160 GOSUB110
170 dn$=dn$+a$
180 RETURN
190 GET#8,a$:IFa$=""THEN190
200 IFstTHEN430
205 p$=" ":IFASC(a$)AND64THENp$="{reverse on}<{reverse off}
210 IF(ASC(a$)AND191)<=128THENf$="del":GOTO250
220 IFASC(a$)AND56THEN190
230 f=(ASC(a$)AND63):f=f+2*(f-1):REMifasc(a$)and64thenp$="{reverse on}<{reverse off}
240 f$=MID$("seqprgusrrel",f,3)
250 GOSUB110
260 t$=RIGHT$(" "+STR$(ASC(a$)),2)
270 GOSUB110
280 s$=RIGHT$(" "+STR$(ASC(a$)),2)
290 n$=""
300 FORa=1TO16
310 GET#8,a$:n$=n$+a$
320 NEXT
330 FORa=1TO9:GET#8,a$:NEXT
340 GOSUB110
350 bl=ASC(a$)
360 GOSUB110
370 bl=bl+ASC(a$)*256:IFf$<>"del"THENbt=bt+bl
380 b$=RIGHT$("{space*2}"+STR$(bl),3)
390 PRINT"{white}";:IFf$="del"THENPRINT"{orange}";
400 POKE212,128
410 PRINTn$;:POKE212,.
420 PRINT"{light gray}"p$" {light green}"f$"{space*2}{pink}"b$"{space*3}{light blue}"t$"{space*4}"s$
430 RETURN
440 PRINT"{clear}{yellow}{ct n}Loading header block
450 OPEN15,8,15:PRINT#15,"i0":GOSUB130
460 bt=.:DIMbm$(35)
470 OPEN8,8,1,"$,s,r":GOSUB130
480 FORa=1TO2:GET#8,a$:NEXT:a=.
490 FORa=1TO35
500 GOSUB110
510 bm=bm+ASC(a$):bm$(a)=RIGHT$(" "+STR$(ASC(a$)),3)
520 GET#8,a$:GET#8,a$:GET#8,a$
530 NEXT
540 dn$="{clear}{ct n}{yellow}Disk: {reverse on}"+CHR$(34)
550 FORa=1TO16:GOSUB160:NEXT
560 dn$=dn$+CHR$(34)
570 FORa=1TO15:GOSUB160:NEXT
580 PRINTdn$:b=.
590 PRINT"{down}{white}Filename{space*9}{light green}Type {pink}Size {light blue}Track Sector{down}
600 GOSUB190:b=b+1:IFf$<>"del"THENpt=pt+1
610 IFstTHEN630
620 IFb<20THEN600
630 POKE198,.:PRINTTAB(12)"{red}{reverse on} Press Any Key {reverse off}";
640 GETk$:IFk$=""THEN640
650 IFst=.THEN580
660 GOSUB130:CLOSE8:CLOSE15
670 PRINT"{clear}{white}{space*11}Vital Statistics
680 PRINT"{space*11}{cm t*16}
690 PRINT"{yellow}Number of programs ="pt
700 PRINT"Blocks used ="bt
710 bf=bm-VAL(bm$(18))
720 PRINT"Blocks free ="bf;
730 a$=""
740 IF664-bt<>bfTHENa$="{pink}Block count mismatch!{yellow}
750 PRINTa$
760 PRINT"Directory blocks free ="bm$(18)
770 a$="{green}{sh -}{space*36}{sh -}
780 PRINT"{down}{green}{cm a}{sh asterisk*36}{cm s}
790 PRINT"{green}{sh -}Free track sectors:{space*17}{sh -}
800 PRINT"{green}{sh -}{cm t*19}{space*17}{sh -}
810 PRINT"{green}{sh -}{light gray}Track:{space*2}1{space*2}2{space*2}3{space*2}4{space*2}5{space*2}6{space*2}7{space*2}8{space*2}9 10{green}{sh -}
820 PRINT"{green}{sh -}{light blue}Total:";:FORa=1TO10:PRINT"{light blue}";:IFVAL(bm$(a))=21THENPRINT"{brown}";
830 PRINTbm$(a);:NEXT:PRINT"{green}{sh -}":PRINTa$
840 PRINT"{green}{sh -}{light gray}Track: 11 12 13 14 15 16 17 18 19 20{green}{sh -}
850 PRINT"{green}{sh -}{light blue}Total:";:FORa=11TO17:PRINT"{light blue}";:IFVAL(bm$(a))=21THENPRINT"{brown}";
860 PRINTbm$(a);:NEXT
870 FORa=18TO20:PRINT"{light blue}";:IFVAL(bm$(a))=19THENPRINT"{brown}";
880 PRINTbm$(a);:NEXT:PRINT"{green}{sh -}":PRINTa$
890 PRINT"{green}{sh -}{light gray}Track: 21 22 23 24 25 26 27 28 29 30{green}{sh -}
900 PRINT"{green}{sh -}{light blue}Total:";:FORa=21TO24:PRINT"{light blue}";:IFVAL(bm$(a))=19THENPRINT"{brown}";
910 PRINTbm$(a);:NEXT
920 FORa=25TO30:PRINT"{light blue}";:IFVAL(bm$(a))=18THENPRINT"{brown}";
930 PRINTbm$(a);:NEXT:PRINT"{green}{sh -}":PRINTa$
940 PRINT"{green}{sh -}{light gray}Track: 31 32 33 34 35{space*15}{green}{sh -}
950 PRINT"{green}{sh -}{light blue}Total:";:FORa=31TO35:PRINT"{light blue}";:IFVAL(bm$(a))=17THENPRINT"{brown}";
960 PRINTbm$(a);:NEXT:PRINT"{space*15}{green}{sh -}
970 PRINT"{cm z}{sh asterisk*36}{cm x}
stop tok64
(bastext 1.0)