start tok64 d64-7vEhQZ
10 REM"{delete*7}character master v3.20 (c) mr.p.
30 REM"{delete*7}****************************************
40 REM flytta tecken i maskinkod c64           (av: gunnar berglund)
50 POKE53280,11:POKE53281,.
60 FORl=679TO730:READa:POKEl,a:NEXT
70 SYS679
80 POKE52,128:POKE56,128
90 POKE56578,PEEK(56578)OR3:POKE56576,(PEEK(56576)AND252)OR1
100 POKE648,136:POKE53272,32:PRINTCHR$(142):PRINT"{clear}"
110 DATA120,165,1,41,251,133,1,169,0,133,251,169,208,133,252,169,0,133,253,169
120 DATA128,133,254,160,0,177,251,145,253,200,192,0,208,247,230,252,230,254,165
130 DATA252,201,216,208,237,165,1,9,4,133,1,88,96
140 REM"{delete*8}****************************************
145 POKE650,128:d=35536
150 PRINT"{yellow}{clear}{ct h}character master 64{.*3} {white}v3.20":POKE53280,0:POKE53281,0
155 FORi=0TO255:POKE35536+i,i:POKE56016+i,12:NEXT
156 PRINT"{home}{down*24}{right*17}{gray}fil ins end{home}
160 sc=32768:bs=PEEK(648)*256:REM       sc=b{pound}rjan tecken & bs=b{pound}rjan sk[rm.
170 PRINT"{down}{yellow}v[lj tecken.
180 PRINT"{down}ditt val: {right}. ({right*3})
200 PRINT"{down*10}{gray}v[lj {cyan}ins {gray}f{pound}r instruktioner."
230 PRINT"{home}{down}{green}(c) 1988-89-90-91: mr.p"
240 POKEd,PEEK(d)OR128:dd=d
241 GETa$:a=31-(PEEK(56320)AND31)
242 IFa$<" "ORa$="{left}"ORa$="{up}"THEN246
243 s=PEEK(bs):PRINT"{yellow}{home}"a$:t=PEEK(bs):POKEbs,s:d=35536+t:GOTO255
245 GETa$:a=31-(PEEK(56320)AND31)
246 IFa$="{right}"ORaAND8THENd=d+1
247 IFa$="{left}"ORaAND4THENd=d-1
248 IFa$="{up}"ORaAND1THENd=d-40
249 IFa$="{down}"ORaAND2THENd=d+40
250 IFd<>ddTHEN255
251 IFa$=CHR$(13)ORaAND16THEN270
252 q=PEEK(d)AND127:IFd>35663THEN254
253 PRINT"{home}{down*4}{right*13}{yellow}("RIGHT$(STR$(1e3+q),3)")":POKEbs+170,q
254 GOTO240
255 IFd<35536THENd=35801
256 IFd>35663ANDd<35793ANDdd<dTHENd=35793
257 IFd>35663ANDd<35793THENd=35663
258 IFd>35793ANDd<35797ANDdd<dTHENd=35797
259 IFd>35793ANDd<35797THENd=35793
260 IFd>35797ANDd<35801ANDdd<dTHENd=35801
261 IFd>35797ANDd<35801THENd=35797
262 IFd>35801THENd=35536
263 IFd<35336THENd=35801
264 POKEdd,PEEK(dd)AND127:GOTO252
270 ct=q:IFd=35801THEN650
280 IFd=35793THEN720
290 IFd=35797THENGOSUB1180:GOTO150
300 PRINT"{home}{down*2}{space*12}"
310 PRINT"{home}{down*6}{yellow}";:y=sc+(ct*8):yy=sc+((ct+128)*8)
320 FORk=yTOy+7:a=PEEK(k)
330 FORl=7TO0STEP-1
340 IFaAND(2^l)THENPRINT"{reverse on} ";:GOTO360
350 PRINT"{reverse off}-";
360 NEXTl:PRINT,"{green}{reverse off}"a"{left}.{yellow}{space*2}":NEXTk
370 r=6:k=.
380 z=r*40+k+bs:cs=r*40+k+55296:POKEcs,1:x=PEEK(z)
381 GETa$
382 a=31-(PEEK(56320)AND31)
384 IFaAND1THENr=r-1
385 IFaAND2THENr=r+1
386 IFaAND4THENk=k-1:GOTO520
387 IFaAND8THENk=k+1:GOTO520
388 IFaAND1ORaAND2THEN520
390 IFa$=""ANDa=.THEN380
395 IFa$="i"THENGOSUB1570:GOTO380
400 IFa$="@"THEN310
405 IFa$="{f1}"THEN640
410 IFa$="m"THENGOSUB1100:GOTO380
420 IFa$="{right}"THENk=k+1:GOTO520
430 IFa$="{down}"THENr=r+1:GOTO520
440 IFa$="{up}"THENr=r-1:GOTO520
445 IFa$="k"THEN1500
450 IFa$="{left}"THENk=k-1:GOTO520
455 IF(a$="{f3}"ORaAND16)ANDx=160THENa$="0"
456 IF(a$="{f3}"ORaAND16)ANDx=45THENa$="1"
460 IFa$="*"ORa$="x"ORa$="1"THENx=160:k=k+1:GOTO520
470 IFa$="n"THENGOSUB1120:GOTO150
480 IFa$="."ORa$=" "ORa$="{sh space}"ORa$="0"THENx=45:k=k+1:GOTO520
490 IFa$=CHR$(13)THENa$="":POKEcs,7:GOTO600
500 IFa$="l"ORa$="r"THENGOSUB1050:GOTO380
501 IFa$="c"THENGOSUB990:GOTO380
502 GOTO380
503 ok=k:OR=r:RETURN
520 POKEcs,7:POKEz,x:k=k+((k>7)-(k<.))*8:r=r+((r>13)-(r<6))*8:GOTO380
600 PRINT"{home}{down*6}";:FORr=6TO13:j=0:FORk=7TO0STEP-1
610 v=PEEK(bs+r*40+(7-k))
620 IFv=160THENj=j+2^k
630 NEXT:POKEy+(r-6),j:PRINT,"{green}"j"{left}.{space*6}":POKEyy+(r-6),255-j
635 NEXT
640 PRINT"{home}{down}";:GOTO170
650 PRINT"{dark gray}{clear}vill du avsluta? ";
660 GETa$:IFa$="n"THEN150
670 IFa$="j"THENPRINT"ja.{gray}":LIST9900-9999
680 GOTO660
720 PRINT"{light gray}{clear}{space*2}{reverse on}s{reverse off}-spara {reverse on}l{reverse off}-ladda {reverse on}${reverse off}-directory {reverse on}n{reverse off}-sluta
730 GETa$:IFa$="n"THEN150
735 IFa$<>"l"ANDa$<>"s"ANDa$<>"$"THEN730
740 INPUT"enhet (8-11)";en:IFen<8ORen>11THEN740
745 PRINT"s[tt i r[tt diskett. tryck sedan p]{space*5}mellanslag"
770 POKE198,.:WAIT198,1:POKE198,.:CLOSE2:IFa$="$"THEN820
780 IFa$="s"THEN880
790 FORz=.TO255:POKEbs+480+z,z:NEXT
800 INPUT"filnamn";fi$:fi$=LEFT$(fi$+"{space*12}",12)+".cmf
805 POKE147,.:SYS57812fi$,en,1:SYS62631
810 OPEN15,en,15:GOSUB970:CLOSE15:GOTO150
820 OPEN2,en,.,"$0:{?*12}.cmf
830 GET#2,a$:IFa$<>CHR$(34)THEN830
831 PRINT"{down}disk : ";:FORi=1TO16:GET#2,a$:PRINTa$;:NEXT:GET#2,a$:PRINT
832 PRINT"fonter p] disken:",
840 GET#2,a$:IFstTHENCLOSE2:GOTO870
850 IFa$<>CHR$(34)THEN840
860 FORi=1TO12:GET#2,a$:PRINTa$;:NEXT:PRINT,:GET#2,a$,a$,a$,a$,a$:GOTO840
870 PRINT"tryck {reverse on}mellanslag{reverse off}":POKE198,.:WAIT198,1:POKE198,.:GOTO150
880 INPUT"filnamn";fi$:fi$=LEFT$(fi$+"{space*12}",12)+".cmf
885 OPEN15,en,15:OPEN2,en,2,"@0:"+fi$+",p,w":GOSUB970
890 PRINT#2,CHR$(0)CHR$(128);:GOSUB970
900 FORi=32768TO34815:PRINT#2,CHR$(PEEK(i));:GOSUB970
910 NEXT:CLOSE2:GOSUB970:GOTO150
970 INPUT#15,en,em$,et,es:IFen<20THENRETURN
980 PRINT"disk fel -"em$","et"{left},"es:CLOSE2:CLOSE15:END
990 REM ** clear **
1000 FORrr=6TO13
1010 FORkk=0TO7
1020 POKEbs+rr*40+kk,45
1030 NEXT:NEXT
1040 RETURN
1050 REM ** rotate **
1060 IFa$="r"THEN1075
1065 FORrr=6TO13:z=PEEK(bs+rr*40):FORkk=1TO7
1070 POKEbs+rr*40+(kk-1),PEEK(bs+rr*40+kk):NEXT:POKEbs+rr*40+7,z:NEXT:RETURN
1075 FORrr=6TO13:z=PEEK(bs+rr*40+7):FORkk=6TO0STEP-1
1080 POKEbs+rr*40+(kk+1),PEEK(bs+rr*40+kk):NEXT:POKEbs+rr*40,z:NEXT:RETURN
1090 REM ** mirror **
1100 FORrr=6TO13:FORkk=0TO7:b(kk)=PEEK(bs+rr*40+kk):NEXT
1110 FORkk=0TO7:POKE(bs+rr*40+(7-kk)),b(kk):NEXT:NEXT:RETURN
1120 REM ** number **
1130 PRINT"{home}{down*6}";
1140 FORi=0TO7:PRINT,"{green}{left}";:INPUTa
1150 POKEy+i,a:IFar=1THENPOKEyy+i,255-a
1160 NEXT
1170 RETURN
1180 PRINT"{white}{clear}instruktioner till character master 64"
1190 PRINT"{down}{cyan}{-*4}att v[lja ett tecken att editera{-*4}";
1200 PRINT"{yellow}styr mark{pound}ren (se n[sta sida). du kan
1210 PRINT"[ven v[lja ett tecken genom att trycka
1215 PRINT"p] motsvarande tangent och sedan return.
1220 PRINT"{cyan}{-*3}specialfunktioner i teckeneditorn{-*3}
1230 PRINT"{yellow}c{space*2}{green}-{yellow} rensar tecknet
1240 PRINT"l,r{green}-{yellow} roterar tecknet v[nster,h{pound}ger
1250 PRINT"@{space*2}{green}-{yellow} ger tillbaka det gamla tecknet":PRINT"m{space*2}{green}-{yellow} speglar tecknet
1255 PRINT"n{space*2}{green}-{yellow} l]ter dig utforma tecken med{space*12}siffror
1256 PRINT"k{space*2}{green}-{yellow} kopierar in ett annat tecken
1257 PRINT"i{space*2}{green}-{yellow} inverterar tecknet
1260 PRINT"{down}{cyan}{-*6}att spara och ladda tecknen{-*6}
1270 PRINT"{yellow}v[lj {white}fil{yellow} och sedan {white}l{yellow} f{pound}r ladda eller
1280 PRINT"{white}s{yellow} f{pound}r spara. {white}n{yellow} ger ]terhopp. du kan bara";
1290 PRINT"spara p] diskett.
1300 PRINT"{down*2}(c) 1988-89-90-91: mr.p."
1320 INPUT"tryck return:";a$
1330 PRINT"{clear}{white}instruktioner till character master 64
1340 PRINT"{down}{cyan}{-*3}ritinstruktioner f{pound}r teckeneditorn{-*3}{yellow}";
1345 PRINT"x,*,1{space*5}{green}-{yellow} t[nd en punkt
1350 PRINT"space,0{space*3}{green}-{yellow} sl[ck en punkt
1355 PRINT"{green}f3{yellow},fire{space*3}{green}-{yellow} invertera en punkt
1360 PRINT"{green}f1{space*8}-{yellow} l[mnar editor utan att [ndra{space*12}tecknet."
1390 PRINT"{down}{cyan}{-*10}att styra mark{pound}ren{-*11}{yellow}
1392 PRINT"crsr{space*6}{green}-{yellow} styr mark{pound}ren i en riktning
1393 PRINT"return{space*4}{green}-{yellow} v[ljer tecken eller l[mnar{space*16}teckeneditorn
1394 PRINT"joystick#2{green}-{yellow} styr mark{pound}ren i en riktning
1400 PRINT"{down}{cyan}--att utnyttja fonterna i egna program--";
1410 PRINT"{yellow}f{pound}r att anv[nda en font i egna program,
1420 PRINT"ladda och lista {green}character loader{yellow} av
1430 PRINT"mr.p.
1440 PRINT"{down}{cyan}{-*4}att ladda filer fr]n c.m. v 3.10{-*4}";
1450 PRINT"{yellow}f{pound}r att ladda filer fr]n v 3.10, anv[nd
1460 PRINT"{green}charfile convert {yellow}av mr.p.
1470 a$="":INPUT"{down}{yellow}{arrow left}{white} ger f{pound}rra sidan";a$
1480 IFa$="{arrow left}"THEN1180
1490 RETURN
1500 INPUT"{home}{down*2}kopiera fr]n ";a$:ct=PEEK(bs+95)AND127
1510 PRINT"{home}{down*6}{yellow}";:z=sc+(ct*8):FORq=zTOz+7:a=PEEK(q):FORw=7TO.STEP-1
1520 IFaAND(2^w)THENPRINT"{reverse on} ";:GOTO1540
1530 PRINT"{reverse off}-";
1540 NEXT:PRINT,"{green}{reverse off}"a"{left}.{yellow}{space*2}":NEXT:PRINT"{home}{down*2}{yellow}{space*18}"
1550 GOTO380
1560 REM ** invert **
1570 FORrr=6TO13:FORkk=.TO7:y=bs+rr*40+kk:z=PEEK(y):x=45:IFz=45THENx=160
1580 POKEy,x:NEXT:NEXT:RETURN
9984 "{delete*6}**viktigt!! l[s detta noga!!**
9985 "{delete*6}******************************
9986 "{delete*6}*{space*3}character master v3.20{space*3}*
9987 "{delete*6}* {=*26} *
9988 "{delete*6}* f{pound}r omstart{space*2}utan att f{pound}r- *
9989 "{delete*6}* lora tecknen:{space*2}starta med: *
9990 "{delete*6}*{space*7}-- goto 140 --{space*7}*
9991 "{delete*6}* {=*26} *
9992 "{delete*6}* {-*9} obs!! {-*10} *
9993 "{delete*6}* om du trycker stop+restore *
9994 "{delete*6}* "dyker" datorn. skriv{space*3}d] *
9995 "{delete*6}* run & tryck return! sk[rm- *
9996 "{delete*6}* minne & spritepekare finns *
9997 "{delete*6}* p] 34816-358539.{space*11}*
9998 "{delete*6}*{space*6}(c) mr.p. : 1991{space*6}*
9999 "{delete*6}******************************
stop tok64
(bastext 1.0)